MQL5 RiferimentoLibreria StandardMatematicheLogica fuzzyMembership functionsCP_ShapedMembershipFunction

CP_ShapedMembershipFunction

Classe per implementare una funzione di appartenenza a forma-pi con i parametri A, B, C e D.

Descrizione

La funzione di appartenenza a forma di pi ha la forma di un trapezio curvilineo. La funzione permette di impostare funzioni di appartenenza asimmetriche con una transizione graduale dalla valutazione pessimistia ad ottimista del numero fuzzy.

fuzzy_p_function

Un codice di esempio per tracciare un grafico viene visualizzato qui di seguito.

Dichiarazione

class CP_ShapedMembershipFuncion : public IMembershipFunction

Titolo

#include <Math\Fuzzy\membershipfunction.mqh>

Gerarchia di ereditarietà

CObject

IMembershipFunction

CP_ShapedMembershipFunction

I metodi della classe

I metodi della classe	Descrizione
A	Ottiene ed imposta il parametro dell'inizio del set fuzzy.
B	Ottiene ed imposta il primo parametro del nucleo dell' insieme fuzzy.
C	Ottiene ed imposta il secondo parametro del nucleo dell' insieme fuzzy.
D	Ottiene e imposta il parametro di fine del set fuzzy.
GetValue	Calcola il valore della funzione di appartenenza da un argomento specificato.

Metodi ereditati dalla classe CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Esempio

//+------------------------------------------------------------------+
//|                                   P_ShapedMembershipFunction.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Crea funzioni di appartenenza
CP_ShapedMembershipFunction func1(0,0.5,3,9);
CP_ShapedMembershipFunction func2(0,4,5.5,9);
CP_ShapedMembershipFunction func3(0,6,7,9);
//--- Crea wrapper per funzioni di appartenenza
double P_ShapedMembershipFunction1(double x) { return(func1.GetValue(x)); }
double P_ShapedMembershipFunction2(double x) { return(func2.GetValue(x)); }
double P_ShapedMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Funzione di start del programma Script                           |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- crea grafica
   CGraphic graphic;
   if(!graphic.Create(0,"P_ShapedMembershipFunction",0,30,30,780,380))
     {
      graphic.Attach(0,"P_ShapedMembershipFunction");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("P_ShapedMembershipFunction");
   graphic.BackgroundMainSize(16);
//--- crea curva
   graphic.CurveAdd(P_ShapedMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[0, 0.5, 3, 9]");
   graphic.CurveAdd(P_ShapedMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[0, 4, 5.5, 9]");
   graphic.CurveAdd(P_ShapedMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[0, 6, 7, 9]");
//--- imposta le proprietà dell'asse X
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- imposta le proprietà asse Y
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- plotta
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue