Referência MQL5Símbolos personalizadosCustomSymbolSetInteger

CustomSymbolSetInteger

Define o valor do tipo inteiro para o símbolo personalizado.

bool  CustomSymbolSetInteger(
   const string              symbol_name,      // nome do símbolo
   ENUM_SYMBOL_INFO_INTEGER  property_id,      // identificador de propriedade
   long                      property_value    // valor de propriedade
   );

Parâmetros

symbol_name

[in] Nome do símbolo personalizado.

property_id

[in] Identificador da propriedade do símbolo. O valor pode ser um dos valores da enumeração ENUM_SYMBOL_INFO_INTEGER.

property_value

[in] Variável de tipo long contendo o valor da propriedade.

Valor de retorno

true, em caso de sucesso, caso contrário, false. Para obter informações sobre o erro, você deve chamar a função GetLastError().

Observação

Histórico de minuto e de ticks do símbolo personalizado é completamente removido, se, na especificação do símbolo, for alterada qualquer uma destas propriedades:

SYMBOL_CHART_MODE — tipo de preço usado para plotagem de barras (Bid ou Last)
SYMBOL_DIGITS — número de casas decimais para exibição do preço

Após a remoção do histórico personalizado, o terminal tentará criar um novo histórico usando as propriedades atualizadas. A mesma coisa acontece quando você altera manualmente as propriedades do símbolo personalizado.

Exemplo:

//+------------------------------------------------------------------+
//|                                       CustomSymbolSetInteger.mq5 |
//|                                  Copyright 2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"

#define   CUSTOM_SYMBOL_NAME     Symbol()+".C"     // nome do símbolo personalizado
#define   CUSTOM_SYMBOL_PATH     "Forex"           // nome do grupo onde o símbolo será criado
#define   CUSTOM_SYMBOL_ORIGIN   Symbol()          // nome do símbolo usado como base para a criação do símbolo personalizado

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- obtemos o código de erro ao criar o símbolo personalizado
   int create=CreateCustomSymbol(CUSTOM_SYMBOL_NAME, CUSTOM_SYMBOL_PATH, CUSTOM_SYMBOL_ORIGIN);

//--- se o código de erro não for 0 (criação bem-sucedida do símbolo) e não for 5304 (símbolo já criado), saímos.
   if(create!=0 && create!=5304)
      return;

//--- obtemos e imprimimos no log as propriedades do símbolo, com base no qual o símbolo personalizado foi criado
//--- (modo de realização de transações, nível de colocação de ordens Stop e distância de congelamento das operações de trading)
   ENUM_SYMBOL_TRADE_EXECUTION origin_exe_mode = (ENUM_SYMBOL_TRADE_EXECUTION)SymbolInfoInteger(CUSTOM_SYMBOL_ORIGIN, SYMBOL_TRADE_EXEMODE);
   int origin_stops_level = (int)SymbolInfoInteger(CUSTOM_SYMBOL_ORIGIN, SYMBOL_TRADE_STOPS_LEVEL);
   int origin_freeze_level= (int)SymbolInfoInteger(CUSTOM_SYMBOL_ORIGIN, SYMBOL_TRADE_FREEZE_LEVEL);

   PrintFormat("The '%s' symbol from which the custom '%s' was created:\n"+
               "  Deal execution mode: %s\n  Stops Level: %d\n  Freeze Level: %d",
               CUSTOM_SYMBOL_ORIGIN, CUSTOM_SYMBOL_NAME,
               StringSubstr(EnumToString(origin_exe_mode), 23), origin_stops_level, origin_freeze_level);

//--- definimos outros valores para essas propriedades do símbolo personalizado
   ResetLastError();
   bool res=true;
   res &=CustomSymbolSetInteger(CUSTOM_SYMBOL_NAME, SYMBOL_TRADE_EXEMODE, SYMBOL_TRADE_EXECUTION_MARKET);
   res &=CustomSymbolSetInteger(CUSTOM_SYMBOL_NAME, SYMBOL_TRADE_STOPS_LEVEL, 10);
   res &=CustomSymbolSetInteger(CUSTOM_SYMBOL_NAME, SYMBOL_TRADE_FREEZE_LEVEL, 3);

//--- se houver erro ao definir qualquer uma das propriedades, informamos no log
   if(!res)
      Print("CustomSymbolSetInteger() failed. Error ", GetLastError());

