//+------------------------------------------------------------------+
//| CustomRatesDelete.mq5 |
//| Copyright 2024, MetaQuotes Ltd. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#define CUSTOM_SYMBOL_NAME Symbol()+".C" // nome do símbolo personalizado
#define CUSTOM_SYMBOL_PATH "Forex" // nome do grupo onde o símbolo será criado
#define CUSTOM_SYMBOL_ORIGIN Symbol() // nome do símbolo usado como base para a criação do símbolo personalizado
#define DATARATES_COUNT 4 // número de barras a serem exibidas no log
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart()
{
//--- obtemos o código de erro ao criar o símbolo personalizado
int create=CreateCustomSymbol(CUSTOM_SYMBOL_NAME, CUSTOM_SYMBOL_PATH, CUSTOM_SYMBOL_ORIGIN);
//--- se o código de erro não for 0 (criação bem-sucedida do símbolo) e não for 5304 (símbolo já criado), saímos.
if(create!=0 && create!=5304)
return;
//--- obtemos o número de barras do símbolo padrão
int bars=Bars(CUSTOM_SYMBOL_ORIGIN, PERIOD_M1);
//--- obtemos os dados de todas as barras do timeframe de minutos de um símbolo padrão no array MqlRates
MqlRates rates[]={};
ResetLastError();
if(CopyRates(CUSTOM_SYMBOL_ORIGIN, PERIOD_M1, 0, bars, rates)!=bars)
{
PrintFormat("CopyRates(%s, PERIOD_M1, 0, %d) failed. Error %d", CUSTOM_SYMBOL_ORIGIN, bars, GetLastError());
return;
}
//--- definimos os dados copiados para o histórico de minutos do símbolo personalizado
ResetLastError();
if(CustomRatesUpdate(CUSTOM_SYMBOL_NAME, rates)<0)
{
PrintFormat("CustomRatesUpdate(%s) failed. Error %d", CUSTOM_SYMBOL_NAME, GetLastError());
return;
}
//--- após atualizar os dados históricos, obtemos o número de barras do símbolo personalizado
bars=Bars(CUSTOM_SYMBOL_NAME, PERIOD_M1);
//--- obtemos os dados de todas as barras do timeframe de minutos do símbolo personalizado no array MqlRates
ResetLastError();
if(CopyRates(CUSTOM_SYMBOL_NAME, PERIOD_M1, 0, bars, rates)!=bars)
{
PrintFormat("CopyRates(%s, PERIOD_M1, 0, %d) failed. Error %d", CUSTOM_SYMBOL_NAME, bars, GetLastError());
return;
}
//--- imprimimos no log as últimas barras DATARATES_COUNT do histórico de minutos do símbolo personalizado
int digits=(int)SymbolInfoInteger(CUSTOM_SYMBOL_NAME, SYMBOL_DIGITS);
PrintFormat("Last %d bars of the custom symbol's minute history:", DATARATES_COUNT);
ArrayPrint(rates, digits, NULL, bars-DATARATES_COUNT, DATARATES_COUNT);
//--- excluímos as duas penúltimas barras de dados presentes no histórico de minutos do símbolo personalizado
datetime time_from= rates[bars-3].time;
datetime time_to = rates[bars-2].time;
ResetLastError();
int deleted=CustomRatesDelete(CUSTOM_SYMBOL_NAME, time_from, time_to);
if(deleted<0)
{
PrintFormat("CustomRatesDelete(%s) failed. Error %d", CUSTOM_SYMBOL_NAME, GetLastError());
return;
}
//--- após excluir duas barras dos dados históricos, obtemos novamente o número de barras do símbolo personalizado
bars=Bars(CUSTOM_SYMBOL_NAME, PERIOD_M1);
//--- obtemos novamente os dados de todas as barras restantes do timeframe de minutos do símbolo personalizado
ResetLastError();
if(CopyRates(CUSTOM_SYMBOL_NAME, PERIOD_M1, 0, bars, rates)!=bars)
{
PrintFormat("CopyRates(%s, PERIOD_M1, 0, %d) failed. Error %d", CUSTOM_SYMBOL_NAME, bars, GetLastError());
return;
}
//--- imprimimos no log as últimas barras DATARATES_COUNT do histórico de minutos atualizado do símbolo personalizado
PrintFormat("\nLast %d bars after applying CustomRatesDelete() with %d deleted bars:", DATARATES_COUNT, deleted);
ArrayPrint(rates, digits, NULL, bars-DATARATES_COUNT, DATARATES_COUNT);
//--- no comentário do gráfico exibimos a dica sobre as chaves de encerramento do script
Comment(StringFormat("Press 'Esc' to exit or 'Del' to delete the '%s' symbol and exit", CUSTOM_SYMBOL_NAME));
//--- em um loop infinito, esperamos as teclas Esc ou Del para sair
while(!IsStopped() && TerminalInfoInteger(TERMINAL_KEYSTATE_ESCAPE)==0)
{
Sleep(16);
//--- ao pressionar Del, excluímos o símbolo personalizado criado e seus dados
if(TerminalInfoInteger(TERMINAL_KEYSTATE_DELETE)<0)
{
//--- excluímos os dados das barras
int deleted=CustomRatesDelete(CUSTOM_SYMBOL_NAME, 0, LONG_MAX);
if(deleted>0)
PrintFormat("%d history bars of the custom symbol '%s' were successfully deleted", deleted, CUSTOM_SYMBOL_NAME);
//--- excluímos os dados de ticks
deleted=CustomTicksDelete(CUSTOM_SYMBOL_NAME, 0, LONG_MAX);
if(deleted>0)
PrintFormat("%d history ticks of the custom symbol '%s' were successfully deleted", deleted, CUSTOM_SYMBOL_NAME);
//--- excluímos o símbolo
if(DeleteCustomSymbol(CUSTOM_SYMBOL_NAME))
PrintFormat("Custom symbol '%s' deleted successfully", CUSTOM_SYMBOL_NAME);
break;
}
}
//--- antes de sair, limpamos o gráfico
Comment("");
/*
resultado:
Last 4 bars of the custom symbol's minute history:
[time] [open] [high] [low] [close] [tick_volume] [spread] [real_volume]
[0] 2024.06.18 20:53:00 1.07341 1.07347 1.07336 1.07343 38 0 0
[1] 2024.06.18 20:54:00 1.07344 1.07354 1.07344 1.07353 21 0 0
[2] 2024.06.18 20:55:00 1.07353 1.07362 1.07351 1.07356 32 0 0
[3] 2024.06.18 20:56:00 1.07356 1.07358 1.07352 1.07354 24 0 0
Last 4 bars after applying CustomRatesDelete() with 2 deleted bars:
[time] [open] [high] [low] [close] [tick_volume] [spread] [real_volume]
[0] 2024.06.18 20:51:00 1.07357 1.07358 1.07347 1.07349 25 0 0
[1] 2024.06.18 20:52:00 1.07349 1.07350 1.07336 1.07341 31 0 0
[2] 2024.06.18 20:53:00 1.07341 1.07347 1.07336 1.07343 38 0 0
[3] 2024.06.18 20:56:00 1.07356 1.07358 1.07352 1.07354 24 0 0
*/
}
//+------------------------------------------------------------------+
//| Cria um símbolo personalizado, retorna o código de erro |
//+------------------------------------------------------------------+
int CreateCustomSymbol(const string symbol_name, const string symbol_path, const string symbol_origin=NULL)
{
//--- definimos o nome do símbolo usado como base para criar o símbolo personalizado
string origin=(symbol_origin==NULL ? Symbol() : symbol_origin);
//--- se não for possível criar o símbolo personalizado, e isso não for um erro 5304, informamos no log
ResetLastError();
int error=0;
if(!CustomSymbolCreate(symbol_name, symbol_path, origin))
{
error=GetLastError();
if(error!=5304)
PrintFormat("CustomSymbolCreate(%s, %s, %s) failed. Error %d", symbol_name, symbol_path, origin, error);
}
//--- sucesso
return(error);
}
//+------------------------------------------------------------------+
//| Exclui o símbolo personalizado |
//+------------------------------------------------------------------+
bool DeleteCustomSymbol(const string symbol_name)
{
//--- ocultamos o símbolo da janela Observação do Mercado
ResetLastError();
if(!SymbolSelect(symbol_name, false))
{
PrintFormat("SymbolSelect(%s, false) failed. Error %d", GetLastError());
return(false);
}
//--- se não for possível excluir o símbolo personalizado, informamos no log e retornamos false
ResetLastError();
if(!CustomSymbolDelete(symbol_name))
{
PrintFormat("CustomSymbolDelete(%s) failed. Error %d", symbol_name, GetLastError());
return(false);
}
//--- sucesso
return(true);
}
|