콘솔형 차트 텍스트 출력에 최적화된 디스플레이 - MetaTrader 5용 라이브러리

라이브러리에는 두 가지 유형의 디스플레이가 있습니다. 첫 번째인 LabelsDisplay는 CChartObjectLabel을 기반으로 합니다. 두 번째인 캔버스 디스플레이는 CCanvas를 기반으로 합니다. 이 디스플레이는 렌더링 빈도에 최적화되어 있습니다. 디스플레이 Demo.mq5의 작업을 시연하는 기본 전문가 어드바이저 외에, 테스터에서만 틱에 대한 측정을 수행하는 두 가지 변형인 CanvasVsLabelsTester.mq5가 더 있습니다. 그리고 테스터와 차트 모두에서 측정을 수행하는 범용 CanvasVsLabels.mq5가 있습니다. 이러한 측정값은 서로 비교할 수 있습니다. 디스플레이 속도 비교에 대한 자세한 내용은 캔버스 대 레이블 링크를 참조하세요.

//+------------------------------------------------------------------+
//|ChartDisplayDemo.mq5 |
//|Copyright 2021, © Cyberdev |
//| https://www.mql5.com/en/users/cyberdev/seller |
//+------------------------------------------------------------------+
#property copyright "저작권 2021, © Cyberdev."
#property link      "https://www.mql5.com/en/users/cyberdev/seller"
#property version   "1.00"

//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
#include "cyberdev\ChartDisplay.mqh"

//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
enum OutType { 
  otCanvas, // 캔버스
  otLabels  // 레이블
};

//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
input OutType outType = otLabels; // outType - 표시 유형
input int nLines = 50; // nLines - 디스플레이의 줄 수
input bool optimizeUpdate = false; // 최적화 업데이트 - 레이블 최적화
input int bWidth = 406; // b폭 - 표시 너비
input int lY_Dist = 14; // lY_Dist - 선 사이의 거리
input bool back = false; // 뒤로 - 레이블의 배경

//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
Strings * display;
CChart Chart;

//+------------------------------------------------------------------+
//| 전문가 초기화 기능|
//+------------------------------------------------------------------+
int OnInit() {
  Chart.Attach(ChartID());
  Chart.ShowGrid(false);
  Chart.ColorBackground(C'194,231,197');
  Chart.ColorBarUp(clrDodgerBlue);
  Chart.ColorBarDown(clrBlueViolet);
  Chart.ColorCandleBull(clrDodgerBlue);
  Chart.ColorCandleBear(clrBlueViolet);
  Chart.ColorForeground(clrBlack);
  switch (outType) {
  case otCanvas:
    display = new CanvasDisplay();
    break;
  case otLabels:
    display = new LabelsDisplay();
    break;
  default:
    return INIT_FAILED;
  }
  if ((outType == otLabels && back &&
       !dynamic_cast<LabelsDisplay *>(display).createExt(nLines, 10, 10, bWidth, lY_Dist)) || 
       !display.create(nLines, 10, 15, bWidth, lY_Dist))
    return INIT_FAILED;
  return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| 전문가 초기화 기능|
//+------------------------------------------------------------------+
void OnDeinit(const int reason) {
  if (CheckPointer(display) == POINTER_DYNAMIC)
    delete display;
  Chart.Detach();
}

//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
#define  concatenate(_rate)                                                         \
 ("Open: " + DoubleToString(rates[_rate].open, digits) +                           \
  "; High: " + DoubleToString(rates[_rate].high, digits) +                         \
  "; Low: " + DoubleToString(rates[_rate].low, digits) +                           \
  "; Close: " + DoubleToString(rates[_rate].close, digits) + ".")   
  

//+------------------------------------------------------------------+
//| 전문가 틱 기능|
//+------------------------------------------------------------------+
void OnTick() {
  MqlRates rates[];
  int digits = (int)SymbolInfoInteger(_Symbol, SYMBOL_DIGITS);
  static datetime time = 0;
  datetime cTime;
  static bool firstRun = true;
  bool triggered = false;
  if (CopyRates(NULL, PERIOD_CURRENT, 0, 2, rates) != 2)
    return;
  display.setText(concatenate(1));
  cTime = rates[0].time;
  if (cTime != time) {
    if (!firstRun) {
      display.push();
      display.setText(concatenate(0));
    }
    time = cTime;
    firstRun = false;
    triggered = true; 
  }
  if(outType == otLabels && optimizeUpdate) {
    if (triggered)
      display.update();
    else
      dynamic_cast<LabelsDisplay *>(display).updateOne();
  }
  else
    display.update();
}
//+------------------------------------------------------------------+

위쪽 줄을 업데이트하려면 사용 중인 클래스의 setText 메서드를 호출해야 합니다. 텍스트를 아래 줄로 이동하려면 사용한 클래스의 push 메서드를 호출합니다. 그리고 추가/업데이트된 텍스트를 디스플레이에 표시하려면 클래스의 업데이트 메서드를 사용합니다. 이 메서드 외에도 LabelsDisplay 클래스에는 디스플레이 속도를 두 배 이상 높일 수 있는 updateOne 메서드가 추가로 있습니다 . 이 메서드는 맨 위 줄을 업데이트해야 할 때만 호출됩니다. 푸시 메서드가 호출된 경우 그 후에는 updateOne 대신 업데이트 메서드를 호출해야 합니다 .

입력 매개변수

따라서 차트에 5가지 모드로 정보를 표시할 수 있습니다.

1. 캔버스
2. 레이블
3. 텍스트출력이 최적화된 레이블
4. 캔버스 배경이 있는 레이블
5. 배경, 플러스, 최적화가있는 레이블

outType: 레이블 모드에서 배경을 사용하면 다른 추가 차트 개체를 사용하는 것과 거의 동일한 부하가 발생합니다. 즉, 디스플레이에 텍스트를 출력하는 데 걸리는 시간이 약간 늘어납니다.