MagicNumber: 定单的“魔法“识别符

1. 历史

在МТ3中,开仓的管理是非常费时的。交易者在处理开仓和平仓列表时，设置执行的工具是限定的。在区分“自己”和“他人”仓位时，方法非常复杂。在 МТ4中，状况有了明显的改变。现在，交易者可以使用多种函数来管理开仓，挂单并且获取平仓信息。

以MagicNumber命名的特殊参数被添加到定单识别符中。这个参数就是我们文章中将提及到的主题。

2.什么是 MagicNumber?

MQL4 参考:

int OrderSend( string symbol, int cmd, double volume, double price, int slippage, double stoploss, double takeprofit, string comment=NULL, int magic=0, datetime expiration=0, color arrow_color=CLR_NONE)
…
magic - 定单魔法数字。可以使用指定识别符。

 即，当定单被放置时，可以给定单指定独有的数字。这个数字将用于区分其他定单。当手动交易时，不使用（尽可能）这个特性，但是在智能交易（自动交易）运作时，此特性是不可替代的。

范例1: 在客户端内交易者和智能交易同时运行。
任务: 智能交易的运行必须按照它自己的形式计算，对于手动开仓不会干涉。
解决: 开仓的智能交易必须指定独特的MagicNumber（零除外）。接下来的日子里，智能交易只会管理提前设定的 MagicNumber 的定单。

范例 2: 在客户端内两个不同计算方法的智能交易同时运行。
任务: 智能交易只管理自己的定单。.
解决: 当开仓时，每个智能交易必须使用自己的 MagicNumber（零除外）。接下来的日子里，智能交易只会管理提前设定的MagicNumber的定单。

范例 3: 在客户端内几个智能交易，交易者和协助智能交易执行的不标准追踪止损同时运行。
任务: 交易的智能交易必须按照自己的形式计算，并且不干涉手动开仓。协助智能交易执行的追踪止损可以在手动开仓处修改，但是其他智能交易不能够开仓。
解决: 智能交易必须使用独有的MagicNumbers并且管理自己的仓位。协助智能交易修改的这些仓位，其 MagicNumber等于 0。

以上三个范例都很现实，用户可以提前解决问题。在这三个范例情况中，都是使用MagicNumber来解决问题的。这不是唯一解决问题的途径，但是最简单的途径。

3. 实践

现在让我们来解决特殊的任务:创建智能交易只管理自己的仓位，不理睬手动仓位和其他智能交易。

首先我们编写一个简单的智能交易，当 MACD 指标零线时，智能交易得到信号开仓。智能交易将会运行如下:

int start()
{
    //---- 记住将要分析的指标值
    //---- 注意：我们使用第一个和第二个柱。可以是每日的 1-bar 。 
    //---- (即., 信号晚些显现), 但是保护反复开仓和平仓
    //---- 在柱内仓位的
    double MACD_1 = iMACD( Symbol(), 0, 12, 26, 9, PRICE_CLOSE, MODE_MAIN, 1 );
    double MACD_2 = iMACD( Symbol(), 0, 12, 26, 9, PRICE_CLOSE, MODE_MAIN, 2 );
 
    int _GetLastError = 0, _OrdersTotal = OrdersTotal();
    //---- 在开仓中搜索
    for ( int z = _OrdersTotal - 1; z >= 0; z -- )
    {
        //---- 如果在选择仓位中生成错误，转到下一步
        if ( !OrderSelect( z, SELECT_BY_POS ) )
        {
            _GetLastError = GetLastError();
            Print( "OrderSelect( ", z, ", SELECT_BY_POS ) - Error #", _GetLastError );
            continue;
        }
 
        //---- 如果开仓不是当前货币对，略过
        if ( OrderSymbol() != Symbol() ) continue;
 
        //---- 如果开仓为BUY,
        if ( OrderType() == OP_BUY )
        {
            //---- 如果 MACD指标看到的零线从上至下,
            if ( NormalizeDouble( MACD_1, Digits + 1 ) <  0.0 && 
                  NormalizeDouble( MACD_2, Digits + 1 ) >= 0.0    )
            {
                //---- 平仓
                if ( !OrderClose( OrderTicket(), OrderLots(), Bid, 5, Green ) )
                {
                    _GetLastError = GetLastError();
                    Alert( "错误 OrderClose # ", _GetLastError );
                    return(-1);
                }
            }
            //---- 如果警报没有改变,退出: 开仓尚早
            else return(0);
        }
        //---- 如果开仓位SELL,
        if ( OrderType() == OP_SELL )
        {
            //----如果MACD指标看到零线从下到上,
            if ( NormalizeDouble( MACD_1, Digits + 1 ) >  0.0 && 
                  NormalizeDouble( MACD_2, Digits + 1 ) <= 0.0    )
            {
                //---- 平仓
                if ( !OrderClose( OrderTicket(), OrderLots(), Ask, 5, Red ) )
                {
                    _GetLastError = GetLastError();
                    Alert( "错误 OrderClose # ", _GetLastError );
                    return(-1);
                }
            }
            //---- 如果警报没有改变,退出:开仓尚早
            else return(0);
        }
    }
 
//+------------------------------------------------------------------+
//| 如果达到此点,没有仓位开仓　　　　　　　　　　　　　　　　　　　　　　　　　   |
//| 检测是否仍有开仓的可能　　　　　　　　　　　　　　　　　　　　　　            |
//+------------------------------------------------------------------+
 
    //---- 如果MACD 指标看到零线从下到上,
    if ( NormalizeDouble( MACD_1, Digits + 1 ) >  0.0 && 
          NormalizeDouble( MACD_2, Digits + 1 ) <= 0.0    )
    {
        //---- 开BUY仓
        if ( OrderSend( Symbol(), OP_BUY, 0.1, Ask, 5, 0.0, 0.0, "MACD_test", 0, 0, Green ) < 0 )
        {
            _GetLastError = GetLastError();
            Alert( "错误OrderSend # ", _GetLastError );
            return(-1);
        }
        return(0);
    }
    //----如果MACD 指标看到零线从上至下,
    if ( NormalizeDouble( MACD_1, Digits + 1 ) <  0.0 && 
          NormalizeDouble( MACD_2, Digits + 1 ) >= 0.0    )
    {
        //---- 开 SELL 仓
        if ( OrderSend( Symbol(), OP_SELL, 0.1, Bid, 5, 0.0, 0.0, "MACD_test", 0, 0, Red ) < 0 )
        {
            _GetLastError = GetLastError();
            Alert( "错误OrderSend # ", _GetLastError );
            return(-1);
        }
        return(0);
    }

    return(0);
}

