Проверьте, что в сервисдеске ответят - Общее обсуждение

Anatoli Kazharski 2017.09.04 16:08 #19851

Alexey Kozitsyn:

Идет инициализация в OnCalculate() при первом запуске (prev_calculated == 0). Думаете перенос в OnInit() что-то изменит? Ну, попробую, конечно, но это что-то из области фантастики...

Стоп. Как я уже сказал, в OnDeinit() инициализируются массивы, которые при следующем запуске (изменении входных параметров) не используются более. Если это (инициализация массива, который не используется под буфер) поможет - это тоже будет багом МТ. Получится, что мало того, что массивы не используются, так их (неразмеченные) еще можно будет инициализировать и это повлияет на отображение...

Без кода сложно. Сообщите здесь потом, что в сервисдеске ответят.

[Удален] 2017.09.04 16:09 #19852

Anatoli Kazharski:
Без кода сложно. Сообщите здесь потом, что в сервисдеске ответят.

Хорошо.

[Удален] 2017.09.04 16:46 #19853

Anatoli Kazharski:
Без кода сложно. Сообщите здесь потом, что в сервисдеске ответят.

Вот тестовый код, если интересно.

Изначально параметр индикатора ложный.

Кидаем индикатор на график. Рисует гистограмму.

Делаем параметры истинным.

Рисует гистограмму и стрелки.

Делаем параметр ложным. На текущем ТФ стрелки исчезают (не всегда). НО! Если попереключать ТФ, у меня на некоторых стрелки появляются хаотично, несмотря на очистку буферов при деинициализации.

#property indicator_separate_window
#property indicator_plots 3
#property indicator_buffers 4
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
input bool inpUseArrows=false;
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double bufGisto[];
double bufGistoColor[];
double bufArrowUp[];
double bufArrowDn[];
//---
const double EMPTY=EMPTY_VALUE;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- Размечаем массив цветов
   color colors[2];
   colors[ 0 ]= clrLime;
   colors[ 1 ] = clrRed;
//--- Устанавливаем параметры графических серий
   SetPlotParametersColorHistogram(0,0,bufGisto,bufGistoColor,false,"test gisto",colors,EMPTY,2);
//--- Проверяем, нужно ли отображать объемы
   if(inpUseArrows) // Если отображать нужно
     {
      SetPlotParametersArrow(1,2,bufArrowUp,false,"test up",EMPTY,clrLime,233,10);
      SetPlotParametersArrow(2,3,bufArrowDn,false,"test dn",EMPTY,clrRed,234,-10);
     }
//---
   IndicatorSetInteger(INDICATOR_DIGITS,0);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
   if(inpUseArrows)
     {
      ArrayInitialize(bufArrowUp,EMPTY);
      ArrayInitialize(bufArrowDn,EMPTY);
     }
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---
   if(prev_calculated==0)
     {
      ArrayInitialize(bufGisto,EMPTY);
      //---
      if(inpUseArrows)
        {
         ArrayInitialize(bufArrowUp,EMPTY);
         ArrayInitialize(bufArrowDn,EMPTY);
        }
      //---
      for(int i=0; i<rates_total; i++)
        {
         bufGisto[i]=(open[i]-close[i])/_Point;
         bufGistoColor[i]=(bufGisto[i]<0) ? 1 : 0;
         //---
         if(inpUseArrows)
           {
            if(bufGisto[i]>20)
               bufArrowDn[i]=bufGisto[i];
            else if(bufGisto[i]<-20)
               bufArrowUp[i]=bufGisto[i];
           }
        }
     }
   else if(rates_total>prev_calculated)
     {
      bufGisto[rates_total-1]=EMPTY;
      //---
      if(inpUseArrows)
        {
         bufArrowUp[ rates_total-1 ] = EMPTY;
         bufArrowDn[ rates_total-1 ] = EMPTY;
        }
     }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| Параметры графического построения: цветная гист-а от 0 линии                |
//+------------------------------------------------------------------+
void SetPlotParametersColorHistogram(const int plotIndex,// Индекс графической серии
                                     const int bufferNum,// Номер первого буфера серии
                                     double& value[],                              // Буфер значений
                                     double& clr[],                                 // Буфер цветов
                                     const bool asSeries,                           // Флаг нумерации как в таймсерии
                                     const string label,                           // Имя серии
                                     const color& colors[],                        // Цвета линии
                                     const double emptyValue = EMPTY_VALUE,         // Пустые значения серии
                                     const int width = 0,                           // Толщина линии
                                     const ENUM_LINE_STYLE style = STYLE_SOLID,      // Стиль линии
                                     const int drawBegin = 0,                        // Количество баров без отрисовки
                                     const int shift=0                           // Сдвиг построения в барах
                                     )
  {
//--- Привязываем буферы
   SetIndexBuffer(bufferNum,value,INDICATOR_DATA);
   SetIndexBuffer(bufferNum+1,clr,INDICATOR_COLOR_INDEX);
//--- Устанавливаем порядок нумерации в массивах-буферах
   ArraySetAsSeries(value,asSeries);
   ArraySetAsSeries(clr,asSeries);
//--- Устанавливаем тип графического построения
   PlotIndexSetInteger(plotIndex,PLOT_DRAW_TYPE,DRAW_COLOR_HISTOGRAM);
//--- Устанавливаем имя графической серии
   PlotIndexSetString(plotIndex,PLOT_LABEL,label);
//--- Устанавливаем пустые значения в буферах
   PlotIndexSetDouble(plotIndex,PLOT_EMPTY_VALUE,emptyValue);
//--- Устанавливаем количество цветов индикатора
   const int size=ArraySize(colors);
   PlotIndexSetInteger(plotIndex,PLOT_COLOR_INDEXES,size);
//--- Устанавливаем цвета индикатора
   for(int i=0; i<size; i++)
      PlotIndexSetInteger(plotIndex,PLOT_LINE_COLOR,i,colors[i]);
//--- Устанавливаем толщину линии
   PlotIndexSetInteger(plotIndex,PLOT_LINE_WIDTH,width);
//--- Устанавливаем стиль линии
   PlotIndexSetInteger(plotIndex,PLOT_LINE_STYLE,style);
//--- Устанавливаем количество баров без отрисовки и значений в DataWindow
   PlotIndexSetInteger(plotIndex,PLOT_DRAW_BEGIN,drawBegin);
//--- Устанавливаем сдвиг графического построения по оси времени в барах
   PlotIndexSetInteger(plotIndex,PLOT_SHIFT,shift);
  }
//+------------------------------------------------------------------+
//| Параметры графического построения: стрелки                                                          |
//+------------------------------------------------------------------+
void SetPlotParametersArrow(const int plotIndex,// Индекс графической серии
                            const int bufferNum,// Номер первого буфера серии
                            double &value[],// Буфер значений
                            const bool asSeries,// Флаг нумерации как в таймсерии
                            const string label,// Имя серии
                            const double emptyValue=EMPTY_VALUE,// Пустые значения серии
                            const color clr=clrRed,// Цвет стрелок
                            const int arrowCode= 159,// Код стрелок
                            const int arrowShift = 0,// Сдвиг стрелок по вертикали
                            const int width=0,// Толщина стрелок
                            const int drawBegin=0,// Количество баров без отрисовки
                            const int shift=0                     // Сдвиг построения в барах
                            )
  {
//--- Привязываем буферы
   SetIndexBuffer(bufferNum,value,INDICATOR_DATA);
//--- Устанавливаем порядок нумерации в массивах-буферах
   ArraySetAsSeries(value,asSeries);
//--- Устанавливаем тип графического построения
   PlotIndexSetInteger(plotIndex,PLOT_DRAW_TYPE,DRAW_ARROW);
//--- Устанавливаем имя графической серии
   PlotIndexSetString(plotIndex,PLOT_LABEL,label);
//--- Устанавливаем пустые значения в буферах
   PlotIndexSetDouble(plotIndex,PLOT_EMPTY_VALUE,emptyValue);
//--- Устанавливаем цвет индикатора
   PlotIndexSetInteger(plotIndex,PLOT_LINE_COLOR,0,clr);
//--- Устанавливаем код стрелок
   PlotIndexSetInteger(plotIndex,PLOT_ARROW,arrowCode);
//--- Устанавливаем смещение стрелок по вертикали
   PlotIndexSetInteger(plotIndex,PLOT_ARROW_SHIFT,arrowShift);
//--- Устанавливаем толщину стрелок
   PlotIndexSetInteger(plotIndex,PLOT_LINE_WIDTH,width);
//--- Устанавливаем количество баров без отрисовки и значений в DataWindow
   PlotIndexSetInteger(plotIndex,PLOT_DRAW_BEGIN,drawBegin);
//--- Устанавливаем сдвиг графического построения по оси времени в барах
   PlotIndexSetInteger(plotIndex,PLOT_SHIFT,shift);
  }