//--- obtemos e imprimimos no log as propriedades alteradas do símbolo personalizado
//--- (modo de realização de transações, nível de colocação de ordens Stop e distância de congelamento das operações de trading)
   ENUM_SYMBOL_TRADE_EXECUTION custom_exe_mode = (ENUM_SYMBOL_TRADE_EXECUTION)SymbolInfoInteger(CUSTOM_SYMBOL_NAME, SYMBOL_TRADE_EXEMODE);
   int custom_stops_level = (int)SymbolInfoInteger(CUSTOM_SYMBOL_NAME, SYMBOL_TRADE_STOPS_LEVEL);
   int custom_freeze_level= (int)SymbolInfoInteger(CUSTOM_SYMBOL_NAME, SYMBOL_TRADE_FREEZE_LEVEL);

   PrintFormat("Custom symbol '%s' based on '%s':\n"+
               "  Deal execution mode: %s\n  Stops Level: %d\n  Freeze Level: %d",
               CUSTOM_SYMBOL_NAME, CUSTOM_SYMBOL_ORIGIN,
               StringSubstr(EnumToString(custom_exe_mode), 23), custom_stops_level, custom_freeze_level);

//--- no comentário do gráfico exibimos a dica sobre as chaves de encerramento do script
   Comment(StringFormat("Press 'Esc' to exit or 'Del' to delete the '%s' symbol and exit", CUSTOM_SYMBOL_NAME));

//--- em um loop infinito, esperamos as teclas Esc ou Del para sair
   while(!IsStopped() && TerminalInfoInteger(TERMINAL_KEYSTATE_ESCAPE)==0)
     {
      Sleep(16);
      //--- ao pressionar Del, excluímos o símbolo personalizado criado
      if(TerminalInfoInteger(TERMINAL_KEYSTATE_DELETE)<0)
        {
         if(DeleteCustomSymbol(CUSTOM_SYMBOL_NAME))
            PrintFormat("Custom symbol '%s' deleted successfully", CUSTOM_SYMBOL_NAME);
         break;
        }
     }
//--- antes de sair, limpamos o gráfico
   Comment("");
   /*
   resultado:
   The 'EURUSD' symbol from which the custom 'EURUSD.C' was created:
     Deal execution mode: INSTANT
     Stops Level: 0
     Freeze Level: 0
   Custom symbol 'EURUSD.C' based on 'EURUSD':
     Deal execution mode: MARKET
     Stops Level: 10
     Freeze Level: 3
   */
  }
//+------------------------------------------------------------------+
//| Cria um símbolo personalizado, retorna o código de erro         |
//+------------------------------------------------------------------+
int CreateCustomSymbol(const string symbol_name, const string symbol_path, const string symbol_origin=NULL)
  {
//--- definimos o nome do símbolo usado como base para criar o símbolo personalizado
   string origin=(symbol_origin==NULL ? Symbol() : symbol_origin);

//--- se não for possível criar o símbolo personalizado, e isso não for um erro 5304, informamos no log
   ResetLastError();
   int error=0;
   if(!CustomSymbolCreate(symbol_name, symbol_path, origin))
     {
      error=GetLastError();
      if(error!=5304)
         PrintFormat("CustomSymbolCreate(%s, %s, %s) failed. Error %d", symbol_name, symbol_path, origin, error);
     }
//--- sucesso
   return(error);
  }
//+------------------------------------------------------------------+
//| Exclui o símbolo personalizado                                   |
//+------------------------------------------------------------------+
bool DeleteCustomSymbol(const string symbol_name)
  {
//--- ocultamos o símbolo da janela Observação do Mercado
   ResetLastError();
   if(!SymbolSelect(symbol_name, false))
     {
      PrintFormat("SymbolSelect(%s, false) failed. Error %d", GetLastError());
      return(false);
     }

//--- se não for possível excluir o símbolo personalizado, informamos no log e retornamos false
   ResetLastError();
   if(!CustomSymbolDelete(symbol_name))
     {
      PrintFormat("CustomSymbolDelete(%s) failed. Error %d", symbol_name, GetLastError());
      return(false);
     }
//--- sucesso
   return(true);
  }

Veja também

SymbolInfoInteger

CustomSymbolDelete

CustomSymbolSetDouble