Watch how to download trading robots for free
Find us on Telegram!
Join our fan page
Interesting script?
So post a link to it -
let others appraise it
You liked the script? Try it in the MetaTrader 5 terminal
Experts

MQL5 Wizard - Trade Signals Based on Bullish Engulfing/Bearish Engulfing + CCI - expert for MetaTrader 5

Views:
7368
Rating:
(20)
Published:
2011.03.10 10:54
Updated:
2016.11.22 07:32
\MQL5\Include\Expert\Signal\MySignals\
acbe_be_cci.mqh (7.99 KB) view
Need a robot or indicator based on this code? Order it on Freelance Go to Freelance

The MQL5 Wizard allows creating ready-made Expert Advisors based on the Standard library classes delivered together with the client terminal (see Creating Ready-Made Expert Advisors in MQL5 Wizard for the details). It allows to check your trade ideas quickly, all you need is to create your own trading signals class. The structure of this class and example can be found in the article MQL5 Wizard: How to Create a Module of Trading Signals.

The generic idea is the following: the class of trading signals is derived from CExpertSignal, the next, it's necessary to override the LongCondition() and ShortCondition() virtual methods with your own methods.

There is a book "Strategies of best traders" (in Russian), there are many trading strategies are considered there, we will focus on reversal candlestick patterns, confirmed by Stochastic, CCI, MFI and RSI oscillators.

The best way is to create the separate class, derived from CExpertSignal for checking of formation of candlestick patterns. For confirmation of trade signals, generated by candlestick patterns, it's sufficient to write the class, derived from CCandlePattern and add the necessary features (for example, confirmation by oscillators) there.

Here we will consider the signals, based "Bullish Engulfing/Bearish Engulfing" reversal candlestick pattern, confirmed by CCI indicator. The module of trade signals is based on the CCandlePattern class, it's simple example of its use for creation of trade signals with candlestick patterns.


1. "Bullish Engulfing" and "Bearish Engulfing" reversal candlestick patterns

1.1. Bullish Engulfing

"Bullish Engulfing" reversal pattern forms in downtrend when a small black candlestick if followed by a large white candlestick that completely eclipses ("engulfs") the candlestick of the previous day. The shadows (tails) of the small candlestick are short, which enables the body of the large candlestick to cover the entire candlestick from the previous day.

Fig. 1. "Bullish Engulfing" candlestick pattern

Fig. 1. "Bullish Engulfing" candlestick pattern

The recognition of "Bullish Engulfing" pattern is implemented in CheckPatternBullishEngulfing() method of CCandlePattern class:

//+------------------------------------------------------------------+
//| Checks formation of "Bullish Engulfing" candlestick pattern      |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBullishEngulfing()
  {
//--- Bullish Engulfing
   if((Open(2)>Close(2))             &&  // previous candle is bearish
      (Close(1)-Open(1)>AvgBody(1))  &&  // body of the bullish candle is higher than average value of the body 
      (Close(1)>Open(2))             &&  // close price of the bullish candle is higher than open price of the bearish candle
      (MidOpenClose(2)<CloseAvg(2))  &&  // downtrend
      (Open(1)<Close(2)))                // open price of the bullish candle is lower than close price of the bearish
      return(true);
//---
   return(false);
  }

The CheckCandlestickPattern(CANDLE_PATTERN_BULLISH_ENGULFING) method of CCandlePattern class is used to check formation of "Bullish Engulfing" candlestick pattern.


1.2. Bearish Engulfing

"Bearish Engulfing" reversal pattern forms in uptrend when a small white candlestick if followed by a large black candlestick that completely eclipses ("engulfs") the candlestick of the previous day. The shadows (tails) of the small candlestick are short, which enables the body of the large candlestick to cover the entire candlestick from the previous day.

Fig. 2. "Bearish Engulfing" candlestick pattern

Fig. 2. "Bearish Engulfing" candlestick pattern

The recognition of "Bearish Engulfing" pattern is implemented in CheckPatternBearishEngulfing() method of CCandlePattern class:

//+------------------------------------------------------------------+
//| Checks formation of "Bearish Engulfing" candlestick pattern      |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBearishEngulfing()
  {
//--- Bearish Engulfing
   if((Open(2)<Close(2))            &&  // previous candle is bearish
      (Open(1)-Close(1)>AvgBody(1)) &&  // body of the candle is higher than average value of the body
      (Close(1)<Open(2))            &&  // close price of the bearish candle is lower than open price of the bullish candle
      (MidOpenClose(2)>CloseAvg(2)) &&  // uptrend
      (Open(1)>Close(2)))               // Open price of the bearish candle is higher than close price of the bullish candle
      return(true);
//---
   return(false);
  }

