MQL5 Wizard - 商品チャネル指数(CCI)による条件付きの"Bullish Engulfing/Bearish Engulfing"のシグナル - MetaTrader 5のためのエキスパート

MQL5 Wizardを使えば、クライアントターミナルにあるStandard libraryのエキスパートアドバイザーを自動生成することができます。(詳細は、Creating Ready-Made Expert Advisors in MQL5 Wizardを参照)トレードシグナルのクラスを生成しさせすれば、トレードアイディアをすぐに確認することができますクラスの例と構造については MQL5 Wizard: How to Create a Module of Trading Signalsを参照してください。

一般的な考え方は下記の通りです。:CExpertSignalがシグナルのクラスです。そして、LongCondition() と ShortCondition() を上書きする必要があります。

"Strategies of best traders" (ロシア)という著書があります。 そこには数多くの手法と方法が記述されており、転換足パターンを Stochastic、 CCI、 MFI、 RSIの条件のもと、焦点を当てていきます。

最も良い方法は、ロウソク足のパターンの確認に、CExpertSignalから導かれるクラスを切り分けて生成することです。ロウソク足のパターンによるトレードシグナルの確認には、CCandlePatternのクラスを書いて、必要な条件例えば、オシレーターの確認など)を追加すれば十分です。

Stochasticのフィルター付きの"Bullish Engulfing/Bearish Engulfing"の転換足パターンのシグナルを考えてみましょう。トレードシグナルのモジュールは、CCandlePattern classに基づいています。ロウソク足のパターンによるシグナルの生成のシンプルな一例です。

1. "Bullish Engulfing" と "Bearish Engulfing"

1.1. Bullish Engulfing

"Bullish Engulfing"は、小さな黒いロウソク足として、下降トレンドで形成されます。その後、大きな白いロウソク足が前日のロウソク足を完璧に覆うように発生します。大きなロウソク足の実体が前日のロウソク足全体を覆うことができるほど、小さなロウソク足のヒゲが短い

図1. "Bullish Engulfing" candlestick pattern

"Bullish Engulfing"は、 CCandlePatternのCheckPatternBullishEngulfing() method に実装されています。:

//+------------------------------------------------------------------+
//| Checks formation of "Bullish Engulfing" candlestick pattern      |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBullishEngulfing()
  {
//--- Bullish Engulfing
   if((Open(2)>Close(2))             &&  // previous candle is bearish
      (Close(1)-Open(1)>AvgBody(1))  &&  // body of the bullish candle is higher than average value of the body 
      (Close(1)>Open(2))             &&  // close price of the bullish candle is higher than open price of the bearish candle
      (MidOpenClose(2)<CloseAvg(2))  &&  // downtrend
      (Open(1)<Close(2)))                // open price of the bullish candle is lower than close price of the bearish
      return(true);
//---
   return(false);
  }

1.2. Bearish Engulfing

"Bearish Engulfing"は、小さな黒いロウソク足として、上昇トレンドで形成されます。その後、大きな白いロウソク足が前日のロウソク足を完璧に覆うように発生します。大きなロウソク足の実体が前日のロウソク足全体を覆うことができるほど、小さなロウソク足のヒゲが短い

図2. "Bearish Engulfing" candlestick pattern

"Bearish Engulfing" は、 CCandlePatternのCheckPatternBearishEngulfing() method に実装されています。:

//+------------------------------------------------------------------+
//| Checks formation of "Bearish Engulfing" candlestick pattern      |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternBearishEngulfing()
  {
//--- Bearish Engulfing
   if((Open(2)<Close(2))            &&  // previous candle is bearish
      (Open(1)-Close(1)>AvgBody(1)) &&  // body of the candle is higher than average value of the body
      (Close(1)<Open(2))            &&  // close price of the bearish candle is lower than open price of the bullish candle
      (MidOpenClose(2)>CloseAvg(2)) &&  // uptrend
      (Open(1)>Close(2)))               // Open price of the bearish candle is higher than close price of the bullish candle
      return(true);
//---
   return(false);
  }

2. CCIによる条件付きのシグナル

買いポジション・売りポジションのシグナルは、CCIで確認する必要があります。CCIの値は基準値よりも大きい/小さい必要があります。 (買いポジションは-50。売りポジションは50。)

ポジションの決済は、CCIの値で行います。2通りのケースがあります。:

1. CCIが反対側の基準値に達した場合(買いポジションは80。売りポジションは-80)
2. 逆のシグナルが発生しない (CCIが下記の点に達したとき:買いポジションは-80。売りポジションは80)

図3. CCIの条件付きの"Bullish Englulfing"

• int CBE_BE_CCI::LongCondition() - 買いポジションのエントリー条件(80) と 売りポジションの決済条件 (40);
  
• int CBE_BE_CCI::ShortCondition() - 売りポジションのエントリー条件(80) と 買いポジションの決済条件 (40).

2.1. 買いポジション/売りポジションの決済

1. CCI の条件付きの "Bullish Engulfing" : CCI(1)<-50 (直近の確定した足のCCIが-50より小さい)

