MQL5 Wizard - Señales de comercio basadas en Bullish Engulfing/Bearish Engulfing + CCI - Asesor Experto para MetaTrader 5

MQL5 Wizard le permite la creación de Asesores Expertos confeccionados en base a las clases de la libreria standard entregadas junto con el terminal del cliente (ver Creación de Asesores Expertos en MQL5 Wizard para más detalles) Permite comprobar sus ideas comerciales de forma rápida, lo único que necesita es crear sus propias clases de señales de operación. La estructura de esta clase y el ejemplo se puede encontrar en el artículo MQL5 Wizard: Cómo crear un módulo de señales de trading.

La idea genérica es la siguiente: la clase de señales de comercio se deriva de CExpertSignal, lo siguiente, es necesario reemplazar los métodos virtuales LongCondition() y ShortCondition() con sus propios métodos.

Hay un libro "Estrategias de mejores traders" (en ruso), allí hay muchas estrategias de negociación que se consideran, nos centraremos en la inversión de los patrones de vela, confirmados por los osciladores Estocástico, CCI, MFI y RSI .

La mejor manera es crear una clase separada, derivada de CExpertSignal para la comprobación de la formación de patrones de velas. Para la confirmación de las señales comerciales, generadas por los patrones de vela, es suficiente con escribir la clase, derivada de CCandlePattern y agregar allí las características necesarias (por ejemplo, la confirmación por osciladores).

Aquí vamos a considerar las señales, basadas en el patrón de velas de reversa "Bullish Engulfing/Bearish Engulfing", confirmadas por el indicador CCI. El módulo de señales de comercio se basa en la clase CCandlePattern, es un simple ejemplo de su uso para la creación de las señales comerciales con los patrones de vela.

1. Patrones de vela de reversa "Bullish Engulfing" and "Bearish Engulfing"

1.1. Bullish Engulfing

El patrón de reversa "Bullish Engulfing" se forma en una tendencia bajista cuando una pequeña vela negra es seguida por una vela larga blanca y esta eclipsa completamente ("sumerge") la vela del día anterior. Las sombras (colas) de la pequeña vela son cortas, lo que permite al cuerpo de la gran vela cubrir toda la vela del día anterior.

Fig. 1. Patrón de vela "Bullish Engulfing"

El Reconocimiento del patrón "Bullish Engulfing" esta implementado en el método CheckPatternBullishEngulfing() de la ClaseCCandlePattern:

//+------------------------------------------------------------------+
//| Comprueba la formación del patrón de velas "Bullish Engulfing    |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBullishEngulfing()
  {
//--- Bullish Engulfing
   if((Open(2)>Close(2))             &&  // la vela anterior es bajista
      (Close(1)-Open(1)>AvgBody(1))  &&  // el cuerpo de la vela alcista es mayor que la media del cuerpo 
      (Close(1)>Open(2))             &&  // el precio de cierre de la vela alcista es más alto que el precio de apertura de la vela bajista
      (MidOpenClose(2)<CloseAvg(2))  &&  // tendencia bajista
      (Open(1)<Close(2)))                // el precio de apertura de la vela alcista es más bajo que el precio de cierre del bajista
      return(true);
//---
   return(false);
  }

1.2. Bearish Engulfing

El patrón de reversa "Bearish Engulfing" se forma en una tendencia alcista cuando una pequeña vela blanca es seguida por una vela larga negra y esta eclipsa completamente ("sumerge") la vela del día anterior. Las sombras (colas) de la pequeña vela son cortas, lo que permite al cuerpo de la gran vela cubrir toda la vela del día anterior.

Fig. 2. Patrón de vela "Bearish Engulfing"

El Reconocimiento del patrón "Bearish Engulfing" esta implementado en el método CheckPatternBearishEngulfing() de la Clase CCandlePattern:

//+------------------------------------------------------------------+
//| Comprueba la formación del patrón de velas "Bearish Engulfing"   |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBearishEngulfing()
  {
//--- Bearish Engulfing
   if((Open(2)<Close(2))            &&  // la vela anterior es bajista
      (Open(1)-Close(1)>AvgBody(1)) &&  // el cuerpo de la vela es mayor que el valor promedio del cuerpo
      (Close(1)<Open(2))            &&  // el precio de cierre de la vela bajista es menor que el precio de apertura de la vela alcista
      (MidOpenClose(2)>CloseAvg(2)) &&  // tendencia alcista
      (Open(1)>Close(2)))               // El precio de apertura de la vela bajista es más alto que el precio de cierre de la vela alcista
      return(true);
//---
   return(false);
  }

