//+------------------------------------------------------------------+
//| Demo_iIchimoku.mq5 |
//| Copyright 2000-2024, MetaQuotes Ltd. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "L'indicateur montre comment il faut recevoir les données"
#property description "des tampons d'indicateur pour l'indicateur technique iIchimoku."
#property description "Le symbole et le temps trame sur lequel l'indicateur est calculé,"
#property description "sont spécifiés par les paramètres symbol et period."
#property description "Le moyen de la création du handle est spécifié par le paramètre 'type' (le type de la fonction)."
#property description "Tous les autres paramètres comme dans Ichimoku Kinko Hyo standard."
#property indicator_chart_window
#property indicator_buffers 5
#property indicator_plots 4
//--- la construction Tenkan_sen
#property indicator_label1 "Tenkan_sen"
#property indicator_type1 DRAW_LINE
#property indicator_color1 clrRed
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- la construction Kijun_sen
#property indicator_label2 "Kijun_sen"
#property indicator_type2 DRAW_LINE
#property indicator_color2 clrBlue
#property indicator_style2 STYLE_SOLID
#property indicator_width2 1
//--- la construction Senkou_Span
#property indicator_label3 "Senkou Span A;Senkou Span B" // dans Data Window deux champs seront montrés
#property indicator_type3 DRAW_FILLING
#property indicator_color3 clrSandyBrown, clrThistle
#property indicator_style3 STYLE_SOLID
#property indicator_width3 1
//--- la construction Chikou_Span
#property indicator_label4 "Chinkou_Span"
#property indicator_type4 DRAW_LINE
#property indicator_color4 clrLime
#property indicator_style4 STYLE_SOLID
#property indicator_width4 1
//+------------------------------------------------------------------+
//| L'énumération des moyens de la création du handle |
//+------------------------------------------------------------------+
enum Creation
{
Call_iIchimoku, // utiliser iIchimoku
Call_IndicatorCreate // utiliser IndicatorCreate
};
//--- les paramètres d'entrée
input Creation type=Call_iIchimoku; // le type de la fonction
input int tenkan_sen=9; // la période Tenkan-sen
input int kijun_sen=26; // la période Kijun-sen
input int senkou_span_b=52; // la période Senkou Span B
input string symbol=" "; // le symbole
input ENUM_TIMEFRAMES period=PERIOD_CURRENT; // le temps trame
//--- le tampon d'indicateur
double Tenkan_sen_Buffer[];
double Kijun_sen_Buffer[];
double Senkou_Span_A_Buffer[];
double Senkou_Span_B_Buffer[];
double Chinkou_Span_Buffer[];
//--- la variable pour stocker le handle de l'indicateur iIchimoku
int handle;
//--- la variable pour le stockage
string name=symbol;
//---le nom de l'indicateur sur le graphique
string short_name;
//--- stockerons le nombre de valeurs dans l'indicateur Ichimoku Kinko Hyo
int bars_calculated=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int OnInit()
{
//--- le rattachement des tableaux aux tampons d'indicateur
SetIndexBuffer(0,Tenkan_sen_Buffer,INDICATOR_DATA);
SetIndexBuffer(1,Kijun_sen_Buffer,INDICATOR_DATA);
SetIndexBuffer(2,Senkou_Span_A_Buffer,INDICATOR_DATA);
SetIndexBuffer(3,Senkou_Span_B_Buffer,INDICATOR_DATA);
SetIndexBuffer(4,Chinkou_Span_Buffer,INDICATOR_DATA);
//--- spécifions les décalages pour le canal Senkou Span sur kijun_sen bars au futur
PlotIndexSetInteger(2,PLOT_SHIFT,kijun_sen);
//---il ne faut pas spécifier le décalage pour la ligne Chikou Span, parce que les données Chinkou Span
//--- sont stockées dans l'indicateur iIchimoku déjà avec le décalage
//--- définissons avec le symbole sur lequel l'indicateur est construit
name=symbol;
//--- supprimons les espaces de la gauche et de la droite
StringTrimRight(name);
StringTrimLeft(name);
//--- si la longueur de la chaîne name est nulle après cela
if(StringLen(name)==0)
{
//--- prenons le symbole du graphique, où on a lancé l'indicateur
name=_Symbol;
}
//--- créons le handle de l'indicateur
if(type==Call_iIchimoku)
handle=iIchimoku(name,period,tenkan_sen,kijun_sen,senkou_span_b);
else
{
//--- remplirons la structure par les valeurs des paramètres de l'indicateur
MqlParam pars[3];
//--- les périodes et les décalages des lignes de l'Alligator
pars[0].type=TYPE_INT;
pars[0].integer_value=tenkan_sen;
pars[1].type=TYPE_INT;
pars[1].integer_value=kijun_sen;
pars[2].type=TYPE_INT;
pars[2].integer_value=senkou_span_b;
//--- créons le handle
handle=IndicatorCreate(name,period,IND_ICHIMOKU,3,pars);
}
//--- si on n'a pas réussi à créer le handle
if(handle==INVALID_HANDLE)
{
//--- informons sur l'échec et déduisons le numéro de l'erreur
PrintFormat("On n'a pas réussi à créer le handle de l'indicateur iIchimoku pour la paire %s/%s, le code de l'erreur %d",
name,
EnumToString(period),
GetLastError());
//--- le travail de l'indicateur est terminé avant terme
return(INIT_FAILED);
}
//--- montrons sur quelle paire le symbole/temps trame a été calculé l'indicateur Ichimoku Kinko Hyo
short_name=StringFormat("iIchimoku(%s/%s, %d, %d ,%d)",name,EnumToString(period),
tenkan_sen,kijun_sen,senkou_span_b);
IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- l'exécution normale de l'initialisation de l'indicateur
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
//--- le nombre de valeurs copiées de l'indicateur iIchimoku
int values_to_copy;
//--- apprenons le nombre de valeurs calculées dans l'indicateur
int calculated=BarsCalculated(handle);
if(calculated<=0)
{
PrintFormat("BarsCalculated() a rendu %d, le code de l'erreur %d",calculated,GetLastError());
return(0);
}
//--- si c'est un premier lancement des calculs de notre indicateur ou a changé le nombre de valeurs dans l'indicateur iIchimoku
//--- ou s'il est nécessaire de calculer l'indicateur pour deux ou plus de barres (cela signifie que quelque chose a changé dans l'histoire)
if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
{
//--- si le tableau Tenkan_sen_Buffer est plus grand, que les valeurs dans l'indicateur iIchimoku sur la paire symbol/period, copions pas tout
//--- autrement copions moins que la taille des tampons d'indicateur
if(calculated>rates_total) values_to_copy=rates_total;
else values_to_copy=calculated;
}
else
{
//--- signifie que notre indicateur est calculé non pour la première fois et dès le moment du dernier appel OnCalculate())
//--- pour le calcul a été ajouté pas plus d'une barre
values_to_copy=(rates_total-prev_calculated)+1;
}
//--- remplissons les tableaux par les valeurs de l'indicateur Ichimoku Kinko Hyo
//--- si FillArraysFromBuffer a rendu false, signifie que les données ne sont pas prêts - terminons le travail
if(!FillArraysFromBuffers(Tenkan_sen_Buffer,Kijun_sen_Buffer,Senkou_Span_A_Buffer,Senkou_Span_B_Buffer,Chinkou_Span_Buffer,
kijun_sen,handle,values_to_copy)) return(0);
//--- formerons le message
string comm=StringFormat("%s ==> a été mise à jour des valeurs de l'indicateur %s: %d",
TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
short_name,
values_to_copy);
//--- déduisons le message de service sur le graphique
Comment(comm);
//--- retiendrons le nombre de valeurs dans l'indicateur Ichimoku Kinko Hyo
bars_calculated=calculated;
//--- rendons la valeur prev_calculated pour un appel suivant
return(rates_total);
}
//+------------------------------------------------------------------+
//| Remplissons les tampons d'indicateur de l'indicateur iIchimoku |
//+------------------------------------------------------------------+
bool FillArraysFromBuffers(double &tenkan_sen_buffer[], // le tampon d'indicateur de la ligne Tenkan-sen
double &kijun_sen_buffer[], // le tampon d'indicateur de la ligne Kijun_sen
double &senkou_span_A_buffer[], // le tampon d'indicateur de la ligne Senkou Span A
double &senkou_span_B_buffer[], // le tampon d'indicateur de la ligne Senkou Span B
double &chinkou_span_buffer[], // le tampon d'indicateur Chinkou Span
int senkou_span_shift, // le décalage des lignes Senkou Span au futur
int ind_handle, // le handle de l'indicateur iIchimoku
int amount // le nombre de valeurs copiées
)
{
//--- oblitérons le code de l'erreur
ResetLastError();
//--- remplissons la partie du tableau Tenkan_sen_Buffer par les valeurs du tampon d'indicateur sous l'index 0
if(CopyBuffer(ind_handle,0,0,amount,tenkan_sen_buffer)<0)
{
//--- si le copiage n'a pas réussi, annonçons le code de l'erreur
PrintFormat("1.On n'a pas réussi à copier les données de l'indicateur iGator, le code de l'erreur %d",GetLastError());
//--- terminerons avec le résultat nul - cela signifie que l'indicateur sera considéré comme non calculé
return(false);
}
//--- remplissons la partie du tableau Kijun_sen_Buffer par les valeurs du tampon d'indicateur sous l'index 1
if(CopyBuffer(ind_handle,1,0,amount,kijun_sen_buffer)<0)
{
//--- si le copiage n'a pas réussi, annonçons le code de l'erreur
PrintFormat("2..On n'a pas réussi à copier les données de l'indicateur iGator, le code de l'erreur %d",GetLastError());
//--- terminerons avec le résultat nul - cela signifie que l'indicateur sera considéré comme non calculé
return(false);
}
//--- remplissons la partie du tableau Chinkou_Span_Buffer par les valeurs du tampon d'indicateur sous l'index 2
//--- à senkou_span_shift>0 la ligne est décalée au futur sur senkou_span_shift bars
if(CopyBuffer(ind_handle,2,-senkou_span_shift,amount,senkou_span_A_buffer)<0)
{
//--- si le copiage n'a pas réussi, annonçons le code de l'erreur
PrintFormat("3.On n'a pas réussi à copier les données de l'indicateur iGator, le code de l'erreur %d",GetLastError());
//--- terminerons avec le résultat nul - cela signifie que l'indicateur sera considéré comme non calculé
return(false);
}
//--- remplissons la partie du tableau Senkou_Span_A_Buffer par les valeurs du tampon d'indicateur sous l'index 3
//--- à senkou_span_shift>0 la ligne est décalée au futur sur senkou_span_shift bars
if(CopyBuffer(ind_handle,3,-senkou_span_shift,amount,senkou_span_B_buffer)<0)
{
//--- si le copiage n'a pas réussi, annonçons le code de l'erreur
PrintFormat("4.On n'a pas réussi à copier les données de l'indicateur iGator, le code de l'erreur %d",GetLastError());
//--- terminerons avec le résultat nul - cela signifie que l'indicateur sera considéré comme non calculé
return(false);
}
//--- remplissons la partie du tableau Senkou_Span_B_Buffer par les valeurs du tampon d'indicateur sous l'index 4
//--- il ne faut pas prendre en considération le décalage pendant le copiage Chinkou Span, parce que les données Chinkou Span
//--- sont stockées dans l'indicateur iIchimoku déjà avec le décalage
if(CopyBuffer(ind_handle,4,0,amount,chinkou_span_buffer)<0)
{
//--- si le copiage n'a pas réussi, annonçons le code de l'erreur
PrintFormat("5.On n'a pas réussi à copier les données de l'indicateur iGator, le code de l'erreur %d",GetLastError());
//--- terminerons avec le résultat nul - cela signifie que l'indicateur sera considéré comme non calculé
return(false);
}
//--- tout a réussi
return(true);
}
//+------------------------------------------------------------------+
//| Indicator deinitialization function |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
if(handle!=INVALID_HANDLE)
IndicatorRelease(handle);
//--- effaçons le graphique à la suppression de l'indicateur
Comment("");
}
|