コンソール・タイプのチャート・テキスト出力に最適化された表示 - MetaTrader 5のためのライブラリ

このライブラリには2種類の表示がある。1つ目のLabelsDisplayは CChartObjectLabelに基づいて いる。もう1つの CanvasDisplayはCCanvasをベースにしている。これらのディスプレイはレンダリング頻度に最適化されている。Demo.mq5ディスプレイの動作をデモするメインのExpert Advisorの他に、テスターでティックのみの計測を行うCanvasVsLabelsTester.mq5という2つのバリエーションがあります。ユニバーサルなCanvasVsLabels.mq5は、テスターとチャートの両方で測定を行います。表示速度の比較の詳細については、リンク「Canvas vs Labels」をご覧ください。

//+------------------------------------------------------------------+
//|ChartDisplayDemo.mq5
//|著作権 2021, © Cyberdev｜サイバーデブ
//| https://www.mql5.com/en/users/cyberdev/seller
//+------------------------------------------------------------------+
#property copyright "Copyright 2021, © Cyberdev."
#property link      "https://www.mql5.com/en/users/cyberdev/seller"
#property version   "1.00"

//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
#include "cyberdev\ChartDisplay.mqh"

//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
enum OutType { 
  otCanvas, // キャンバス
  otLabels  // ラベル
};

//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
input OutType outType = otLabels; // outType - 表示タイプ
input int nLines = 50; // nLines - ディスプレイの行数。
input bool optimizeUpdate = false; // optimiseUpdate - ラベルの最適化
input int bWidth = 406; // bWidth - 表示幅
input int lY_Dist = 14; // lY_Dist - 線間の距離．
input bool back = false; // 背面 - ラベルの背景

//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
Strings * display;
CChart Chart;

//+------------------------------------------------------------------+
//| エキスパート初期化関数|
//+------------------------------------------------------------------+
int OnInit() {
  Chart.Attach(ChartID());
  Chart.ShowGrid(false);
  Chart.ColorBackground(C'194,231,197');
  Chart.ColorBarUp(clrDodgerBlue);
  Chart.ColorBarDown(clrBlueViolet);
  Chart.ColorCandleBull(clrDodgerBlue);
  Chart.ColorCandleBear(clrBlueViolet);
  Chart.ColorForeground(clrBlack);
  switch (outType) {
  case otCanvas:
    display = new CanvasDisplay();
    break;
  case otLabels:
    display = new LabelsDisplay();
    break;
  default:
    return INIT_FAILED;
  }
  if ((outType == otLabels && back &&
       !dynamic_cast<LabelsDisplay *>(display).createExt(nLines, 10, 10, bWidth, lY_Dist)) || 
       !display.create(nLines, 10, 15, bWidth, lY_Dist))
    return INIT_FAILED;
  return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
|エキスパート初期化関数|
//+------------------------------------------------------------------+
void OnDeinit(const int reason) {
  if (CheckPointer(display) == POINTER_DYNAMIC)
    delete display;
  Chart.Detach();
}

//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
#define  concatenate(_rate)                                                         \
 ("Open: " + DoubleToString(rates[_rate].open, digits) +                           \
  "; High: " + DoubleToString(rates[_rate].high, digits) +                         \
  "; Low: " + DoubleToString(rates[_rate].low, digits) +                           \
  "; Close: " + DoubleToString(rates[_rate].close, digits) + ".")   
  

//+------------------------------------------------------------------+
//| エキスパート・ティック機能|
//+------------------------------------------------------------------+
void OnTick() {
  MqlRates rates[];
  int digits = (int)SymbolInfoInteger(_Symbol, SYMBOL_DIGITS);
  static datetime time = 0;
  datetime cTime;
  static bool firstRun = true;
  bool triggered = false;
  if (CopyRates(NULL, PERIOD_CURRENT, 0, 2, rates) != 2)
    return;
  display.setText(concatenate(1));
  cTime = rates[0].time;
  if (cTime != time) {
    if (!firstRun) {
      display.push();
      display.setText(concatenate(0));
    }
    time = cTime;
    firstRun = false;
    triggered = true; 
  }
  if(outType == otLabels && optimizeUpdate) {
    if (triggered)
      display.update();
    else
      dynamic_cast<LabelsDisplay *>(display).updateOne();
  }
  else
    display.update();
}
//+------------------------------------------------------------------+

一番上の行を更新するには、使用しているクラスの setText メソッドを呼び出す必要があります。下の行にテキストを移動するには、使用する クラスのpushメソッドを呼び出します。そして、追加／更新されたテキストをディスプレイに表示するには、いずれかのクラスのupdateメソッドを使います。このメソッドに加えて 、 LabelsDisplay クラスには updateOneメソッドがあり 、表示を2倍以上速くすることができる。このメソッドは、最上行を更新する必要がある場合にのみ呼び出される。もしpushメソッドが呼ばれたなら、その後にupdateOneの代わりにupdate メソッドを呼ぶべきである 。

入力パラメーター

このように、5つの異なるモードでチャートに情報を表示することができます。

1. キャンバス
2. ラベル
3. 最適化された テキスト出力のラベル
4. キャンバス 背景付きラベル
5. 背景付きラベル、プラス、最適化

outType: Labelsモードで背景を使用すると、他の追加チャート・オブジェクトを使用するのとほぼ同じ負荷がかかります。つまり、ディスプレイへのテキスト出力にかかる時間がわずかに増加します。