这样我们得到以下图表，看看它怎样运行:

都不错，但是这里有个问题存在。如果在智能交易执行期间开仓，智能交易将会默认为这个仓位为自己的仓位。这是我们不想看到的。

我们将按照以下方法让它管理自己的仓位:

• 以Expert_ID　命名添加外部变量协助智能交易开仓来改变 MagicNumber 值
• 在函数OrderSelect()选择仓位之后，对编译Expert_ID变量所选定单的MagicNumber 添加检测
• 在开仓期间，我们将在MagicNumber处写下 Expert_ID的值替换 0
  

考虑上面的变化，代码将显现如下:

extern int Expert_ID = 1234;
 
int start()
{
    //---- 记住将要分析的指标值
    //---- 注意：我们使用第一个和第二个柱。可以是每日的 1-bar 。 
    //---- (即., 信号晚些显现), 但是保护反复开仓和平仓
    //---- 在柱内仓位的
    double MACD_1 = iMACD( Symbol(), 0, 12, 26, 9, PRICE_CLOSE, MODE_MAIN, 1 );
    double MACD_2 = iMACD( Symbol(), 0, 12, 26, 9, PRICE_CLOSE, MODE_MAIN, 2 );
 
    int _GetLastError = 0, _OrdersTotal = OrdersTotal();
    //---- 在全部开仓中搜索
    for ( int z = _OrdersTotal - 1; z >= 0; z -- )
    {
        //---- 如果在搜索仓位中生成错误。转到下一步
        if ( !OrderSelect( z, SELECT_BY_POS ) )
        {
            _GetLastError = GetLastError();
            Print( "OrderSelect( ", z, ", SELECT_BY_POS ) -错误 #", _GetLastError );
            continue;
        }
 
        //---- 如果平仓仓位不是当前货币对，略过
        if ( OrderSymbol() != Symbol() ) continue;
 
        //---- 如果MagicNumber 不等于Expert_ID, 忽略此仓位
        if ( OrderMagicNumber() != Expert_ID ) continue;
 
        //---- 如果开BUY仓,
        if ( OrderType() == OP_BUY )
        {
            //---- 如果MACD 指标看到零线从上到下,
            if ( NormalizeDouble( MACD_1, Digits + 1 ) <  0.0 && 
                  NormalizeDouble( MACD_2, Digits + 1 ) >= 0.0    )
            {
                //---- 平仓
                if ( !OrderClose( OrderTicket(), OrderLots(), Bid, 5, Green ) )
                {
                    _GetLastError = GetLastError();
                    Alert( "错误 OrderClose # ", _GetLastError );
                    return(-1);
                }
            }
            //---- 如果警报没有改变, 退出: 开仓尚早
            else
            { return(0); }
        }
        //---- 如果开SELL仓,
        if ( OrderType() == OP_SELL )
        {
            //---- 如果MACD指标看到零线从下到上,
            if ( NormalizeDouble( MACD_1, Digits + 1 ) >  0.0 && 
                  NormalizeDouble( MACD_2, Digits + 1 ) <= 0.0    )
            {
                //---- 平仓
                if ( !OrderClose( OrderTicket(), OrderLots(), Ask, 5, Red ) )
                {
                    _GetLastError = GetLastError();
                    Alert( "错误 OrderClose № ", _GetLastError );
                    return(-1);
                }
            }
            //---- 如果警报没有改变,退出: 开仓尚早
            else return(0);
        }
    }
 
//+------------------------------------------------------------------+
//| 如果执行达到此点,没有仓位开仓　　　　　　　　　　　　　　　　　　　　　　    |
//| 检测是否有可能开仓　　　　　　　　　　　　　　　　　　　　　　　            |
//+------------------------------------------------------------------+
 
    //---- 如果MACD 指标看到零线从下到上,
    if ( NormalizeDouble( MACD_1, Digits + 1 ) >  0.0 && 
          NormalizeDouble( MACD_2, Digits + 1 ) <= 0.0    )
    {
        //---- 开BUY仓
        if ( OrderSend( Symbol(), OP_BUY, 0.1, Ask, 5, 0.0, 0.0, "MACD_test", 
              Expert_ID, 0, Green ) < 0 )
        {
            _GetLastError = GetLastError();
            Alert( "错误OrderSend # ", _GetLastError );
            return(-1);
        }
        return(0);
    }
    //---- 如果MACD 指标看到零线从上至下,
    if ( NormalizeDouble( MACD_1, Digits + 1 ) <  0.0 && 
          NormalizeDouble( MACD_2, Digits + 1 ) >= 0.0    )
    {
        //---- 开SELL仓
        if ( OrderSend( Symbol(), OP_SELL, 0.1, Bid, 5, 0.0, 0.0, "MACD_test", 
              Expert_ID, 0, Red ) < 0 )
        {
            _GetLastError = GetLastError();
            Alert( "错误 OrderSend # ", _GetLastError );
            return(-1);
        }
        return(0);
    }

    return(0);
}

