MQL5 リファレンス時系列と指標へのアクセスBarsCalculated

BarsCalculated

지정된 지표에 대해 계산된 데이터 수를 반환합니다.

int  BarsCalculated(
   int       indicator_handle,     // 지표 핸들
   );

Parameters

indicator_handle

[in] 지표 핸들, 해당 지표 함수에 의해 반환됩니다.

반환 값

지표 버퍼에서 계산된 데이터 양을 반환하거나 오류 발생 시 -1 (아직 계산되지 않은 데이터)

참고

이 기능은 지표 생성 후 즉시 지표 데이터를 가져와야 할 때 유용합니다(지표 핸들을 사용할 수 있음).

예:

void OnStart()
  {
   double Ups[];
//--- 배열에 대한 시계열 순서 설정
   ArraySetAsSeries(Ups,true);
//--- 프랙탈 지표에 대한 핸들 생성
   int FractalsHandle=iFractals(NULL,0);
//--- 에러 코드를 재설정
   ResetLastError();
//--- 지표값 복사 시도
   int i,copied=CopyBuffer(FractalsHandle,0,0,1000,Ups);
   if(copied<=0)
     {
      Sleep(50);
      for(i=0;i<100;i++)
        {
         if(BarsCalculated(FractalsHandle)>0)
            break;
         Sleep(50);
        }
      copied=CopyBuffer(FractalsHandle,0,0,1000,Ups);
      if(copied<=0)
        {
         Print("상부 프랙탈 복사 실패. Error = ",GetLastError(),
         "i = ",i,"    copied = ",copied);
         return;
        }
       else
         Print("상부 프랙탈 복사됨",
         "i = ",i,"    copied = ",copied);
     }
   else Print("상부 프랙탈 복사됨. ArraySize = ",ArraySize(Ups));
  }

Bars

IndicatorCreate