2. CCIが-80ラインを上向きにクロスした場合、もしくは80ラインを下向きにクロスした場合、売りポジションは決済します。

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open long position, result=80)                  |
//| 2) Market exit (close short position, result=40)                 |
//+------------------------------------------------------------------+
int CBE_BE_CCI::LongCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open long position
//--- formation of Bullish Engulfing pattern and CCI<-50
   if(CheckCandlestickPattern(CANDLE_PATTERN_BULLISH_ENGULFING) && (CCI(1)<-50))
     result=80;
//--- checking of conditions to close short position
//--- signal line crossover of overbought/oversold levels (downward -80, downward -80)
   if(((CCI(1)>-80) && (CCI(2)<-80)) || ((CCI(1)<80) && (CCI(2)>80)))
     result=40;
//--- return result
   return(result);
  }

2.2. 売りポジション/買いポジションの決済

1. CCIの条件付きの""Bearish Engulfing": CCI(1)>50 (直近の確定した足のCCIが50より大きい)..

2. CCIが-80 か 80を下向きにクロスした場合、買いポジションを決済します。

//+------------------------------------------------------------------+
//| Checks conditions for entry and exit from market                 |
//| 1) Market entry (open short position, result=80)                 |
//| 2) Market exit (close long position, result=40)                  |
//+------------------------------------------------------------------+
int CBE_BE_CCI::ShortCondition()
  {
   int result=0;
//--- idx can be used to determine Expert Advisor work mode
//--- idx=0 - in this case EA checks trade conditions at each tick
//--- idx=1 - in this case EA checks trade consition only at news bars
   int idx   =StartIndex();
//--- checking of conditions to open short position
//--- formation of Bearish Engulfing pattern and CCI>50
   if(CheckCandlestickPattern(CANDLE_PATTERN_BEARISH_ENGULFING) && (CCI(1)>50))
     result=80;
//--- checking of conditions to close long position
//--- signal line crossover of overbought/oversold levels (downward -80, downward 80)
   if(((CCI(1)<80) && (CCI(2)>80)) || ((CCI(1)<-80) && (CCI(2)>-80)))
     result=40;
//--- return result
   return(result);
  }

2.3. MQL5 WizardでEAを生成する

エキスパートアドバイザーを生成するには、MQL5 Wizardを立ち上げてください。:

図4. MQL5 WizardでEAを生成する

エキスパートアドバイザーの名前を決めましょう。:

図5. エキスパートアドバイザーの一般設定

トレードシグナルのモジュールを選択します。

図6. エキスパートアドバイザーのシグナルプロパティ

今回の場合、モジュールは１つだけ使います。

"Signals based on Bullish Engulfing/Bearish Engulfing confirmed by CCI"のモジュールを追加::

図7. エキスパートアドバイザーのシグナルプロパティ

シグナルの追加モジュール:

図8. エキスパートアドバイザーのシグナルプロパティ

トレーリングプロパティにも様々なものがありますが、今回は"Trailing Stop not used"にします。:

図9. エキスパートアドバイザーのトレーリングプロパティTrailing properties of the Expert Advisor

資金管理プロパティとして、"Trading with fixed trade volume"(単利)を使います。:

図10エキスパートアドバイザーの資金管理プロパティMoney management properties of the Expert Advisor

"Finish"ボタンを押すと、エキスパートアドバイザーがExpert_ABE_BE_CCI.mq5に生成されます。保存場所は、terminal_data_folder\MQL5\Experts\です。.

生成後のエキスパートアドバイザーのデフォルトのパラメーター:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =10;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =10;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =50.0;   // Stop Loss level (in points)
input double         Signal_TakeLevel       =50.0;   // Take Profit level (in points)

上記は下記にしなければなりません。:

//--- inputs for main signal
input int            Signal_ThresholdOpen   =40;     // Signal threshold value to open [0...100]
input int            Signal_ThresholdClose  =20;     // Signal threshold value to close [0...100]
input double         Signal_PriceLevel      =0.0;    // Price level to execute a deal
input double         Signal_StopLevel       =0.0;    // Stop Loss level (in points)
input double         Signal_TakeLevel       =0.0;    // Take Profit level (in points)

Signal_ThresholdOpen/Signal_ThresholdClose パラメーターは、ポジションのオープン、決済の最初のレベルを決めます。

LongCondition() と ShortCondition() のメソッドのコードの中に、デフォルトの固定値が入っています。:

• エントリー: 80;
• 決済: 40.
  

Signal_StopLevel と Signal_TakeLevel パラメータの値は、0にします。これは、ポジションの決済は、今朝い条件がtrueの場合にのみ行われるということを意味します。

2.4. バックテスト結果

過去データでエキスパートアドバイザーをテストしてみましょう。 (EURUSD H1, テスト期間: 2010.01.01-2011.03.16, PeriodCCI=49, MA_period=11).

エキスパートアドバイザーの生成において、今回は固定ロット(Trading Fixed Lot, 0.1), トレーリングストップ(Trailing not used)はなしを選択しました。

図11. Bullish Engulfing/Bearish Engulfing + CCIのテスト結果

パラメーターの最適な設定値は、MetaTrader 5 client terminalのStrategy Testerで探すことができます。

MQL5 Wizard で生成したコードは expert_abe_be_cci.mq5.です。