现在，当智能交易运行时，用户可以手动开仓。智能交易将不会干涉。

4. 多个相同的智能交易在一种货币对的不同图表上

存在这样的状况，相同的智能交易必须在相同货币对的图表中运行，但是需要不同的时间周期。例如，如果我们尝试添加我们的智能交易同时添加到 EURUSD, H1图表和 EURUSD, M30图表，他们将会相互影响:每个都会“考虑”开仓并且会默认管理。

这个问题可以通过 Expert_ID　一个协调另一个的方式解决。但是这羊不是很方便。如果很多智能交易在运行，他们的ID必然会混乱。

解决这个问题我们需要以 MagicNumber　值作为图表周期。怎样执行呢？如果我们添加图表周期到 Expert_ID, 可能２个不同的智能交易在２个不同的图表上生成相同的 MagicNumber。

所以我们最好用 Expert_ID值乘以 10 并且把图表周期(代码从1 到 9, 精确值)放置到最后  。

如下图表:

    int Period_ID = 0;
    switch ( Period() )
    {
        case PERIOD_MN1: Period_ID = 9; break;
        case PERIOD_W1:  Period_ID = 8; break;
        case PERIOD_D1:  Period_ID = 7; break;
        case PERIOD_H4:  Period_ID = 6; break;
        case PERIOD_H1:  Period_ID = 5; break;
        case PERIOD_M30: Period_ID = 4; break;
        case PERIOD_M15: Period_ID = 3; break;
        case PERIOD_M5:  Period_ID = 2; break;
        case PERIOD_M1:  Period_ID = 1; break;
    }
    _MagicNumber = Expert_ID * 10 + Period_ID;

现在添加这个代码智能交易的 init()函数并且用 Expert_ID替换MagicNumber。

最终版本的智能交易如下:

extern int Expert_ID = 1234;
int _MagicNumber = 0;
 
int init()
{
    int Period_ID = 0;
    switch ( Period() )
    {
        case PERIOD_MN1: Period_ID = 9; break;
        case PERIOD_W1:  Period_ID = 8; break;
        case PERIOD_D1:  Period_ID = 7; break;
        case PERIOD_H4:  Period_ID = 6; break;
        case PERIOD_H1:  Period_ID = 5; break;
        case PERIOD_M30: Period_ID = 4; break;
        case PERIOD_M15: Period_ID = 3; break;
        case PERIOD_M5:  Period_ID = 2; break;
        case PERIOD_M1:  Period_ID = 1; break;
    }
    _MagicNumber = Expert_ID * 10 + Period_ID;

    return(0);
}
 
