Opposite trade - expert para MetaTrader 5

Abrimos uma posição oposta à fechada, com o mesmo volume. Funciona para qualquer símbolo e qualquer magic.

Por exemplo, temos uma posição aberta em AUDUSD BUY 0.01. Como esta posição está fechada (por exemplo, fechamos manualmente), o Expert Advisor Opposite trade abrirá imediatamente novas posições no par AUDUSD, agora é uma posição SELL.

O código inteiro está contido na função OnTradeTransaction:

//+------------------------------------------------------------------+
//| TradeTransaction function                                        |
//+------------------------------------------------------------------+
void OnTradeTransaction(const MqlTradeTransaction &trans,
                        const MqlTradeRequest &request,
                        const MqlTradeResult &result)
  {
//--- get transaction type as enumeration value 
   ENUM_TRADE_TRANSACTION_TYPE type=trans.type;
//--- if transaction is result of addition of the transaction in history
   if(type==TRADE_TRANSACTION_DEAL_ADD)
     {
      long     deal_type         =-1;
      long     deal_entry        =-1;
      double   deal_volume       =0.0;
      string   deal_symbol       ="";
      if(HistoryDealSelect(trans.deal))
        {
         deal_type         =HistoryDealGetInteger(trans.deal,DEAL_TYPE);
         deal_entry        =HistoryDealGetInteger(trans.deal,DEAL_ENTRY);
         deal_volume       =HistoryDealGetDouble(trans.deal,DEAL_VOLUME);
         deal_symbol       =HistoryDealGetString(trans.deal,DEAL_SYMBOL);
        }
      else
         return;
      if(deal_entry==DEAL_ENTRY_OUT)
        {
         switch((int)deal_type)
           {
            case  DEAL_TYPE_BUY:
               m_trade.Buy(deal_volume,deal_symbol);
               break;
            case  DEAL_TYPE_SELL:
               m_trade.Sell(deal_volume,deal_symbol);
               break;
            default:
               break;
           }
        }
     }
  }

Aqui esperamos a transação de fechamento de posição (DEAL_ENTRY_OUT). Uma vez que esta transação aparece, verificamos a posição do trade (se fecharmos uma compra, esta será uma transação de venda e vice-versa) e abriremos uma nova posição.