//--- 制御要素のライブラリを接続する
#include <ChartObjects\ChartObjectsTxtControls.mqh>
//--- 定義済み定数
#define X_PROPERTY_NAME_1 10 // 最初の列のプロパティ名の x 座標
#define X_PROPERTY_VALUE_1 225 // 最初の列のプロパティ値の x 座標
#define X_PROPERTY_NAME_2 345 // 2 番目の列のプロパティ名の x 座標
#define X_PROPERTY_VALUE_2 550 // 2 番目の列のプロパティ値の x 座標
#define X_BUTTON_1 285 // 最初の列のボタンの x 座標
#define X_BUTTON_2 700 // 2 番目の列のボタンの x 座標
#define Y_PROPERTY_1 30 // 最初及び 2 番目の列の先頭の y 座標
#define Y_PROPERTY_2 286 // 3 番目の列の先頭の y 座標
#define Y_DISTANCE 16 // ライン間のY 軸方向の距離
#define LAST_PROPERTY_NUMBER 111 // 最後のグラフィックプロパティの数
//--- 入力パラメータ
input color InpFirstColor=clrDodgerBlue; // 奇数の線の色
input color InpSecondColor=clrGoldenrod; // 偶数の線の色
//--- 変数と配列
CChartObjectLabel ExtLabelsName[]; // プロパティ名を表示するためのラベル
CChartObjectLabel ExtLabelsValue[]; // プロパティ値を表示するためのラベル
CChartObjectButton ExtButtons[]; // ボタン
int ExtNumbers[]; // プロパティインデックス
string ExtNames[]; // プロパティ名
uchar ExtDataTypes[]; // プロパティのデータ型( integer, double, string)
uint ExtGroupTypes[]; // グループのいずれかに属する特性のデータを格納する配列
uchar ExtDrawTypes[]; // プロパティ表示の種類のデータを格納する配列
double ExtMaxValue[]; // パネルの操作時に可能な最大のプロパティ値
double ExtMinValue[]; // パネルの操作時に可能な最小のプロパティ値
double ExtStep[]; // プロパティ変更ステップ
int ExtCount; // プロパティ総数
color ExtColors[2]; // 線表示の色の配列
string ExtComments[2]; // コメント配列(CHART_COMMENT プロパティ)
//+------------------------------------------------------------------+
//| カスタム指標を初期化する関数 |
//+------------------------------------------------------------------+
int OnInit()
{
//--- チャートにコメントを表示する
Comment("SomeComment");
//--- 後で切り替えが出来るように色を配列に収納する
ExtColors[0]=InpFirstColor;
ExtColors[1]=InpSecondColor;
//--- 後で切り替えが出来るようにコメントを配列に収納する
ExtComments[0]="FirstComment";
ExtComments[1]="SecondComment";
//--- チャートのプロパティを管理するためのコントロールパネルを準備して表示する
if(!PrepareControls())
return(INIT_FAILED);
//--- 実行成功
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| エキスパートの初期化解除関数 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
//--- チャートのコメントを削除する
Comment("");
}
//+------------------------------------------------------------------+
//| チャートイベントハンドラ |
//+------------------------------------------------------------------+
void OnChartEvent(const int id,
const long &lparam,
const double &dparam,
const string &sparam)
{
//--- チャートクリックイベントをチェック
if(id==CHARTEVENT_OBJECT_CLICK)
{
//--- オブジェクト名をセパレータで分ける
string obj_name[];
StringSplit(sparam,'_',obj_name);
//--- オブジェクトがボタンかどうかチェック
if(obj_name[0]=="Button")
{
//--- ボタンインデックスを受け取る
int index=(int)StringToInteger(obj_name[1]);
//--- ボタンを放す
ExtButtons[index].State(false);
//--- プロパティの新しい値を型に応じて設定する
if(ExtDataTypes[index]=='I')
ChangeIntegerProperty(index);
if(ExtDataTypes[index]=='D')
ChangeDoubleProperty(index);
if(ExtDataTypes[index]=='S')
ChangeStringProperty(index);
}
}
//--- プロパティ値を描き直す
RedrawProperties();
ChartRedraw();
}
//+------------------------------------------------------------------+
//| チャートの整数プロパティを変更する |
//+------------------------------------------------------------------+
void ChangeIntegerProperty(const int index)
{
//--- 現プロパティ値を受け取る
long value=ChartGetInteger(0,(ENUM_CHART_PROPERTY_INTEGER)ExtNumbers[index]);
//--- 次のプロパティ値を定義する
switch(ExtDrawTypes[index])
{
case 'C':
value=GetNextColor((color)value);
break;
default:
value=(long)GetNextValue((double)value,index);
break;
}
//--- 新しいプロパティ値を設定する
ChartSetInteger(0,(ENUM_CHART_PROPERTY_INTEGER)ExtNumbers[index],0,value);
}
//+------------------------------------------------------------------+
//| チャートの double 型プロパティを変更する |
//+------------------------------------------------------------------+
void ChangeDoubleProperty(const int index)
{
//--- 現プロパティ値を受け取る
double value=ChartGetDouble(0,(ENUM_CHART_PROPERTY_DOUBLE)ExtNumbers[index]);
//--- 次のプロパティ値を定義する
value=GetNextValue(value,index);
//--- 新しいプロパティ値を設定する
ChartSetDouble(0,(ENUM_CHART_PROPERTY_DOUBLE)ExtNumbers[index],value);
}
//+------------------------------------------------------------------+
//| チャートの string 型プロパティを変更する |
//+------------------------------------------------------------------+
void ChangeStringProperty(const int index)
{
//--- ExtComments配列内部を切り替えるための静的変数
static uint comment_index=1;
//--- 別のコメントを受信するためのインデックスを変更する
comment_index=1-comment_index;
//--- 新しいプロパティ値を設定する
ChartSetString(0,(ENUM_CHART_PROPERTY_STRING)ExtNumbers[index],ExtComments[comment_index]);
}
//+------------------------------------------------------------------+
//| 次のプロパティ値を取得する |
//+------------------------------------------------------------------+
double GetNextValue(const double value,const int index)
{
if(value+ExtStep[index]<=ExtMaxValue[index])
return(value+ExtStep[index]);
else
return(ExtMinValue[index]);
}
//+------------------------------------------------------------------+
//| color 型プロパティの次の色を取得する |
//+------------------------------------------------------------------+
color GetNextColor(const color clr)
{
//--- 次の color 値を返す
switch(clr)
{
case clrWhite: return(clrRed);
case clrRed: return(clrGreen);
case clrGreen: return(clrBlue);
case clrBlue: return(clrBlack);
default: return(clrWhite);
}
}
//+------------------------------------------------------------------+
//| プロパティ値を描き直す |
//+------------------------------------------------------------------+
void RedrawProperties(void)
{
//--- プロパティ値のテキスト
string text;
long value;
//--- プロパティ数のループ
for(int i=0;i<ExtCount;i++)
{
text="";
switch(ExtDataTypes[i])
{
case 'I':
//--- 現プロパティ値を受け取る
if(!ChartGetInteger(0,(ENUM_CHART_PROPERTY_INTEGER)ExtNumbers[i],0,value))
break;
//--- 整数プロパティのテキスト
switch(ExtDrawTypes[i])
{
//--- color プロパティ
case 'C':
text=(string)((color)value);
break;
//--- boolean プロパティ
case 'B':
text=(string)((bool)value);
break;
//--- ENUM_CHART_MODE 列挙プロパティ
case 'M':
text=EnumToString((ENUM_CHART_MODE)value);
break;
//--- ENUM_CHART_VOLUME_MODE 列挙プロパティ
case 'V':
text=EnumToString((ENUM_CHART_VOLUME_MODE)value);
break;
//--- int 型の数
default:
text=IntegerToString(value);
break;
}
break;
case 'D':
//--- double 型プロパティのテキスト
text=DoubleToString(ChartGetDouble(0,(ENUM_CHART_PROPERTY_DOUBLE)ExtNumbers[i]),4);
break;
case 'S':
//--- string 型プロパティのテキスト
text=ChartGetString(0,(ENUM_CHART_PROPERTY_STRING)ExtNumbers[i]);
break;
}
//--- プロパティ値を表示する
ExtLabelsValue[i].Description(text);
}
}
//+------------------------------------------------------------------+
//| チャートプロパティを管理するためのパネルを作成する |
//+------------------------------------------------------------------+
bool PrepareControls(void)
{
//--- 予備を含めて配列にメモリを割り当てる
MemoryAllocation(LAST_PROPERTY_NUMBER+1);
//--- 変数
int i=0; // ループ変数
int col_1=0; // 最初の列のプロパティの数
int col_2=0; // 2 番目の列のプロパティの数
int col_3=0; // 3 番目の列のプロパティの数
//--- 現在のプロパティ数は0
ExtCount=0;
//--- ループでプロパティを探す
while(i<=LAST_PROPERTY_NUMBER)
{
//--- 現プロパティの数を保存する
ExtNumbers[ExtCount]=i;
//--- ループ変数の値を増やす
i++;
//--- そのような番号を持つプロパティがあるかどうかをチェック
if(CheckNumber(ExtNumbers[ExtCount],ExtNames[ExtCount],ExtDataTypes[ExtCount],ExtGroupTypes[ExtCount],ExtDrawTypes[ExtCount]))
{
//--- プロパティのための制御要素を作成する
switch(ExtGroupTypes[ExtCount])
{
case 1:
//--- プロパティのラベルとボタンを作成する
if(!ShowProperty(ExtCount,0,X_PROPERTY_NAME_1,X_PROPERTY_VALUE_1,X_BUTTON_1,Y_PROPERTY_1+col_1*Y_DISTANCE,true))
return(false);
//--- 最初の列内の要素の数が増加した
col_1++;
break;
case 2:
//--- プロパティのラベルとボタンを作成する
if(!ShowProperty(ExtCount,1,X_PROPERTY_NAME_2,X_PROPERTY_VALUE_2,X_BUTTON_2,Y_PROPERTY_1+col_2*Y_DISTANCE,true))
return(false);
//--- 2 番目の列内の要素の数が増加した
col_2++;
break;
case 3:
//--- プロパティのみにラベルを作成する
if(!ShowProperty(ExtCount,2,X_PROPERTY_NAME_2,X_PROPERTY_VALUE_2,0,Y_PROPERTY_2+col_3*Y_DISTANCE,false))
return(false);
//--- 3 番目の列内の要素の数が増加した
col_3++;
break;
}
//--- プロパティの最大値と最小値とステップを定義する
GetMaxMinStep(ExtNumbers[ExtCount],ExtMaxValue[ExtCount],ExtMinValue[ExtCount],ExtStep[ExtCount]);
//--- プロパティ数を増加する
ExtCount++;
}
}
//--- 配列に使用されていないメモリを解放する
MemoryAllocation(ExtCount);
//--- プロパティ値を描き直す
RedrawProperties();
ChartRedraw();
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| 配列にメモリを割り当てる |
//+------------------------------------------------------------------+
void MemoryAllocation(const int size)
{
ArrayResize(ExtLabelsName,size);
ArrayResize(ExtLabelsValue,size);
ArrayResize(ExtButtons,size);
ArrayResize(ExtNumbers,size);
ArrayResize(ExtNames,size);
ArrayResize(ExtDataTypes,size);
ArrayResize(ExtGroupTypes,size);
ArrayResize(ExtDrawTypes,size);
ArrayResize(ExtMaxValue,size);
ArrayResize(ExtMinValue,size);
ArrayResize(ExtStep,size);
}
//+------------------------------------------------------------------+
//| プロパティインデックスが |
//| ENUM_CHART_PROPERTIES 列挙値の 1 つかどうかチェックする |
//+------------------------------------------------------------------+
bool CheckNumber(const int ind,string &name,uchar &data_type,uint &group_type,uchar &draw_type)
{
//--- プロパティが整数型かどうかチェックする
ResetLastError();
name=EnumToString((ENUM_CHART_PROPERTY_INTEGER)ind);
if(_LastError==0)
{
data_type='I'; // ENUM_CHART_PROPERTY_INTEGER 列挙のプロパティ
GetTypes(ind,group_type,draw_type); // プロパティの表示パラメータを定義する
return(true);
}
//--- プロパティが double 型かどうかチェックする
ResetLastError();
name=EnumToString((ENUM_CHART_PROPERTY_DOUBLE)ind);
if(_LastError==0)
{
data_type='D'; // ENUM_CHART_PROPERTY_DOUBLE 列挙のプロパティ
GetTypes(ind,group_type,draw_type); // プロパティの表示パラメータを定義する
return(true);
}
//--- プロパティが string 型かどうかチェックする
ResetLastError();
name=EnumToString((ENUM_CHART_PROPERTY_STRING)ind);
if(_LastError==0)
{
data_type='S'; // ENUM_CHART_PROPERTY_STRING 列挙のプロパティ
GetTypes(ind,group_type,draw_type); // プロパティの表示パラメータを定義する
return(true);
}
//--- プロパティがいずれの列挙にも属しない
return(false);
}
//+------------------------------------------------------------------+
//| プロパティを格納すべきグループ、ならびにその表示タイプを |
//| 定義する |
//+------------------------------------------------------------------+
void GetTypes(const int property_number,uint &group_type,uchar &draw_type)
{
//--- プロパティが3 番目のグループに属するかどうかチェックする
//--- 3 番目のグループのプロパティは、CHART_BRING_TO_TOP から始まる2 番目の列に表示されている
if(CheckThirdGroup(property_number,group_type,draw_type))
return;
//--- プロパティが 2 番目のグループに属するかどうかチェックする
//--- 2 番目のグループのプロパティは、2 番目の列に表示されている
if(CheckSecondGroup(property_number,group_type,draw_type))
return;
//--- ここに来た場合、プロパティは最初のグループ(最初の列)に属している
CheckFirstGroup(property_number,group_type,draw_type);
}
//+----------------------------------------------------------------------+
//| プロパティが3 番目のグループに属するかどうかチェックして、 |
//| 属する場合はその表示タイプを定義する |
//+----------------------------------------------------------------------+
bool CheckThirdGroup(const int property_number,uint &group_type,uchar &draw_type)
{
//--- プロパティが3 番目のグループに属するかどうかチェックする
switch(property_number)
{
//--- boolean プロパティ
case CHART_IS_OBJECT:
case CHART_WINDOW_IS_VISIBLE:
draw_type='B';
break;
//--- integer プロパティ
case CHART_VISIBLE_BARS:
case CHART_WINDOWS_TOTAL:
case CHART_WINDOW_HANDLE:
case CHART_WINDOW_YDISTANCE:
case CHART_FIRST_VISIBLE_BAR:
case CHART_WIDTH_IN_BARS:
case CHART_WIDTH_IN_PIXELS:
draw_type='I';
break;
//--- double 型プロパティ
case CHART_PRICE_MIN:
case CHART_PRICE_MAX:
draw_type='D';
break;
//--- 実際には、このプロパティはチャートを他の全てのチャートの上に表示するコマンドである
//--- このウィンドウは使用される前には常に他のウィンドウの上にあるので
//--- パネルに適用する要はない
case CHART_BRING_TO_TOP:
draw_type=' ';
break;
//--- プロパティが3 番目のグループに属しない
default:
return(false);
}
//--- プロパティが3 番目のグループに属す
group_type=3;
return(true);
}
//+----------------------------------------------------------------------+
//| プロパティが第 2 グループに属するかどうかチェックして、 |
//| 属する場合はその表示タイプを定義する |
//+----------------------------------------------------------------------+
bool CheckSecondGroup(const int property_number,uint &group_type,uchar &draw_type)
{
//--- プロパティが 2 番目のグループに属するかどうかチェックする
switch(property_number)
{
//--- ENUM_CHART_MODE 型のプロパティ
case CHART_MODE:
draw_type='M';
break;
//--- ENUM_CHART_VOLUME_MODE 型のプロパティ
case CHART_SHOW_VOLUMES:
draw_type='V';
break;
//--- string 型プロパティ
case CHART_COMMENT:
draw_type='S';
break;
//--- color プロパティ
case CHART_COLOR_BACKGROUND:
case CHART_COLOR_FOREGROUND:
case CHART_COLOR_GRID:
case CHART_COLOR_VOLUME:
case CHART_COLOR_CHART_UP:
case CHART_COLOR_CHART_DOWN:
case CHART_COLOR_CHART_LINE:
case CHART_COLOR_CANDLE_BULL:
case CHART_COLOR_CANDLE_BEAR:
case CHART_COLOR_BID:
case CHART_COLOR_ASK:
case CHART_COLOR_LAST:
case CHART_COLOR_STOP_LEVEL:
draw_type='C';
break;
//--- プロパティが第 2 グループに属しない
default:
return(false);
}
//--- プロパティが3 番目のグループに属す
group_type=2;
return(true);
}
//+-----------------------------------------------------------------------+
//| プロパティが第 2 及び第三のプロパティグループに属していないことだけが既に知られている時のみに |
//| 呼び出される |
//+-----------------------------------------------------------------------+
void CheckFirstGroup(const int property_number,uint &group_type,uchar &draw_type)
{
//--- プロパティが1 番目のグループに属す
group_type=1;
//--- プロパティの表示タイプを定義する
switch(property_number)
{
//--- integer プロパティ
case CHART_SCALE:
case CHART_HEIGHT_IN_PIXELS:
draw_type='I';
return;
//--- double 型プロパティ
case CHART_SHIFT_SIZE:
case CHART_FIXED_POSITION:
case CHART_FIXED_MAX:
case CHART_FIXED_MIN:
case CHART_POINTS_PER_BAR:
draw_type='D';
return;
//--- boolean プロパティのみが残される
default:
draw_type='B';
return;
}
}
//+------------------------------------------------------------------+
//| プロパティのラベルとボタンを作成する |
//+------------------------------------------------------------------+
bool ShowProperty(const int ind,const int type,const int x1,const int x2,
const int xb,const int y,const bool btn)
{
//--- ExtColors 色配列の内部を切り替えるための静的変数
static uint color_index[3]={1,1,1};
//--- 別の色を受け取るためにインデックスを変更する
color_index[type]=1-color_index[type];
//--- プロパティのラベルとボタン(btn=true の場合)を表示する
if(!LabelCreate(ExtLabelsName[ind],"name_"+(string)ind,ExtNames[ind],ExtColors[color_index[type]],x1,y))
return(false);
if(!LabelCreate(ExtLabelsValue[ind],"value_"+(string)ind,"",ExtColors[color_index[type]],x2,y))
return(false);
if(btn && !ButtonCreate(ExtButtons[ind],(string)ind,xb,y+1))
return(false);
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| ラベルを作成する |
//+------------------------------------------------------------------+
bool LabelCreate(CChartObjectLabel &lbl,const string name,const string text,
const color clr,const int x,const int y)
{
if(!lbl.Create(0,"Label_"+name,0,x,y)) return(false);
if(!lbl.Description(text)) return(false);
if(!lbl.FontSize(10)) return(false);
if(!lbl.Color(clr)) return(false);
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| ボタンを作成する |
//+------------------------------------------------------------------+
bool ButtonCreate(CChartObjectButton &btn,const string name,
const int x,const int y)
{
if(!btn.Create(0,"Button_"+name,0,x,y,50,15)) return(false);
if(!btn.Description("Next")) return(false);
if(!btn.FontSize(10)) return(false);
if(!btn.Color(clrBlack)) return(false);
if(!btn.BackColor(clrWhite)) return(false);
if(!btn.BorderColor(clrBlack)) return(false);
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| プロパティの最大値と最小値とステップを定義する |
//+------------------------------------------------------------------+
void GetMaxMinStep(const int property_number,double &max,double &min,double &step)
{
double value;
//--- プロパティ値を型に応じて設定する
switch(property_number)
{
case CHART_SCALE:
max=5;
min=0;
step=1;
break;
case CHART_MODE:
case CHART_SHOW_VOLUMES:
max=2;
min=0;
step=1;
break;
case CHART_SHIFT_SIZE:
max=50;
min=10;
step=2.5;
break;
case CHART_FIXED_POSITION:
max=90;
min=0;
step=15;
break;
case CHART_POINTS_PER_BAR:
max=19;
min=1;
step=3;
break;
case CHART_FIXED_MAX:
value=ChartGetDouble(0,CHART_FIXED_MAX);
max=value*1.25;
min=value;
step=value/32;
break;
case CHART_FIXED_MIN:
value=ChartGetDouble(0,CHART_FIXED_MIN);
max=value;
min=value*0.75;
step=value/32;
break;
case CHART_HEIGHT_IN_PIXELS:
max=700;
min=520;
step=30;
break;
//--- 初期値
default:
max=1;
min=0;
step=1;
}
}
|