//+------------------------------------------------------------------+
//| SocketTlsHandshake.mq5 |
//| Copyright 2024, MetaQuotes Ltd. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2024, MetaQuotes Ltd."
#property link "https://www.mql5.com
#property version "1.00"
#define SERVER "smtp.gmail.com"
#define PORT 587
//+------------------------------------------------------------------+
//| Ручное переключение небезопасного соединения на безопасное |
//+------------------------------------------------------------------+
bool TlsHandshake(int socket)
{
//--- получим приветствие от сервера
string rsp;
if(!RecvString(socket,rsp))
return(false);
//--- приветствуем сервер
if(!SendString(socket,"EHLO my.domain.com\r\n"))
return(false);
//--- получаем ответ сервера со списком поддерживаемых команд
if(!RecvString(socket,rsp))
return(false);
//--- распечатаем приветствие
Print("SERVER: ",rsp);
//--- информируем сервер, что хотим перейти с небезопасного соединения на безопасное с использованием TLS
if(!SendString(socket,"STARTTLS\r\n"))
return(false);
//--- получаем ответ сервера
if(!RecvString(socket,rsp))
return(false);
//--- в примере мы не проверяем ответ сервера о готовности перейти на TLS ('Ready to start TLS')
//--- инициируем защищенное TLS (SSL)-соединение с указанным хостом по протоколу TLS Handshake
if(SocketTlsHandshake(socket,SERVER))
return(true);
Print("SocketTlsHandshake() failed. Error ",GetLastError());
return(false);
}
//+------------------------------------------------------------------+
//| Script program start function |
//+------------------------------------------------------------------+
void OnStart(void)
{
//--- создаём сокет и получаем его хэндл
int socket=SocketCreate();
if(socket==INVALID_HANDLE)
{
Print("SocketCreate() failed. Error ",GetLastError());
return;
}
//--- подключаемся к серверу SERVER по порту PORT
if(!SocketConnect(socket,SERVER,PORT,10000))
{
Print("SocketConnect() failed. Error ",GetLastError());
}
else
{
//--- установлено небезопасное соединение
PrintFormat("%s connection has been established to %s:%d",(PORT==443 ? "A secured" : "An unsecured"),SERVER,PORT);
//--- переключаем на безопасное соединение
if(PORT!=443 && TlsHandshake(socket))
{
PrintFormat("Unsecured connection to %s:%d switched to secured",SERVER,PORT);
//--- если соединение защищено сертификатом, выведем его данные
string subject,issuer,serial,thumbprint;
datetime expiration;
if(SocketTlsCertificate(socket,subject,issuer,serial,thumbprint,expiration))
{
Print("TLS certificate:");
Print(" Owner: ",subject);
Print(" Issuer: ",issuer);
Print(" Number: ",serial);
Print(" Print: ",thumbprint);
Print(" Expiration: ",expiration);
}
}
}
//--- закроем сокет после использования
SocketClose(socket);
/*
результат:
An unsecured connection has been established to smtp.gmail.com:587
SERVER: 220 smtp.gmail.com ESMTP a640c23a62f3a-a9b1f298319sm82305866b.105 - gsmtp
SERVER: 250-smtp.gmail.com at your service, [37.193.40.122]
250-SIZE 35882577
250-8BITMIME
250-STARTTLS
250-ENHANCEDSTATUSCODES
250-PIPELINING
250-CHUNKING
250 SMTPUTF8
SERVER: 220 2.0.0 Ready to start TLS
SocketTlsHandshake(): A secure connection to smtp.gmail.com:587 is now established
TLS certificate:
Owner: /CN=smtp.gmail.com
Issuer: /C=US/O=Google Trust Services/CN=WR2
Number: 1f:f4:db:2a:5a:e6:dc:52:0a:4c:05:ce:81:cc:c3:f7
Print: d6be8af229b5329cd3d4c2789c02aa94f89b421c
Expiration: 2024.12.30 08:25:30
*/
}
//+------------------------------------------------------------------+
//| Отправляет строку на сервер |
//+------------------------------------------------------------------+
bool SendString(int socket,const string str)
{
//--- конвертируем строку в массив символов
uchar data[];
int size=StringToCharArray(str,data,0,str.Length(),CP_UTF8);
//--- отправляем данные в сокет
ResetLastError();
if(SocketSend(socket,data,size)==size)
return(true);
//--- ошибка отправки данных
Print("Failed to send data to server. Error ",GetLastError());
return false;
}
//+------------------------------------------------------------------+
//| Получает строку с сервера |
//+------------------------------------------------------------------+
bool RecvString(int socket,string& result,uint timeout_ms=1000)
{
//--- ждём появления данных на сокете
ulong wait_time_end=GetMicrosecondCount()+timeout_ms*1000;
while(!SocketIsReadable(socket))
{
Sleep(10);
//--- время ожидания данных истекло - возвращаем NULL в качестве ответа
if(wait_time_end<GetMicrosecondCount())
{
Print("ERROR: No response from server");
return(false);
}
}
//--- читаем данные из сокета
uchar data[128];
uint size=0;
string resp=NULL;
do
{
uchar b[1];
int n=SocketRead(socket,b,1,1000);
if(n < 0)
break;
if(n)
{
data[size++]=b[0];
if(size==data.Size())
{
resp += CharArrayToString(data,0,data.Size(),CP_UTF8);
size = 0;
}
}
}
while(SocketIsReadable(socket));
//--- копируем в строку прочитанные данные
if(size)
resp+=CharArrayToString(data,0,size,CP_UTF8);
//--- если пустая строка, то ошибка
if(!resp.Length())
{
Print("ERROR: No response from server");
return(false);
}
//--- отдаём строку
result=resp;
return(true);
}
|