Referência MQL5Métodos matriciais e vetoriaisCaracterísticasNorm

Norm

Retorna a norma de uma matriz ou vetor.

double vector::Norm(
  const ENUM_VECTOR_NORM  norm,     // norma do vetor
  const int                        norm_p=2  // número p-norm caso VECTOR_NORM_P
   );

double matrix::Norm(
  const ENUM_MATRIX_NORM  norm      // norma da matriz
   );

Parâmetros

norm

[in] Ordem da norma

Valor retornado

Norma de uma matriz ou vetor.

Observação

VECTOR_NORM_INF – valor absoluto máximo entre os elementos do vetor.
VECTOR_NORM_MINUS_INF – valor mínimo absoluto do vetor.
VECTOR_NORM_P – norma-p do vetor. Se norm_p=0, é o número de elementos não nulos do vetor; norm_p=1 é a soma dos valores absolutos dos elementos vetoriais; norm_p=2 é a raiz quadrada da soma dos quadrados dos valores dos elementos vetoriais. A norma-p pode ser negativa.
MATRIX_NORM_FROBENIUS – raiz quadrada da soma dos quadrados dos valores dos elementos da matriz. A norma de Frobenius e a norma do vetor P2 são consistentes.
MATRIX_NORM_SPECTRAL – valor máximo do espectro da matriz.
MATRIX_NORM_NUCLEAR – soma dos valores singulares da matriz.
MATRIX_NORM_INF – norma-p1 vetorial máxima entre os vetores verticais da matriz. A norma inf da matriz e a norma inf do vetor são consistentes.
MATRIX_NORM_MINUS_INF – norma-p1 vetorial mínima entre os vetores verticais da matriz.
MATRIX_NORM_P1 – norma-p1 vetorial máxima entre os vetores horizontais da matriz.
MATRIX_NORM_MINUS_P1 – norma-p1 vetorial mínima entre os vetores horizontais da matriz.
MATRIX_NORM_P2 – maior valor singular da matriz.
MATRIX_NORM_MINUS_P2 – menor valor singular da matriz.

Algoritmo simples para calcular a norma-p de um vetor em MQL5:

double VectorNormP(const vector& v,int norm_value)
  {
   ulong  i;
   double norm=0.0;
//---
   switch(norm_value)
     {
      case 0 :
         for(i=0; i<v.Size(); i++)
            if(v[i]!=0)
               norm+=1.0;
         break;
      case 1 :
         for(i=0; i<v.Size(); i++)
            norm+=MathAbs(v[i]);
         break;
      case 2 :
         for(i=0; i<v.Size(); i++)
            norm+=v[i]*v[i];
         norm=MathSqrt(norm);
         break;
      default :
         for(i=0; i<v.Size(); i++)
            norm+=MathPow(MathAbs(v[i]),norm_value);
         norm=MathPow(norm,1.0/norm_value);
     }
//---
   return(norm);
  }

Exemplo em MQL5:

  matrix a= {{0, 1, 2, 3, 4, 5, 6, 7, 8}};
  a=a-4;
  Print("matrix a \n", a);
  a.Reshape(3, 3);
  matrix b=a;
  Print("matrix b \n", b);
  Print("b.Norm(MATRIX_NORM_P2)=", b.Norm(MATRIX_NORM_FROBENIUS));
  Print("b.Norm(MATRIX_NORM_FROBENIUS)=", b.Norm(MATRIX_NORM_FROBENIUS));
  Print("b.Norm(MATRIX_NORM_INF)", b.Norm(MATRIX_NORM_INF));
  Print("b.Norm(MATRIX_NORM_MINUS_INF)", b.Norm(MATRIX_NORM_MINUS_INF));
  Print("b.Norm(MATRIX_NORM_P1)=)", b.Norm(MATRIX_NORM_P1));
  Print("b.Norm(MATRIX_NORM_MINUS_P1)=", b.Norm(MATRIX_NORM_MINUS_P1));
  Print("b.Norm(MATRIX_NORM_P2)=", b.Norm(MATRIX_NORM_P2));
  Print("b.Norm(MATRIX_NORM_MINUS_P2)=", b.Norm(MATRIX_NORM_MINUS_P2));

  /*
  matrix a
  [[-4,-3,-2,-1,0,1,2,3,4]]
  matrix b
  [[-4,-3,-2]
  [-1,0,1]
  [2,3,4]]
  b.Norm(MATRIX_NORM_P2)=7.745966692414834
  b.Norm(MATRIX_NORM_FROBENIUS)=7.745966692414834
  b.Norm(MATRIX_NORM_INF)9.0
  b.Norm(MATRIX_NORM_MINUS_INF)2.0
  b.Norm(MATRIX_NORM_P1)=)7.0
  b.Norm(MATRIX_NORM_MINUS_P1)=6.0
  b.Norm(MATRIX_NORM_P2)=7.348469228349533
  b.Norm(MATRIX_NORM_MINUS_P2)=1.857033188519056e-16
  */

Exemplo em Python:

import numpy as np
from numpy import linalg as LA
a = np.arange(9) - 4
print("a \n",a)
b = a.reshape((3, 3))
print("b \n",b)
print("LA.norm(b)=",LA.norm(b))
print("LA.norm(b, 'fro')=",LA.norm(b, 'fro'))
print("LA.norm(b, np.inf)=",LA.norm(b, np.inf))
print("LA.norm(b, -np.inf)=",LA.norm(b, -np.inf))
print("LA.norm(b, 1)=",LA.norm(b, 1))
print("LA.norm(b, -1)=",LA.norm(b, -1))
print("LA.norm(b, 2)=",LA.norm(b, 2))
print("LA.norm(b, -2)=",LA.norm(b, -2))

a
[-4 -3 -2 -1  0  1  2  3  4]
b
[[-4 -3 -2]
[-1  0  1]
[ 2  3  4]]
LA.norm(b)= 7.745966692414834
LA.norm(b, 'fro')= 7.745966692414834
LA.norm(b, np.inf)= 9.0
LA.norm(b, -np.inf)= 2.0
LA.norm(b, 1)= 7.0
LA.norm(b, -1)= 6.0
LA.norm(b, 2)= 7.3484692283495345
LA.norm(b, -2)= 1.857033188519056e-16

Size

Cond