Manual de referencia de MQL5Métodos de matrices y vectoresCaracterísticasNorm

Norm

Retorna la norma de una matriz o vector.

double vector::Norm(
  const ENUM_VECTOR_NORM  norm,     // norma del vector
  const int                        norm_p=2  // número p-norm en el caso VECTOR_NORM_P
   );

double matrix::Norm(
  const ENUM_MATRIX_NORM  norm      // norma de la matriz
   );

Parámetros

norm

[in] Orden de la norma

Valor retornado

Norma de una matriz o vector.

Observación

VECTOR_NORM_INF – valor absoluto máximo entre los elementos del vector.
VECTOR_NORM_MINUS_INF – valor absoluto mínimo del vector.
VECTOR_NORM_P – norma P del vector. Si norm_p=0, será el número de elementos del vector distintos de cero; norm_p=1 será la suma de los valores absolutos de los elementos del vector; norm_p=2 será la raíz cuadrada de la suma de los cuadrados de los valores de los elementos del vector. La norma P puede ser negativa.
MATRIX_NORM_FROBENIUS – raíz cuadrada de la suma de los cuadrados de los valores de los elementos de la matriz. La norma de Frobenius y la norma P2 del vector son coherentes.
MATRIX_NORM_SPECTRAL – valor máximo del espectro de la matriz.
MATRIX_NORM_NUCLEAR – suma de los valores singulares de la matriz.
MATRIX_NORM_INF – norma P1 vectorial máxima entre los vectores verticales de la matriz. La norma inf de la matriz y la norma del vector son consistentes.
MATRIX_NORM_MINUS_INF – norma P1 vectorial mínima entre los vectores verticales de la matriz.
MATRIX_NORM_P1 – norma P1 vectorial máxima entre los vectores horizontales de la matriz.
MATRIX_NORM_MINUS_P1 – norma P1 vectorial mínima entre los vectores horizontales de la matriz.
MATRIX_NORM_P2 – valor singular mayor de la matriz.
MATRIX_NORM_MINUS_P2 – valor singular menor de la matriz.

Aquí vemos un algoritmo simple para calcular el vector de norma P en MQL5:

double VectorNormP(const vector& v,int norm_value)
  {
   ulong  i;
   double norm=0.0;
//---
   switch(norm_value)
     {
      case 0 :
         for(i=0; i<v.Size(); i++)
            if(v[i]!=0)
               norm+=1.0;
         break;
      case 1 :
         for(i=0; i<v.Size(); i++)
            norm+=MathAbs(v[i]);
         break;
      case 2 :
         for(i=0; i<v.Size(); i++)
            norm+=v[i]*v[i];
         norm=MathSqrt(norm);
         break;
      default :
         for(i=0; i<v.Size(); i++)
            norm+=MathPow(MathAbs(v[i]),norm_value);
         norm=MathPow(norm,1.0/norm_value);
     }
//---
   return(norm);
  }

Ejemplo en MQL5:

  matrix a= {{0, 1, 2, 3, 4, 5, 6, 7, 8}};
  a=a-4;
  Print("matrix a \n", a);
  a.Reshape(3, 3);
  matrix b=a;
  Print("matrix b \n", b);
  Print("b.Norm(MATRIX_NORM_P2)=", b.Norm(MATRIX_NORM_FROBENIUS));
  Print("b.Norm(MATRIX_NORM_FROBENIUS)=", b.Norm(MATRIX_NORM_FROBENIUS));
  Print("b.Norm(MATRIX_NORM_INF)", b.Norm(MATRIX_NORM_INF));
  Print("b.Norm(MATRIX_NORM_MINUS_INF)", b.Norm(MATRIX_NORM_MINUS_INF));
  Print("b.Norm(MATRIX_NORM_P1)=)", b.Norm(MATRIX_NORM_P1));
  Print("b.Norm(MATRIX_NORM_MINUS_P1)=", b.Norm(MATRIX_NORM_MINUS_P1));
  Print("b.Norm(MATRIX_NORM_P2)=", b.Norm(MATRIX_NORM_P2));
  Print("b.Norm(MATRIX_NORM_MINUS_P2)=", b.Norm(MATRIX_NORM_MINUS_P2));

  /*
  matrix a
  [[-4,-3,-2,-1,0,1,2,3,4]]
  matrix b
  [[-4,-3,-2]
  [-1,0,1]
  [2,3,4]]
  b.Norm(MATRIX_NORM_P2)=7.745966692414834
  b.Norm(MATRIX_NORM_FROBENIUS)=7.745966692414834
  b.Norm(MATRIX_NORM_INF)9.0
  b.Norm(MATRIX_NORM_MINUS_INF)2.0
  b.Norm(MATRIX_NORM_P1)=)7.0
  b.Norm(MATRIX_NORM_MINUS_P1)=6.0
  b.Norm(MATRIX_NORM_P2)=7.348469228349533
  b.Norm(MATRIX_NORM_MINUS_P2)=1.857033188519056e-16
  */

Ejemplo en Python:

import numpy as np
from numpy import linalg as LA
a = np.arange(9) - 4
print("a \n",a)
b = a.reshape((3, 3))
print("b \n",b)
print("LA.norm(b)=",LA.norm(b))
print("LA.norm(b, 'fro')=",LA.norm(b, 'fro'))
print("LA.norm(b, np.inf)=",LA.norm(b, np.inf))
print("LA.norm(b, -np.inf)=",LA.norm(b, -np.inf))
print("LA.norm(b, 1)=",LA.norm(b, 1))
print("LA.norm(b, -1)=",LA.norm(b, -1))
print("LA.norm(b, 2)=",LA.norm(b, 2))
print("LA.norm(b, -2)=",LA.norm(b, -2))

a
[-4 -3 -2 -1  0  1  2  3  4]
b
[[-4 -3 -2]
[-1  0  1]
[ 2  3  4]]
LA.norm(b)= 7.745966692414834
LA.norm(b, 'fro')= 7.745966692414834
LA.norm(b, np.inf)= 9.0
LA.norm(b, -np.inf)= 2.0
LA.norm(b, 1)= 7.0
LA.norm(b, -1)= 6.0
LA.norm(b, 2)= 7.3484692283495345
LA.norm(b, -2)= 1.857033188519056e-16

Size

Cond