문서화섹션
MQL5 リファレンスネットワーク関数SendNotification 

SendNotification

"알림" 탭에서 MetaQuotes ID가 지정된 모바일 터미널로 푸시 알림을 보냅니다.

bool  SendNotification(
   string  text          // 알림 텍스트
   );

매개 변수

텍스트

[in]   알림 텍스트. 메시지 길이는 255자를 초과할 수 없습니다.

반환값

터미널에서 알림이 성공적으로 전송된 경우 true이고, 오류가 발생한 경우 false를 반환합니다. 알림 푸시 실패후 확인시, GetLastError ()는 다음 오류 중 하나를 반환할 수 있습니다

  • 4515 – ERR_NOTIFICATION_SEND_FAILED,
  • 4516 – ERR_NOTIFICATION_WRONG_PARAMETER,
  • 4517 – ERR_NOTIFICATION_WRONG_SETTINGS,
  • 4518 – ERR_NOTIFICATION_TOO_FREQUENT.

참고

SendNotification() 함수에는 초당 2회 이하의 요청과 분당 10회 이하의 요청이라는 엄격한 사용 제한이 설정되어 있습니다. 사용 빈도 모니터링은 다이내믹합니다. 제한 위반 시 함수가 비활성화될 수 있습니다.

SendNotification() 함수는 Strategy Tester에서 작동하지 않습니다.

예:

//+------------------------------------------------------------------+
//|                                             SendNotification.mq5 |
//|                                  Copyright 2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com
#property version     "1.00"
 
#define   MESSAGE   "Test Message"
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수                                          |
//+------------------------------------------------------------------+
void OnStart(void)
  {
//--- 터미널에서 알림을 보낼 수 있는 권한을 확인합니다.
   if(!TerminalInfoInteger(TERMINAL_NOTIFICATIONS_ENABLED))
     {
      Print("Error. 클라이언트 터미널이 알림을 보낼 수 있는 권한이 없습니다.");
      return;
     }
//--- 알림 보내기
   ResetLastError();
   if(!SendNotification(MESSAGE))
      Print("SendNotification() failed. Error ",GetLastError());
  }