int start()
{
    //---- 记住将要分析的指标值
    //---- 注意：我们使用第一个和第二个柱。可以是每日的 1-bar 。 
    //---- (即., 信号晚些显现), 但是保护反复开仓和平仓
    //---- 在柱内仓位的
    double MACD_1 = iMACD( Symbol(), 0, 12, 26, 9, PRICE_CLOSE, MODE_MAIN, 1 );
    double MACD_2 = iMACD( Symbol(), 0, 12, 26, 9, PRICE_CLOSE, MODE_MAIN, 2 );
 
    int _GetLastError = 0, _OrdersTotal = OrdersTotal();
    //---- 在全部开仓中搜索
    for ( int z = _OrdersTotal - 1; z >= 0; z -- )
    {
        //---- 如果在搜索过程中生成错误。转到下一步
        if ( !OrderSelect( z, SELECT_BY_POS ) )
        {
            _GetLastError = GetLastError();
            Print( "OrderSelect( ", z, ", SELECT_BY_POS ) - 错误#", _GetLastError );
            continue;
        }
 
        //---- 如果开仓仓位不是当前货币对，忽略
        if ( OrderSymbol() != Symbol() ) continue;
 
        //---- 如果MagicNumber 不等于 _MagicNumber, 忽略此仓位
        if ( OrderMagicNumber() != _MagicNumber ) continue;
 
        //----如果开BUY仓,
        if ( OrderType() == OP_BUY )
        {
            //---- 如果MACD指标看见零线从上至下,
            if ( NormalizeDouble( MACD_1, Digits + 1 ) <  0.0 && 
                  NormalizeDouble( MACD_2, Digits + 1 ) >= 0.0    )
            {
                //---- 平仓
                if ( !OrderClose( OrderTicket(), OrderLots(), Bid, 5, Green ) )
                {
                    _GetLastError = GetLastError();
                    Alert( "错误 OrderClose # ", _GetLastError );
                    return(-1);
                }
            }
            //---- 如果警报没有改变，停止: 开新仓位尚早
            else return(0);
        }
        //---- 如果开SELL仓，
        if ( OrderType() == OP_SELL )
        {
            //---- 如果MACD指标看见零线从下到上,
            if ( NormalizeDouble( MACD_1, Digits + 1 ) >  0.0 && 
                  NormalizeDouble( MACD_2, Digits + 1 ) <= 0.0    )
            {
                //----平仓
                if ( !OrderClose( OrderTicket(), OrderLots(), Ask, 5, Red ) )
                {
                    _GetLastError = GetLastError();
                    Alert( "错误OrderClose № ", _GetLastError );
                    return(-1);
                }
            }
            //---- 如果警报没有改变, 停止: 开新仓位尚早
            else return(0);
        }
    }
 
//+------------------------------------------------------------------+
//| 如果执行达到此点，没有仓位开仓　　　　　　　　　　　　　　　　　　　　　　    |
//| 检测是否仍有可能开仓　　　　　　　　　　　　　　　　　　　　　　　           |
//+------------------------------------------------------------------+
 
    //---- 如果MACD 指标看见零线从下到上,
    if ( NormalizeDouble( MACD_1, Digits + 1 ) >  0.0 && 
          NormalizeDouble( MACD_2, Digits + 1 ) <= 0.0    )
    {
        //---- 开 BUY 仓
        if ( OrderSend( Symbol(), OP_BUY, 0.1, Ask, 5, 0.0, 0.0, "MACD_test", 
              _MagicNumber, 0, Green ) < 0 )
        {
            _GetLastError = GetLastError();
            Alert( "错误 OrderSend # ", _GetLastError );
            return(-1);
        }
        return(0);
    }
    //---- 如果MACD 指标看到零线从上至下,
    if ( NormalizeDouble( MACD_1, Digits + 1 ) <  0.0 && 
          NormalizeDouble( MACD_2, Digits + 1 ) >= 0.0    )
    {
        //---- 开 SELL 仓
        if ( OrderSend( Symbol(), OP_SELL, 0.1, Bid, 5, 0.0, 0.0, "MACD_test", 
              _MagicNumber, 0, Red ) < 0 )
        {
            _GetLastError = GetLastError();
            Alert( "错误 OrderSend # ", _GetLastError );
            return(-1);
        }
        return(0);
    }

    return(0);
}

这样的显示智能交易可以在不同周期的几个图表中使用。

如果需要在相同时间周期和货币对的图表(例如, EURUSD H1 和EURUSD H4)上开启两个智能交易， 此Expert_ID 变量值将被改变。但是这种情况很罕见。

使用以上代码，用户能够改善他的智能交易并且“教会”智能交易区分自己的仓位和他人的仓位。

转自俄罗斯MetaQuotes Software Corp.
原文: http://articles.mql4.com/ru/articles/1359