The CheckCandlestickPattern(CANDLE_PATTERN_BEARISH_ENGULFING) method of CCandlePattern class is used to check formation of "Bearish Engulfing" candlestick pattern.


2. Trade signals, confirmed by CCI indicator

The trading signals to open long or short position must be confirmed by CCI indicator. The value of CCI must be greater/lower than critical levels (-50 for long position and 50 for short position).

The closing of opened position depends on the values of CCI. It can be done in 2 cases:

  1. if CCI line has reached the opposite critical level (80 for long position and -80 for short position)
  2. if the reverse signal isn't confirmed (when CCI reaches the following levels: -80 for long position and 80 for short position)

Fig. 3. "Bullish Englulfing" pattern, confirmed by CCI indicator

Fig. 3. "Bullish Englulfing" pattern, confirmed by CCI indicator


  • int CBE_BE_CCI::LongCondition() - checks conditions to open long position (returns 80) and close of the short position (returns 40);
  • int CBE_BE_CCI::ShortCondition() - checks conditions to open short position (returns 80) and close of the long position (returns 40).

2.1. Open long position/Close short position

  1. The formation of "Bullish Engulfing" pattern must be confirmed by CCI indicator: CCI(1)<-50 (the value of the CCI of the last completed bar must be less than -50).

  2. The short position must be closed if the CCI indicator has crossed upward the critical level -80 or crossed downward the critical level 80.

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open long position, result=80)                  |
//| 2) Market exit (close short position, result=40)                 |
//+------------------------------------------------------------------+
int CBE_BE_CCI::LongCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open long position
//--- formation of Bullish Engulfing pattern and CCI<-50
   if(CheckCandlestickPattern(CANDLE_PATTERN_BULLISH_ENGULFING) && (CCI(1)<-50))
     result=80;
//--- checking of conditions to close short position
//--- signal line crossover of overbought/oversold levels (downward -80, downward -80)
   if(((CCI(1)>-80) && (CCI(2)<-80)) || ((CCI(1)<80) && (CCI(2)>80)))
     result=40;
//--- return result
   return(result);
  }

2.2. Open short position/Close long position

  1. The formation of "Bearish Engulfing" pattern must be confirmed by CCI indicator: CCI(1)>50 (the value of the CCI indicator of the last completed bar must be greater than 50).

  2. The long position must be closed if CCI indicator has crossed downward the -80 or 80 levels.

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open short position, result=80)                 |
//| 2) Market exit (close long position, result=40)                  |
//+------------------------------------------------------------------+
int CBE_BE_CCI::ShortCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open short position
//--- formation of Bearish Engulfing pattern and CCI>50
   if(CheckCandlestickPattern(CANDLE_PATTERN_BEARISH_ENGULFING) && (CCI(1)>50))
     result=80;
//--- checking of conditions to close long position
//--- signal line crossover of overbought/oversold levels (downward -80, downward 80)
   if(((CCI(1)<80) && (CCI(2)>80)) || ((CCI(1)<-80) && (CCI(2)>-80)))
     result=40;
//--- return result
   return(result);
  }


2.3. Creating Expert Advisor using MQL5 Wizard

The CBE_BE_CCI class isn't included in the Standard Library classes, to use it, it's necessary to download the acbe_be_cci.mqh file (see attachments) and save it to the client_terminal_data\folder\MQL5\Include\Expert\Signal\MySignals. The same should be done with the candlepatterns.mqh file. You can use it in MQL5 Wizard after restart of the MetaEditor.

To create an Expert Advisor launch MQL5 Wizard:

Fig. 4. Creating Expert Advisor using MQL5 Wizard

Fig. 4. Creating Expert Advisor using MQL5 Wizard

Let's specify the name of the Expert Advisor:

Fig. 5. General properties of the Expert Advisor

Fig. 5. General properties of the Expert Advisor

After that we need to select the modules of trade signals used.

Fig. 6. Signal properties of the Expert Advisor

Fig. 6. Signal properties of the Expert Advisor

In our case we use only one module of trade signals.

Adding the "Signals based on Bullish Engulfing/Bearish Engulfing confirmed by CCI" module of trading signals:

