针对控制台类型的图表文本输出进行了优化显示 - MetaTrader 5程序库

该库包含两种类型的显示。第一种是基于CChartObjectLabel 的LabelsDisplay 。第二种是 基于 CCanvas 的 CanvasDisplay。这些显示均针对渲染频率进行了优化。除了演示 Demo.mq5 显示器工作的主 Expert Advisor 之外，还有两个变体：CanvasVsLabelsTester.mq5，用于仅在测试器中对刻度进行测量。而通用CanvasVsLabels.mq5 则可在测试仪和图表中执行测量。有关比较显示速度的详细信息，请参阅Canvas vs Labels 链接。

//+------------------------------------------------------------------+
//|ChartDisplayDemo.mq5
//|版权所有 2021, © Cyberdev ||
//| https://www.mql5.com/en/users/cyberdev/seller |
//+------------------------------------------------------------------+
#property copyright "版权 2021 年，© Cyberdev"。
#property link      "https://www.mql5.com/en/users/cyberdev/seller"
#property version   "1.00"

//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
#include "cyberdev\ChartDisplay.mqh"

//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
enum OutType { 
  otCanvas, // 帆布
  otLabels  // 标签
};

//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
input OutType outType = otLabels; // outType - 显示类型
input int nLines = 50; // nLines - 显示屏行数
input bool optimizeUpdate = false; // optimiseUpdate - 标签优化
input int bWidth = 406; // bWidth - 显示宽度
input int lY_Dist = 14; // lY_Dist - 线间距离
input bool back = false; // 背面 - 标签背景

//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
Strings * display;
CChart Chart;

//+------------------------------------------------------------------+
//| 专家初始化函数|
//+------------------------------------------------------------------+
int OnInit() {
  Chart.Attach(ChartID());
  Chart.ShowGrid(false);
  Chart.ColorBackground(C'194,231,197');
  Chart.ColorBarUp(clrDodgerBlue);
  Chart.ColorBarDown(clrBlueViolet);
  Chart.ColorCandleBull(clrDodgerBlue);
  Chart.ColorCandleBear(clrBlueViolet);
  Chart.ColorForeground(clrBlack);
  switch (outType) {
  case otCanvas:
    display = new CanvasDisplay();
    break;
  case otLabels:
    display = new LabelsDisplay();
    break;
  default:
    return INIT_FAILED;
  }
  if ((outType == otLabels && back &&
       !dynamic_cast<LabelsDisplay *>(display).createExt(nLines, 10, 10, bWidth, lY_Dist)) || 
       !display.create(nLines, 10, 15, bWidth, lY_Dist))
    return INIT_FAILED;
  return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| 专家去初始化函数|
//+------------------------------------------------------------------+
void OnDeinit(const int reason) {
  if (CheckPointer(display) == POINTER_DYNAMIC)
    delete display;
  Chart.Detach();
}

//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
#define  concatenate(_rate)                                                         \
 ("Open: " + DoubleToString(rates[_rate].open, digits) +                           \
  "; High: " + DoubleToString(rates[_rate].high, digits) +                         \
  "; Low: " + DoubleToString(rates[_rate].low, digits) +                           \
  "; Close: " + DoubleToString(rates[_rate].close, digits) + ".")   
  

//+------------------------------------------------------------------+
//| 专家勾选功能|
//+------------------------------------------------------------------+
void OnTick() {
  MqlRates rates[];
  int digits = (int)SymbolInfoInteger(_Symbol, SYMBOL_DIGITS);
  static datetime time = 0;
  datetime cTime;
  static bool firstRun = true;
  bool triggered = false;
  if (CopyRates(NULL, PERIOD_CURRENT, 0, 2, rates) != 2)
    return;
  display.setText(concatenate(1));
  cTime = rates[0].time;
  if (cTime != time) {
    if (!firstRun) {
      display.push();
      display.setText(concatenate(0));
    }
    time = cTime;
    firstRun = false;
    triggered = true; 
  }
  if(outType == otLabels && optimizeUpdate) {
    if (triggered)
      display.update();
    else
      dynamic_cast<LabelsDisplay *>(display).updateOne();
  }
  else
    display.update();
}
//+------------------------------------------------------------------+

要更新顶行，需要调用所用类的 setText 方法。要将文本移到下一行，需要调用所用类 的 push 方法。要在显示屏上显示添加/更新的文本，可使用任何一个类的 update 方法。除此方法外 ， LabelDisplay 类还有一个 updateOne方法 ，可将显示速度提高 2 倍以上。只有在需要更新顶行时才会调用该方法。如果调用了 push 方法，那么在此之后应调用update 方法，而不是 updateOne。

输入参数

因此，可以用 5 种不同的模式在图表中显示信息。

1. 画布
2. 标签
3. 优化 文本输出的标签
4. 带画布 背景的标签
5. 带背景、外加优化的标签

在 outType: Labels 模式下使用背景与使用其他附加图表对象的负载大致相同。也就是说，它会略微增加向显示屏输出文本所需的时间。