Referência MQL5Biblioteca PadrãoMatemáticaLógica difusaFunções de associaçãoCP_ShapedMembershipFunction

CP_ShapedMembershipFunction

Classe para implementar a função de associação em forma de Pi com parâmetros A, B, C e D.

Descrição

A função de associação em forma de Pi tem forma de trapézio curvilíneo. A função é usada para definir funções de associação assimétricas com uma transição suave de avaliação pessimista para optimista do número difuso.

fuzzy_p_function

Exemplo de código para plotagem do gráfico mostrado abaixo.

Declaração

class CP_ShapedMembershipFuncion : public IMembershipFunction

Cabeçalho

#include <Math\Fuzzy\membershipfunction.mqh>

Hierarquia de herança

CObject

IMembershipFunction

CP_ShapedMembershipFunction

Métodos de classe

Método de classe	Descrição
A	Retorna e define o parâmetro de início do conjunto difuso.
B	Retorna e define o primeiro parâmetro de núcleo do conjunto difuso.
C	Retorna e define o segundo parâmetro de núcleo do conjunto difuso.
D	Retorna e define o parâmetro de fim do conjunto difuso.
GetValue	Calcula o valor da função de associação para o argumento especificado.

Métodos herdados da classe CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Exemplo

//+------------------------------------------------------------------+
//|                                   P_ShapedMembershipFunction.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Create membership functions
CP_ShapedMembershipFunction func1(0,0.5,3,9);
CP_ShapedMembershipFunction func2(0,4,5.5,9);
CP_ShapedMembershipFunction func3(0,6,7,9);
//--- Create wrappers for membership functions
double P_ShapedMembershipFunction1(double x) { return(func1.GetValue(x)); }
double P_ShapedMembershipFunction2(double x) { return(func2.GetValue(x)); }
double P_ShapedMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- create graphic
   CGraphic graphic;
   if(!graphic.Create(0,"P_ShapedMembershipFunction",0,30,30,780,380))
     {
      graphic.Attach(0,"P_ShapedMembershipFunction");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("P_ShapedMembershipFunction");
   graphic.BackgroundMainSize(16);
//--- create curve
   graphic.CurveAdd(P_ShapedMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[0, 0.5, 3, 9]");
   graphic.CurveAdd(P_ShapedMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[0, 4, 5.5, 9]");
   graphic.CurveAdd(P_ShapedMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[0, 6, 7, 9]");
//--- sets the X-axis properties
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- sets the Y-axis properties
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- plot
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue