//+------------------------------------------------------------------+
//| SocketIsConnected.mq5 |
//| Copyright 2024, MetaQuotes Ltd. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2024, MetaQuotes Ltd."
#property link "https://www.mql5.com
#property version "1.00"
#property description "Add Address to the list of allowed ones in the terminal settings to let the example work"
#property script_show_inputs
input string Address ="www.mql5.com";
input int Port =80;
input bool CloseSocket=true;
bool ExtTLS =false;
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart(void)
{
//--- создаём сокет и получаем его хэндл
int socket=SocketCreate();
//--- проверим хэндл
if(socket!=INVALID_HANDLE)
{
//--- если всё в порядке, подключаемся
if(SocketConnect(socket,Address,Port,1000))
{
PrintFormat("Established connection to %s:%d",Address,Port);
string subject,issuer,serial,thumbprint;
datetime expiration;
//--- если соединение защищено сертификатом, выведем его данные
if(SocketTlsCertificate(socket,subject,issuer,serial,thumbprint,expiration))
{
Print("TLS certificate:");
Print(" Owner: ",subject);
Print(" Issuer: ",issuer);
Print(" Number: ",serial);
Print(" Print: ",thumbprint);
Print(" Expiration: ",expiration);
ExtTLS=true;
}
//--- отправим на сервер запрос GET
if(HTTPSend(socket,"GET / HTTP/1.1\r\nHost: www.mql5.com\r\nUser-Agent: MT5\r\n\r\n"))
{
Print("GET request sent");
//--- прочитаем ответ
if(!HTTPRecv(socket,1000))
Print("Failed to get a response, error ",GetLastError());
}
else
Print("Failed to send GET request, error ",GetLastError());
}
else
{
PrintFormat("Connection to %s:%d failed, error %d",Address,Port,GetLastError());
}
//--- при установленном флаге закроем сокет после использования
if(CloseSocket)
SocketClose(socket);
}
else
Print("Failed to create a socket, error ",GetLastError());
//--- проверим подключение к серверу
bool connected=SocketIsConnected(socket);
//--- если подключение отсутствует - завершаем работу
if(!connected)
{
Print("No connection to server");
}
//--- если есть подключение к серверу
else
{
Print("Connection to the server is available\nThe connection needs to be closed. Closing");
//--- закроем сокет и проверим ещё раз состояние подключения
SocketClose(socket);
connected=SocketIsConnected(socket);
}
//--- распечатаем в журнале текущее состояние подключения к серверу
Print("Currently connected: ",(connected ? "opened" : "closed"));
/*
результат при CloseSocket = true:
No connection to server
Currently connected: closed
результат при CloseSocket = false:
Connection to the server is available
The connection needs to be closed. Closing
Currently connected: closed
*/
}
//+------------------------------------------------------------------+
//| Отправка команды на сервер |
//+------------------------------------------------------------------+
bool HTTPSend(int socket,string request)
{
//--- конвертируем строку в массив символов, терминирующий ноль отбрасываем
char req[];
int len=StringToCharArray(request,req)-1;
if(len<0)
return(false);
//--- если используется защищенное TLS-соединение через порт 443
if(ExtTLS)
return(SocketTlsSend(socket,req,len)==len);
//--- если используется обычное TCP-соединение
return(SocketSend(socket,req,len)==len);
}
//+------------------------------------------------------------------+
//| Чтение ответа сервера |
//+------------------------------------------------------------------+
bool HTTPRecv(int socket,uint timeout_ms)
{
char rsp[];
string result;
ulong timeout_check=GetTickCount64()+timeout_ms;
//--- читаем данные из сокета, пока они есть, но не дольше timeout
do
{
uint len=SocketIsReadable(socket);
if(len)
{
int rsp_len;
//--- разные команды чтения в зависимости от того, защищенное соединение или нет
if(ExtTLS)
rsp_len=SocketTlsRead(socket,rsp,len);
else
rsp_len=SocketRead(socket,rsp,len,timeout_ms);
//--- разберем ответ
if(rsp_len>0)
{
result+=CharArrayToString(rsp,0,rsp_len);
//--- распечатаем только заголовок ответа
int header_end=StringFind(result,"\r\n\r\n");
if(header_end>0)
{
Print("HTTP answer header received:");
Print(StringSubstr(result,0,header_end));
return(true);
}
//--- обновим время истечения таймаута чтения
timeout_check=GetTickCount64()+timeout_ms;
}
}
}
while(GetTickCount64()<timeout_check && !IsStopped());
return(false);
}
|