DocumentationSections
Référence MQL5Variables Globales du TerminalGlobalVariablesDeleteAll 

GlobalVariablesDeleteAll

Supprime les variables globales du terminal de client.

int  GlobalVariablesDeleteAll(
   string     prefix_name=NULL      // toutes les variables globales, dont les noms commencent par le préfixe
   datetime   limit_data=0          // toutes les variables globales, qui changeaient avant la date indiquée
   );

Paramètres

prefix_name=NULL

[in]  Le préfixe du nom des variables globales supprimées. Si on indique le préfixe NULL ou la chaîne vide, toutes les variables globales conviennent  au critère de l'effacement ,correspondantes au critère de l'effacement selon la date

limit_data=0

[in]  La date pour la sélection des variables globales par le temps de la dernière modification. Les variables globales se suppriment, qui changeaient avant la date indiquée. Si le paramètre est égal au zéro, toutes les variables globales, correspondantes au premier critère (selon le préfixe) se suppriment.

La valeur rendue

Le nombre de variables supprimées.

Note

Si les deux paramètres sont égaux au zéro (prefix_name=NULL et limit_data=0),toutes les variables globales du terminal se suppriment. Si on indique les deux paramètres, se suppriment les variables globales correspondantes simultanément à chacun des paramètres indiqués.

Les variables globales existent dans le terminal de client les 4 semaines dès le moment du dernier appel, après cela elles se suppriment automatiquement.

 

Exemple :

#property copyright "Copyright 2025, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#property script_show_inputs
 
#property description   "Le script supprime les variables globales du terminal client."
#property description   "Date limite : les variables avant la date spécifiée sont supprimées."
#property description   "Si la valeur est zéro, les variables qui correspondent au critère de préfixe de nom sont supprimées."
#property description   "Préfixe du nom : Préfixe du nom de la variable. Si elles ne sont pas spécifiées, les variables sont supprimées en fonction du critère Date limite."
#property description   "Si tous les paramètres d'entrée sont nuls, alors toutes les variables globales sont supprimées."
#property description   "Si les deux paramètres sont spécifiés, alors les variables globales correspondant à chacun des paramètres spécifiés sont supprimées."
 
//--- variables d'entrée
input datetime InpLimitDate=  0;       // date limite
input string   InpPrefix   =  NULL;    // préfixe du nom
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- obtient le nombre total de variables globales du terminal client,
//--- supprime les variables conformément aux critères de suppression sélectionnés dans les paramètres du script et
//--- imprime le résultat de la suppression dans le journal
   int total=GlobalVariablesTotal();
   int deleted=GlobalVariablesDeleteAll(InpPrefix, InpLimitDate);
   PrintFormat("Of %d global variables, %d have been removed. %d remain", total, deleted, total-deleted);
   /*
   résultat :
   Of 21 global variables, 21 have been removed. 0 remain
   */
  }