反対取引 - MetaTrader 5のためのエキスパート

決済したポジションと反対のポジションを同じ取引量で開きます。これは任意の銘柄と任意のマジックナンバーで動作します。

たとえば、AUDUSD BUY 0.01ポジションがあるとします。このポジションが閉じられる（たとえば、手動で決済するなど）とOpposite tradeエキスパートアドバイザーはすぐに新しいAUDUSDの売りポジションを開きます。

コードはすべてOnTradeTransaction関数に含まれます。

//+------------------------------------------------------------------+
//| TradeTransaction関数                                              |
//+------------------------------------------------------------------+
void OnTradeTransaction(const MqlTradeTransaction &trans,
                        const MqlTradeRequest &request,
                        const MqlTradeResult &result)
  {
//--- トランザクション型を列挙値として取得する 
   ENUM_TRADE_TRANSACTION_TYPE type=trans.type;
//---トランザクションが履歴にトランザクションを追加した結果である場合
   if(type==TRADE_TRANSACTION_DEAL_ADD)
     {
      long     deal_type         =-1;
      long     deal_entry        =-1;
      double   deal_volume       =0.0;
      string   deal_symbol       ="";
      if(HistoryDealSelect(trans.deal))
        {
         deal_type         =HistoryDealGetInteger(trans.deal,DEAL_TYPE);
         deal_entry        =HistoryDealGetInteger(trans.deal,DEAL_ENTRY);
         deal_volume       =HistoryDealGetDouble(trans.deal,DEAL_VOLUME);
         deal_symbol       =HistoryDealGetString(trans.deal,DEAL_SYMBOL);
        }
      else
         return;
      if(deal_entry==DEAL_ENTRY_OUT)
        {
         switch((int)deal_type)
           {
            case  DEAL_TYPE_BUY:
               m_trade.Buy(deal_volume,deal_symbol);
               break;
            case  DEAL_TYPE_SELL:
               m_trade.Sell(deal_volume,deal_symbol);
               break;
            default:
               break;
           }
        }
     }
  }

ここではポジションを決済する約定(DEAL_ENTRY_OUT).を待ちます。約定が表示されたら、約定のポジションを確認します（買いを閉じた取引場合これは売り約定となり、逆の場合も同様）。新しいポジションを開きます。