Demo_FileMove - Skript für den MetaTrader 5

Das Skript versucht eine Quelldatei von einem Unterverzeichnis des lokalen Terminalordners in ein Zielverzeichnis des gemeinsamen Ordners aller Client-Terminals zu kopieren. Die Namen der Dateien und Verzeichnisse werden in den Eingabeparametern des Skripts angegeben. Der Ort des lokalen Terminal-Ordners kann durch Aufruf der TerminalInfoString() Funktion festgestellt werden.

PrintFormat("Der Pfad zum lokalen Terminal-Ordner lautet: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
PrintFormat("Pfad zum gemeinsamen Ordner aller Client-Terminals: %s\\Files\\",TerminalInfoString(TERMINAL_COMMONDATA_PATH));

Zunächst verwendet das Skript die FileIsExist() Funktion um zu bestimmen, ob es eine Quelldatei mit dem angegebenen Pfad im lokalen Terminalordner gibt, wenn nicht, wird eine Fehlermeldung angezeigt. Dann wird geprüft, ob es eine Zieldatei mit dem spezifizierten Pfad gibt. Wenn die Zieldatei nicht existiert, wird die Verschiebung ohne dem FILE_REWRITE Flag ausgeführt. Ansonsten wird das Flag verwendet oder die Verschiebung wird nicht ausgeführt.

Code:

//--- Zeige Fenster mit den Eingabeparametern, wenn Sie das Skript starten
#property script_show_inputs
Eingabeparameter:
input string InpSrcName="data.txt";
input string InpDstName="newdata.txt";
input string InpSrcDirectory="IrgendeinOrdner";
input string InpDstDirectory="AndererOrdner";
//+------------------------------------------------------------------+
//| Skript Programmstart Funktion                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   string local=TerminalInfoString(TERMINAL_DATA_PATH);
   string common=TerminalInfoString(TERMINAL_COMMONDATA_PATH);
//--- Pfade beziehen
   string src_path;
   string dst_path;
   StringConcatenate(src_path,InpSrcDirectory,"//",InpSrcName);
   StringConcatenate(dst_path,InpDstDirectory,"//",InpDstName);
//--- prüfen, ob die Quelldatei existiert (wenn nicht - Ausstieg)
   if(FileIsExist(src_path))
      PrintFormat("%s Datei existiert im Ordner %s\\Files\\%s folder",InpSrcName,local,InpSrcDirectory);
   else
     {
      PrintFormat("Fehler, %s Quelldatei nicht gefunden",InpSrcName);
      return;
     }
//--- prüfe, ob die Zieldatei bereits existiert
   if(FileIsExist(dst_path,FILE_COMMON))
     {
      PrintFormat("%s Datei existiert im %s\\Files\\%s Ordner",InpDstName,common,InpDstDirectory);
      //--- Datei existiert, Verschiebung sollte mit dem FILE_REWRITE Flag ausgeführt werden
      ResetLastError();
      if(FileMove(src_path,0,dst_path,FILE_COMMON|FILE_REWRITE))
         PrintFormat("%s Datei verschoben",InpSrcName);
      else
         PrintFormat("Fehler! Code = %d",GetLastError());
     }
   else
     {
      PrintFormat("%s Datei existiert nicht im %s\\Files\\%s Ordner",InpDstName,common,InpDstDirectory);
      //--- Datei existiert nicht, Verschiebung sollte ohne das FILE_REWRITE Flag ausgeführt werden
      ResetLastError();
      if(FileMove(src_path,0,dst_path,FILE_COMMON))
         PrintFormat("%s Datei verschoben",InpSrcName);
      else
         PrintFormat("Fehler! Code = %d",GetLastError());
     }
//--- Datei verschoeben; jetzt überprüfen
   if(FileIsExist(dst_path,FILE_COMMON) && !FileIsExist(src_path,0))
      Print("Erfolg!");
   else
      Print("Fehler!");
  }