Référence MQL5Accès aux Séries de Données et aux IndicateursiTime

iTime

Retourne l'heure d'ouverture de la barre (indiquée par le paramètre 'shift') sur le graphique correspondant.

datetime  iTime(
   const string        symbol,          // Symbole
   ENUM_TIMEFRAMES     timeframe,       // Période
   int                 shift            // Décalage
   );

Parameters

symbol

[in] Le nom du symbole de l'instrument financier. NULL signifie le symbole courant.

timeframe

[in] Période. Peut être l'une des valeurs de l'énumération ENUM_TIMEFRAMES. 0 signifie la période actuelle du graphique.

shift

[in] L'indice de la valeur reçue des timeseries (décalage en arrière du nombre spécifié de barres relativement à la barre courante).

Valeur de Retour

L'heure d'ouverture de la barre (indiquée avec le paramètre 'shift') sur le graphique correspondant ou 0 en cas d'erreur. Pour connaître les détails de l'erreur, appelez la fonction GetLastError().

Note

La fonction retourne toujours les données actuelles. Pour cela, elle effectue une demande à la timeserie pour le symbole et la période spécifiés à chaque appel. Cela signifie que s'il n'y a pas de données prêtes au premier appel à la fonction, la préparation des résultats peut prendre un peu de temps.

La fonction ne stocke pas les résultats des appels précédents, et il n'y a pas de cache local pour un retour rapide de la valeur.

Exemple :

//+------------------------------------------------------------------+
//| Fonction de démarrage du script                                  |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- La date est un dimanche
   datetime time=D'2018.06.10 12:00';
   string symbol="GBPUSD";
   ENUM_TIMEFRAMES tf=PERIOD_H1;
   bool exact=false;
//--- il n'y a pas de barre à l'heure spécifiée, iBarShift retournera l'indice de la barre la plus proche
   int bar_index=iBarShift(symbol,tf,time,exact);
   PrintFormat("1. %s %s %s(%s): l'indice de la barre est %d (exact=%s)",
               symbol,EnumToString(tf),TimeToString(time),DayOfWeek(time),bar_index,string(exact));
   datetime bar_time=iTime(symbol,tf,bar_index);
   PrintFormat("L'heure de la barre #%d est %s (%s)",
               bar_index,TimeToString(bar_time),DayOfWeek(bar_time));
//PrintFormat(iTime(symbol,tf,bar_index));
//--- Demande l'indice de la barre à la date spécifiée : mais il n'y a pas de barre, retourne -1
   exact=true;
   bar_index=iBarShift(symbol,tf,time,exact);
   PrintFormat("2. %s %s %s (%s):l'indice de la barre est %d (exact=%s)",
               symbol,EnumToString(tf),TimeToString(time),DayOfWeek(time),bar_index,string(exact));
  }
//+------------------------------------------------------------------+
//| Retourne le nom du jour de la semaine                            |
//+------------------------------------------------------------------+
string DayOfWeek(const datetime time)
  {
   MqlDateTime dt;
   string day="";
   TimeToStruct(time,dt);
   switch(dt.day_of_week)
     {
      case 0: day=EnumToString(DIMANCHE);
      break;
      case 1: day=EnumToString(LUNDI);
      break;
      case 2: day=EnumToString(MARDI);
      break;
      case 3: day=EnumToString(MERCREDI);
      break;
      case 4: day=EnumToString(JEUDI);
      break;
      case 5: day=EnumToString(VENDREDI);
      break;
      default:day=EnumToString(SAMEDI);
      break;
     }
//---
   return day;
  }
/* Le résultat:
  1. GBPUSD PERIOD_H1 2018.06.10 12:00(DIMANCHE): l'indice de la barre est 64 (exact=false)
  L'heure de la barre #64 est 2018.06.08 23:00 (VENDREDI)
  2. GBPUSD PERIOD_H1 2018.06.10 12:00 (DIMANCHE):l'indice de la barre est -1 (exact=true)
*/

Voir également

CopyTime, CopyRates

iOpen

iTickVolume