2. Señales de comercio, confirmadas por el indicador CCI

Las señales de comercio para abrir posiciones largas o cortas deben ser confirmadas por el indicador CCI . El valor de CCI debe ser mayor / menor que los niveles críticos (-50 para la posición larga y 50 para la posición corta).

El cierre de la posición abierta depende de los valores de CCI. Se puede hacer de 2 formas:

1. si la línea CCI ha alcanzado el nivel crítico opuesto (80 para la posición larga y -80 para la posición corta)
2. si no se confirma la señal inversa (cuando CCI alcanza los siguientes niveles: -80 para la posición larga y 80 para la posición corta)

Fig. 3. Patrón "Bullish Engulfing" confirmado por indicador CCI

• int CBE_BE_CCI::LongCondition() - comprueba las condiciones para abrir posiciones largas (devuelve 80) y cierra la posición corta (devuelve 40);
  
• int CBE_BE_CCI::ShortCondition() - comprueba las condiciones para abrir una posición corta (devuelve 80) y cierra la posición larga (devuelve 40).

2.1. Abre una posición larga/Cierra una posición corta

1. La formación del patrón "Bullish Engulfing" debe ser confirmada por el indicador CCI: CCI(1)<-50 (el valor de CCI de la última barra completada debe ser inferior a -50).

2. La posición corta debe estar cerrada si el indicador CCI ha cruzado al alza el nivel critico -80 o cruzado a la baja el nivel crítico 80.

//+------------------------------------------------------------------+
//| Comprueba las condiciones para las entradas y salidas al mercado |
//| 1) Entrada al mercado (abrir posición larga, resultado=80)       |
//| 2) Salida del mercado (cerrar posición corta, resultado=40)      |
//+------------------------------------------------------------------+
int CBE_BE_CCI::LongCondition()
  {
   int result=0;
//--- idx se puede utilizar para determinar el modo de trabajo del Asesor Experto
//--- idx=0 - en este caso el EA comprueba las condiciones del comercio en cada tick
//--- idx=1 - en este caso el EA comprueba la condición de comercio sólo en las barras nuevas
   int idx   =StartIndex();
//--- checking of conditions to open long position
//--- formation of Bullish Engulfing pattern and CCI<-50
   if(CheckCandlestickPattern(CANDLE_PATTERN_BULLISH_ENGULFING) && (CCI(1)<-50))
     result=80;
//--- comprobación de las condiciones para cerrar la posición corta
//--- cruce de la línea de señal de los niveles de sobre compra / sobre venta (a la baja -80, a la baja -80)
   if(((CCI(1)>-80) && (CCI(2)<-80)) || ((CCI(1)<80) && (CCI(2)>80)))
     result=40;
//--- devuelve el resultado
   return(result);
  }

2.2. Abrir la posición corta/Cerrar la posición larga

1. La formación del patrón "Bearish Engulfing" debe ser confirmada por el indicador CCI : CCI(1)>50 (el valor del indicador CCI de la última barra completa debe ser mayor que 50).

2. La posición larga debe ser cerrada si el indicador CCI ha cruzado a la baja los niveles -80 o 80 .

//+------------------------------------------------------------------+
//| Comprueba las condiciones para las entradas y salidas al mercado |
//| 1) Entrada al mercado (abrir posición larga, resultado=80)       |
//| 2) Salida del mercado (cerrar posición corta, resultado=40)      |
//+------------------------------------------------------------------+
int CBE_BE_CCI::ShortCondition()
  {
   int result=0;
//--- idx se puede utilizar para determinar el modo de trabajo del Asesor Experto
//--- idx=0 - en este caso el EA comprueba las condiciones del comercio en cada tick
//--- idx=1 - en este caso el EA comprueba la condición de comercio sólo en las barras nuevas
   int idx   =StartIndex();
//--- comprobación de las condiciones para abrir una posición corta
//--- formación del patrón Bearish Engulfing y CCI>50
   if(CheckCandlestickPattern(CANDLE_PATTERN_BEARISH_ENGULFING) && (CCI(1)>50))
     result=80;
//--- comprobación de las condiciones para cerrar la posición larga
//--- línea de señal de cruce de los niveles de sobre compra / sobre venta (a la baja -80, a la baja 80)
   if(((CCI(1)<80) && (CCI(2)>80)) || ((CCI(1)<-80) && (CCI(2)>-80)))
     result=40;
//--- devuelve el resultado
   return(result);
  }

