Nachschlagewerk MQL5Matrizen und VektorenEigenschaftenNorm

Norm

Rückgabe der Matrix- oder Vektornorm.

double vector::Norm(
  const ENUM_VECTOR_NORM  norm,     // Vektornorm
  const int                        norm_p=2  // Zahl der P-Norm im Falles von VECTOR_NORM_P
   );

double matrix::Norm(
  const ENUM_MATRIX_NORM  norm      // Matrixnorm
   );

Parameter

Norm

[in] Art der Norm

Rückgabewert

Matrix- oder Vektornorm

Hinweis

VECTOR_NORM_INF ist der maximale, absolute Wert unter den Vektorelementen.
VECTOR_NORM_MINUS_INF ist der minimale, absolute Wert eines Vektors.
VECTOR_NORM_P ist die P-Norm des Vektors. Wenn norm_p=0 ist, ist dies die Anzahl der Vektorelemente, die nicht Null sind. norm_p=1 ist die Summe der Absolutwerte der Vektorelemente. norm_p=2 ist die Quadratwurzel aus der Summe der Quadrate der Werte der Vektorelemente. P-Norm kann negativ sein.
MATRIX_NORM_FROBENIUS ist die Quadratwurzel aus der Summe der Quadrate der Werte der Matrixelemente. Die Frobenius-Norm und die Vektor-P2-Norm sind konsistent.
MATRIX_NORM_SPECTRAL ist der Maximalwert des Matrixspektrums.
MATRIX_NORM_NUCLEAR ist die Summe der Singulärwerte der Matrix.
MATRIX_NORM_INF ist die maximale p1-Norm des Vektors unter den vertikalen Vektoren der Matrix. Die Matrix-Inf-Norm und die Vektor-Inf-Norm sind konsistent.
MATRIX_NORM_MINUS_INF ist die minimale p1-Norm des Vektors unter den vertikalen Vektoren der Matrix.
MATRIX_NORM_P1 ist die p1-Norm des maximalen Vektors unter den horizontalen Matrixvektoren.
MATRIX_NORM_MINUS_P1 ist die p1-Norm des minimalen Vektors unter den horizontalen Matrixvektoren.
MATRIX_NORM_P2 ist der höchste Singulärwert der Matrix.
MATRIX_NORM_MINUS_P2 ist der niedrigste Singulärwert einer Matrix.

Ein einfacher Algorithmus zur Berechnung der P-Norm eines Vektors in MQL5:

double VectorNormP(const vector& v,int norm_value)
  {
   ulong  i;
   double norm=0.0;
//---
   switch(norm_value)
     {
      case 0 :
         for(i=0; i<v.Size(); i++)
            if(v[i]!=0)
               norm+=1.0;
         break;
      case 1 :
         for(i=0; i<v.Size(); i++)
            norm+=MathAbs(v[i]);
         break;
      case 2 :
         for(i=0; i<v.Size(); i++)
            norm+=v[i]*v[i];
         norm=MathSqrt(norm);
         break;
      default :
         for(i=0; i<v.Size(); i++)
            norm+=MathPow(MathAbs(v[i]),norm_value);
         norm=MathPow(norm,1.0/norm_value);
     }
//---
   return(norm);
  }

MQL5 Beispiel:

  matrix a= {{0, 1, 2, 3, 4, 5, 6, 7, 8}};
  a=a-4;
  Print("matrix a \n", a);
  a.Reshape(3, 3);
  matrix b=a;
  Print("matrix b \n", b);
  Print("b.Norm(MATRIX_NORM_P2)=", b.Norm(MATRIX_NORM_FROBENIUS));
  Print("b.Norm(MATRIX_NORM_FROBENIUS)=", b.Norm(MATRIX_NORM_FROBENIUS));
  Print("b.Norm(MATRIX_NORM_INF)", b.Norm(MATRIX_NORM_INF));
  Print("b.Norm(MATRIX_NORM_MINUS_INF)", b.Norm(MATRIX_NORM_MINUS_INF));
  Print("b.Norm(MATRIX_NORM_P1)=)", b.Norm(MATRIX_NORM_P1));
  Print("b.Norm(MATRIX_NORM_MINUS_P1)=", b.Norm(MATRIX_NORM_MINUS_P1));
  Print("b.Norm(MATRIX_NORM_P2)=", b.Norm(MATRIX_NORM_P2));
  Print("b.Norm(MATRIX_NORM_MINUS_P2)=", b.Norm(MATRIX_NORM_MINUS_P2));

  /*
  matrix a
  [[-4,-3,-2,-1,0,1,2,3,4]]
  matrix b
  [[-4,-3,-2]
  [-1,0,1]
  [2,3,4]]
  b.Norm(MATRIX_NORM_P2)=7.745966692414834
  b.Norm(MATRIX_NORM_FROBENIUS)=7.745966692414834
  b.Norm(MATRIX_NORM_INF)9.0
  b.Norm(MATRIX_NORM_MINUS_INF)2.0
  b.Norm(MATRIX_NORM_P1)=)7.0
  b.Norm(MATRIX_NORM_MINUS_P1)=6.0
  b.Norm(MATRIX_NORM_P2)=7.348469228349533
  b.Norm(MATRIX_NORM_MINUS_P2)=1.857033188519056e-16
  */

Python Beispiel:

import numpy as np
from numpy import linalg as LA
a = np.arange(9) - 4
print("a \n",a)
b = a.reshape((3, 3))
print("b \n",b)
print("LA.norm(b)=",LA.norm(b))
print("LA.norm(b, 'fro')=",LA.norm(b, 'fro'))
print("LA.norm(b, np.inf)=",LA.norm(b, np.inf))
print("LA.norm(b, -np.inf)=",LA.norm(b, -np.inf))
print("LA.norm(b, 1)=",LA.norm(b, 1))
print("LA.norm(b, -1)=",LA.norm(b, -1))
print("LA.norm(b, 2)=",LA.norm(b, 2))
print("LA.norm(b, -2)=",LA.norm(b, -2))

a
[-4 -3 -2 -1  0  1  2  3  4]
b
[[-4 -3 -2]
[-1  0  1]
[ 2  3  4]]
LA.norm(b)= 7.745966692414834
LA.norm(b, 'fro')= 7.745966692414834
LA.norm(b, np.inf)= 9.0
LA.norm(b, -np.inf)= 2.0
LA.norm(b, 1)= 7.0
LA.norm(b, -1)= 6.0
LA.norm(b, 2)= 7.3484692283495345
LA.norm(b, -2)= 1.857033188519056e-16

Size

Cond