iTime

해당 차트에서 막대의 오픈 시간('shift' 매개 변수로 표시됨)을 반환합니다.

datetime  iTime(
   const string        symbol,          // 심볼
   ENUM_TIMEFRAMES     timeframe,       // 주기
   int                 shift            // 시프트
   );

Parameters

symbol

[in] 금융상품의 심볼명. NULL은 현재 심볼을 의미합니다.

timeframe

[in] 주기. 이 값은 ENUM_TIMEFRAMES 열거값 중 하나일 수 있습니다. 0은 현재 차트 주기를 의미합니다.

shift

[in] 시계열에서 수신된 값의 인덱스(현재 막대를 기준으로 지정된 막대 수만큼 후진 이동).

반환 값

해당 차트에서 막대의 오픈 시간('shift' 매개 변수로 표시됨) 또는 오류 발생 시 0. 오류 세부사항에 대해선, GetLastError() 함수를 호출하십시오.

참고

이 함수는 항상 실제 데이터를 반환합니다. 이를 위해 각 통화 중에 지정된 심볼/주기에 대한 시계열 요청을 수행합니다. 즉, 첫 번째 기능 호출 중에 준비된 데이터가 없을 경우 결과를 준비하는 데 시간이 걸릴 수 있습니다.

이 함수는 이전 호출 결과를 저장하지 않으며 빠른 값 반환을 위한 로컬 캐시가 없습니다.

예:

//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- 날짜는 일요일입니다.
   datetime time=D'2018.06.10 12:00';
   string symbol="GBPUSD";
   ENUM_TIMEFRAMES tf=PERIOD_H1;
   bool exact=false;
//--- 지정된 시간에 막대가 없습니다. iBarShift가 가장 가까운 막대의 색인을 반환합니다.
   int bar_index=iBarShift(symbol,tf,time,exact);
   PrintFormat("1. %s %s %s(%s): bar index is %d (exact=%s)",
               symbol,EnumToString(tf),TimeToString(time),DayOfWeek(time),bar_index,string(exact));
   datetime bar_time=iTime(symbol,tf,bar_index);
   PrintFormat("Time of bar #%d is %s (%s)",
               bar_index,TimeToString(bar_time),DayOfWeek(bar_time));
//PrintFormat(iTime(symbol,tf,bar_index));
//--- 지정된 시간으로 막대 색인을 요청하지만 막대가 없으므로 -1을 반환합니다
   exact=true;
   bar_index=iBarShift(symbol,tf,time,exact);
   PrintFormat("2. %s %s %s (%s):bar index is %d (exact=%s)",
               symbol,EnumToString(tf),TimeToString(time),DayOfWeek(time),bar_index,string(exact));
  }
//+------------------------------------------------------------------+
//| 주의 요일 이름을 반환합니다                          |
//+------------------------------------------------------------------+
string DayOfWeek(const datetime time)
  {
   MqlDateTime dt;
   string day="";
   TimeToStruct(time,dt);
   switch(dt.day_of_week)
     {
      case 0: day=EnumToString(SUNDAY);
      break;
      case 1: day=EnumToString(MONDAY);
      break;
      case 2: day=EnumToString(TUESDAY);
      break;
      case 3: day=EnumToString(WEDNESDAY);
      break;
      case 4: day=EnumToString(THURSDAY);
      break;
      case 5: day=EnumToString(FRIDAY);
      break;
      default:day=EnumToString(SATURDAY);
      break;
     }
//---
   return day;
  }
/* The result:
   1. GBPUSD PERIOD_H1 2018.06.10 12:00(SUNDAY): bar index is 64 (exact=false)
   Time of bar #64 is 2018.06.08 23:00 (FRIDAY)
   2. GBPUSD PERIOD_H1 2018.06.10 12:00 (SUNDAY):bar index is -1 (exact=true)
*/

CopyTime, CopyRates

iOpen

iTickVolume