//+------------------------------------------------------------------+

[Удален] 2017.09.04 16:48 #19854

Anatoli Kazharski:

Ни в какую не идет. Сервисдеск #1832411 x64, 1643.

Anatoli Kazharski 2017.09.04 17:18 #19855

Alexey Kozitsyn:
Ни в какую не идет. Сервисдеск #1832411 x64, 1643.

Независимо от того, указываете ли Вы массивы для стрелок в качестве буферов, они всё равно жёстко заданы:

#property indicator_plots   3
#property indicator_buffers 4

//---

Как вариант, если стрелки не нужно отображать, то их можно просто исключить из показа - DRAW_NONE.

Попробуйте такой вариант:

...
//--- Проверяем, нужно ли отображать объемы
   if(inpUseArrows) // Если отображать нужно
     {
      SetPlotParametersArrow(1,2,bufArrowUp,false,"test up",EMPTY,clrLime,233,10);
      SetPlotParametersArrow(2,3,bufArrowDn,false,"test dn",EMPTY,clrRed,234,-10);
     }
   else
     {
      //--- Устанавливаем тип графического построения
      PlotIndexSetInteger(1,PLOT_DRAW_TYPE,DRAW_NONE);
      PlotIndexSetInteger(2,PLOT_DRAW_TYPE,DRAW_NONE);
     }
...

[Удален] 2017.09.04 17:27 #19856

Anatoli Kazharski:

Независимо от того, указываете ли Вы массивы для стрелок в качестве буферов, они всё равно жёстко заданы:

//---

Как вариант, если стрелки не нужно отображать, то их можно просто исключить из показа - DRAW_NONE.

Попробуйте такой вариант:

Я думал об этом, но тут минус есть. Массивы будут автоматом размечаться и расширяться, жрать ресурс. Лучше пусть разработчики пофиксят баг.

А по поводу того, что жестко заданы... Если я не привязываю буферы к граф. сериям - почему я вижу какой-то неизвестный мусор, от которого я избавиться не могу.

Иначе получается, что динамические индикаторы невозможно нормально построить.

Самый идеальный вариант - чистить буферы в деините и все. Но очистка не помогает...

ExpertRemove().... Подскажите по indicator_buffers. Не СХЕМЫ реализации инсайда. или

fxsaber 2017.09.04 19:36 #19857

Просьба в ME в списке функций/методов по ALT+M показывать еще тип возвращаемого значения.

Konstantin 2017.09.05 04:18 #19858

Не плохо бы ввести разграничение на тип string как принято в других ЯП на обычную строку и "сырую" строку. Думаю к этому все равно придут, но на начальном этапе это исключило бы многие проблемы в будущем.

К примеру в Python при создании "сырой" строки используется r"строка"

Новая версия платформы MetaTrader Новая версия платформы MetaTrader Universal MA Cross EA

Andrey Dik 2017.09.05 04:35 #19859

По какой причине могут не полностью выводится логи в тестере? Всё что можно посмотреть - посмотрел и проверил, победить не смог.

fxsaber 2017.09.05 05:03 #19860

Andrey Dik:

По какой причине могут не полностью выводится логи в тестере? Всё что можно посмотреть - посмотрел и проверил, победить не смог.

Много записей. Смотрите log-файл.

Ошибки, баги, вопросы - страница 1986