MQL5 RiferimentoMetodi Matriciali e VettorialiCaratteristicheNorm

Norm

Restituisce la norma di una matrice o vettore.

double vector::Norm(
  const ENUM_VECTOR_NORM  norm,     // norma del vettore
  const int                        norm_p=2  // numero della p-norma nel caso di VECTOR_NORM_P
   );

double matrix::Norm(
  const ENUM_MATRIX_NORM  norm      // norma matriciale
   );

Parametri

norma

[in] Ordine della norma

Valore Restituito

Norma della matrice o vettore

Note

VECTOR_NORM_INF è il valore massimo assoluto tra gli elementi del vettore.
VECTOR_NORM_MINUS_INF è il valore minimo assoluto di un vettore.
VECTOR_NORM_P è la p-norma del vettore. Se norm_p=0, allora questo è il numero di elementi vettoriali diversi da zero. norm_p=1 è la somma dei valori assoluti degli elementi del vettore. norm_p=2 è la radice quadrata della somma dei quadrati dei valori degli elementi del vettore. Norma-p può essere negativa.
MATRIX_NORM_FROBENIUS è la radice quadrata della somma dei quadrati dei valori degli elementi della matrice. La norma di Frobenius e la P2-norma vettore sono compatibili.
MATRIX_NORM_SPECTRAL è il valore massimo dello spettro della matrice.
MATRIX_NORM_NUCLEAR è la somma dei valori singolari della matrice.
MATRIX_NORM_INF è la massima p1-norma vettore tra i vettori verticali della matrice. La matrice norm-inf e il vettore norm-inf sono compatibili.
MATRIX_NORM_MINUS_INF è la minima p1_norma vettore tra i vettori verticali della matrice.
MATRIX_NORM_P1 la massima p1-norma vettore tra i vettori orizzontali della matrice.
MATRIX_NORM_MINUS_P1 è la minima p1_norma vettore tra i vettori orizzontali della matrice.
MATRIX_NORM_P2 è il valore singolare più alto della matrice.
MATRIX_NORM_MINUS_P2 è il valore singolare più basso di una matrice.

Un semplice algoritmo per calcolare la P-norma di un vettore in MQL5:

double VectorNormP(const vector& v,int norm_value)
  {
   ulong  i;
   double norm=0.0;
//---
   switch(norm_value)
     {
      case 0 :
         for(i=0; i<v.Size(); i++)
            if(v[i]!=0)
               norm+=1.0;
         break;
      case 1 :
         for(i=0; i<v.Size(); i++)
            norm+=MathAbs(v[i]);
         break;
      case 2 :
         for(i=0; i<v.Size(); i++)
            norm+=v[i]*v[i];
         norm=MathSqrt(norm);
         break;
      default :
         for(i=0; i<v.Size(); i++)
            norm+=MathPow(MathAbs(v[i]),norm_value);
         norm=MathPow(norm,1.0/norm_value);
     }
//---
   return(norm);
  }

Esempio in MQL5:

  matrix a= {{0, 1, 2, 3, 4, 5, 6, 7, 8}};
  a=a-4;
  Print("matrix a \n", a);
  a.Reshape(3, 3);
  matrix b=a;
  Print("matrix b \n", b);
  Print("b.Norm(MATRIX_NORM_P2)=", b.Norm(MATRIX_NORM_FROBENIUS));
  Print("b.Norm(MATRIX_NORM_FROBENIUS)=", b.Norm(MATRIX_NORM_FROBENIUS));
  Print("b.Norm(MATRIX_NORM_INF)", b.Norm(MATRIX_NORM_INF));
  Print("b.Norm(MATRIX_NORM_MINUS_INF)", b.Norm(MATRIX_NORM_MINUS_INF));
  Print("b.Norm(MATRIX_NORM_P1)=)", b.Norm(MATRIX_NORM_P1));
  Print("b.Norm(MATRIX_NORM_MINUS_P1)=", b.Norm(MATRIX_NORM_MINUS_P1));
  Print("b.Norm(MATRIX_NORM_P2)=", b.Norm(MATRIX_NORM_P2));
  Print("b.Norm(MATRIX_NORM_MINUS_P2)=", b.Norm(MATRIX_NORM_MINUS_P2));

  /*
  matrix a
  [[-4,-3,-2,-1,0,1,2,3,4]]
  matrix b
  [[-4,-3,-2]
  [-1,0,1]
  [2,3,4]]
  b.Norm(MATRIX_NORM_P2)=7.745966692414834
  b.Norm(MATRIX_NORM_FROBENIUS)=7.745966692414834
  b.Norm(MATRIX_NORM_INF)9.0
  b.Norm(MATRIX_NORM_MINUS_INF)2.0
  b.Norm(MATRIX_NORM_P1)=)7.0
  b.Norm(MATRIX_NORM_MINUS_P1)=6.0
  b.Norm(MATRIX_NORM_P2)=7.348469228349533
  b.Norm(MATRIX_NORM_MINUS_P2)=1.857033188519056e-16
  */

Esempio in Python:

import numpy as np
from numpy import linalg as LA
a = np.arange(9) - 4
print("a \n",a)
b = a.reshape((3, 3))
print("b \n",b)
print("LA.norm(b)=",LA.norm(b))
print("LA.norm(b, 'fro')=",LA.norm(b, 'fro'))
print("LA.norm(b, np.inf)=",LA.norm(b, np.inf))
print("LA.norm(b, -np.inf)=",LA.norm(b, -np.inf))
print("LA.norm(b, 1)=",LA.norm(b, 1))
print("LA.norm(b, -1)=",LA.norm(b, -1))
print("LA.norm(b, 2)=",LA.norm(b, 2))
print("LA.norm(b, -2)=",LA.norm(b, -2))

a
[-4 -3 -2 -1  0  1  2  3  4]
b
[[-4 -3 -2]
[-1  0  1]
[ 2  3  4]]
LA.norm(b)= 7.745966692414834
LA.norm(b, 'fro')= 7.745966692414834
LA.norm(b, np.inf)= 9.0
LA.norm(b, -np.inf)= 2.0
LA.norm(b, 1)= 7.0
LA.norm(b, -1)= 6.0
LA.norm(b, 2)= 7.3484692283495345
LA.norm(b, -2)= 1.857033188519056e-16

Size

Cond