2.3. Creando el Asesor Experto utilizando MQL5 Wizard

Para crear un Asesor Experto lanzaremos MQL5 Wizard:

Fig. 4. Creando el Asesor Experto utilizando MQL5 Wizard

Vamos a especificar el nombre del Asesor Experto:

Fig. 5. Propiedades generales del Asesor Experto

Después de eso tenemos que seleccionar los módulos de señales comerciales utilizados.

Fig. 6. Propiedades de la señal del Asesor Experto

En nuestro caso usamos sólo un módulo de señales comerciales.

Añadiendo los módulos de señales de comercio de las "Señales basadas en Bullish Engulfing/Bearish Engulfing confirmadas por el por el CCI":

Fig. 7. Propiedades de la señal del Asesor Experto

El módulo de señales de comercio añadido:

Fig. 8. Propiedades de la señal del Asesor Experto

Puedes seleccionar cualquier propiedad de trailing, pero vamos a utilizar "Trailing Stop not used":

Fig. 9. Propiedades de trailing del Asesor Experto

En cuanto a las propiedades de manejo del dinero, vamos a utilizar "Trading with fixed trade volume":

Fig. 10. Propiedades de la administración del dinero del Asesor Experto

Al presionar el botón "Finish" button, obtendremos el código generado del Asesor Experto Expert Advisor, ubicado en Expert_ABE_BE_CCI.mq5, que se guardará en terminal_data_folder\MQL5\Experts\.

Loa parámetros de entrada generados por defecto del Asesor Experto

//--- entradas para la señal principal
input int            Signal_ThresholdOpen   =10;     // Valor umbral de la señal para abrir [0...100]
input int            Signal_ThresholdClose  =10;     // Valor umbral de señal la para cerrar [0...100]
input double         Signal_PriceLevel      =0.0;    // Nivel de precio para ejecutar una transacción
input double         Signal_StopLevel       =50.0;   // Nivel de Stop Loss(en puntos)
input double         Signal_TakeLevel       =50.0;   // Nivel de Take Profit(en puntos)

deben ser reemplazado por:

//--- entradas para la señal principal
input int            Signal_ThresholdOpen   =40;     // Valor umbral de señal la para cerrar [0...100]
input int            Signal_ThresholdClose  =20;     // Valor umbral de señal la para cerrar [0...100]
input double         Signal_PriceLevel      =0.0;    // Nivel de precio para ejecutar una transacción
input double         Signal_StopLevel       =0.0;    // Nivel de Stop Loss(en puntos)
input double         Signal_TakeLevel       =0.0;    // Nivel de Take Profit(en puntos)

Los parámetros de entrada Signal_ThresholdOpen / Signal_ThresholdClose permiten especificar los niveles de umbral para la apertura y cierre de posiciones.

En el código de los métodos LongCondition () y ShortCondition () de la clase de señales de comercio hemos especificado los valores fijos del umbral:

• Abrir posición: 80;
• Cerrar posición: 40.
  

Los valores de los parámetros de entrada Signal_StopLevel y Signal_TakeLevel se establecen en 0, esto significa que el cierre de las posiciones se hará sólo cuando las condiciones de cierre sean verdaderas.

2.4. Resultados del backtesting del Historial

Vamos a considerar el backtesting del Asesor Experto sobre los datos históricos (EURUSD H1, período de prueba: 2010.01.01-2011.03.16, PeriodCCI=49, MA_period=11).

En la creación del Asesor Experto se utilizó el volumen fijo (Trading Fixed Lot, 0.1), El algoritmo de Trailing Stop algorithm no se utiliza (Trailing not used).

Fig. 11. Resultados de las pruebas del Asesor Experto, basadas en Bullish Engulfing/Bearish Engulfing + CCI

El mejor conjunto de parámetros de entrada se puede encontrar utilizando el Strategy Tester del terminal de cliente MetaTrader 5 .

El código del Asesor Experto, creado por MQL5 Wizard se adjunta en expert_abe_be_cci.mq5.