Fig. 7. Signal properties of the Expert Advisor

Fig. 7. Signal properties of the Expert Advisor

Module of trade signals added:

Fig. 8. Signal properties of the Expert Advisor

Fig. 8. Signal properties of the Expert Advisor

You can select any trailing properties, but we will use "Trailing Stop not used":

Fig. 9. Trailing properties of the Expert Advisor

Fig. 9. Trailing properties of the Expert Advisor

Concerning the money management properties, we will use "Trading with fixed trade volume":

Fig. 10. Money management properties of the Expert Advisor

Fig. 10. Money management properties of the Expert Advisor

By pressing the "Finish" button, we will get the code of the generated Expert Advisor, located in Expert_ABE_BE_CCI.mq5, it will be saved in terminal_data_folder\MQL5\Experts\.

The default input parameters of the generated Expert Advisor:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =10;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =50.0;   // Stop Loss level (in points)
input double         Signal_TakeLevel       =50.0// Take Profit level (in points)

must be replaced to:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =20;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =0.0;    // Stop Loss level (in points)
input double         Signal_TakeLevel       =0.0;    // Take Profit level (in points)

The Signal_ThresholdOpen/Signal_ThresholdClose input parameters allow to specify threshold levels for open and close of positions.

In code of the LongCondition() and ShortCondition() methods of the trade signals class we have specified the fixed values of the threshold:

  • Open position: 80;
  • Close position: 40.

The Expert Advisor, generated by MQL5 Wizard open and close position using the "votes" from the modules of trade signals. The vote of the main module (as container, it consist of all the modules added) is also used, but its LongCondition() and ShortCondition() methods always return 0.

The vote results of the main module is also used in "votes" averaging. In our case we have:  main module + 1 module of trade signals, so we need to take this fact into account when setting of the threshold values. Because of this fact the ThresholdOpen and ThresholdClose must be set as 40=(0+80)/2 and 20=(0+40)/2.

The values of Signal_StopLevel and Signal_TakeLevel input parameters is set to 0, it means that closing of the positions will be done only when closing conditions will be true.


2.4. History backtesting results

Let's consider backtesting of the Expert Advisor on historical data (EURUSD H1, testing period: 2010.01.01-2011.03.16, PeriodCCI=49, MA_period=11).

In creation of Expert Advisor we used the fixed volume (Trading Fixed Lot, 0.1), Trailing Stop algorithm is not used (Trailing not used).

Fig. 11. Testing results of the Expert Advisor, based on Bullish Engulfing/Bearish Engulfing + CCI

Fig. 11. Testing results of the Expert Advisor, based on Bullish Engulfing/Bearish Engulfing + CCI


The best set of input parameters can be found using the Strategy Tester of MetaTrader 5 client terminal.

The code of the Expert Advisor, created by MQL5 Wizard is attached in expert_abe_be_cci.mq5.


Translated from Russian by MetaQuotes Ltd.
Original code: https://www.mql5.com/ru/code/306

MQL5 Wizard - Trade Signals Based on Bullish Engulfing/Bearish Engulfing + Stochastic MQL5 Wizard - Trade Signals Based on Bullish Engulfing/Bearish Engulfing + Stochastic

Trade signals based on "Bullish Engulfing/Bearish Engulfing" candlestick pattern, confirmed by Stochastic indicator is considered. The code of the Expert Advisor based on this strategy can be generated automatically using the MQL5 Wizard.

CDownLoadHistory class CDownLoadHistory class

The CDownLoadHistory class provides the methods of historical data downloading.

MQL5 Wizard - Trade Signals Based on Bullish Engulfing/Bearish Engulfing + MFI MQL5 Wizard - Trade Signals Based on Bullish Engulfing/Bearish Engulfing + MFI

Trade signals based on "Bullish Engulfing/Bearish Engulfing" candlestick pattern, confirmed by Market Facilitation Index (MFI) indicator is considered. The code of the Expert Advisor based on this strategy can be generated automatically using the MQL5 Wizard.

MQL5 Wizard - Trade Signals Based on Bullish Engulfing/Bearish Engulfing + RSI MQL5 Wizard - Trade Signals Based on Bullish Engulfing/Bearish Engulfing + RSI

Trade signals based on "Bullish Engulfing/Bearish Engulfing" candlestick pattern, confirmed by Relative Strength Index (RSI) indicator is considered. The code of the Expert Advisor based on this strategy can be generated automatically using the MQL5 Wizard.