DocumentazioneSezioni
MQL5 RiferimentoSimboli PersonalizzatiCustomSymbolDelete 

CustomSymbolDelete

Elimina un simbolo personalizzato con il nome specificato.

bool  CustomSymbolDelete(
   const string     symbol_name          // nome del simbolo personalizzato
   );

Parametri

symbol

[in]  Nome simbolo personalizzato. Non deve corrispondere al nome di un simbolo già esistente.

Valore Restituito

true – successo, altrimenti – false. Per ottenere informazioni sull'errore, chiamare la funzione GetLastError().

Nota

Non è possibile eliminare il simbolo personalizzato visualizzato nel Market Watch o quello in cui è aperto un grafico.

 

Esempio:

//+------------------------------------------------------------------+
//|                                           CustomSymbolDelete.mq5 |
//|                                  Copyright 2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
 
#define   CUSTOM_SYMBOL_NAME     Symbol()+".C"  // nome del simbolo personalizzato
#define   CUSTOM_SYMBOL_PATH     "Forex"        // nome del gruppo in cui un simbolo è stato creato
#define   CUSTOM_SYMBOL_ORIGIN   Symbol()       // nome di un simbolo su cui è basata la personalizzazione
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- se la creazione di un simbolo personalizzato non va a buon fine, informarne nel journal
   if(!CustomSymbolCreate(CUSTOM_SYMBOL_NAME, CUSTOM_SYMBOL_PATH, CUSTOM_SYMBOL_ORIGIN))
     {
      Print("CustomSymbolCreate() failed. Error ", GetLastError());
      return;
     }
 
//--- verificare l'esistenza del simbolo creato e stampare il risultato nel journal
   bool custom= false;
   bool exist = SymbolExist(CUSTOM_SYMBOL_NAME, custom);
   PrintFormat("Custom symbol '%s' exists: %s", CUSTOM_SYMBOL_NAME, (string)exist);
   
//--- attendere due secondi e cancellare il simbolo creato con il messaggio risultante nel journal
   Sleep(2000);
   ResetLastError();
   bool deleted = CustomSymbolDelete(CUSTOM_SYMBOL_NAME);
   Print(deleted ? StringFormat("Custom symbol '%s' removed", CUSTOM_SYMBOL_NAME) : StringFormat("CustomSymbolDelete() failed. Error ",GetLastError()));
 
//--- verificare l'esistenza del simbolo creato e stampare il risultato nel journal
   exist = SymbolExist(CUSTOM_SYMBOL_NAME, custom);
   PrintFormat("Custom symbol '%s' exists: %s", CUSTOM_SYMBOL_NAME, (string)exist);
   /*
   risultato:
   Custom symbol 'EURUSD.C' exists: true
   Custom symbol 'EURUSD.C' removed
   Custom symbol 'EURUSD.C' exists: false
   */
  }

 

Guarda anche

SymbolName, SymbolSelect, CustomSymbolCreate