DocumentationSections
Référence MQL5Date et HeureTimeGMT 

TimeGMT

Renvoie l'heure GMT, qui est calculée en tenant compte du changement d'heure d'été par l'heure locale de l'ordinateur sur lequel le terminal client est exécuté. Il existe 2 variantes de la fonction.

Appel sans paramètres

datetime  TimeGMT();

Appel avec un paramètre du type MqlDateTime

datetime  TimeGMT(
   MqlDateTime&  dt_struct      // variable du type de la structure
   );

Paramètres

dt_struct

[out]  Variable du type MqlDateTime.

Valeur de Retour

Valeur du type datetime

Note

Si la variable du type MqlDateTime a été transmise comme paramètre, elle est remplie de façon correspondante.

Pour utiliser les compteurs et la minuterie à haute précision, il faut utiliser la fonction GetTickCount() qui retourne la valeur en millisecondes.

Lors des tests dans le Testeur de Stratégie, TimeGMT() est toujours égal à l'heure du serveur simulée TimeTradeServer().

Exemple :

void OnStart()
  {
//--- déclare la variable MqlDateTime à remplir avec des données de date/heure et récupère l'heure locale et GMT du PC
   MqlDateTime tm={};
   datetime    time1=TimeLocal();            // première forme de l'appel : heure locale du PC
   datetime    time2=TimeGMT(tm);            // deuxième forme de l'appel: GMT calculée à partir de l'heure locale du PC en remplissant la structure MqlDateTime
   int         shift=int(time1-time2)/3600;  // décalage horaire local par rapport à GMT
   
//--- affiche l'heure locale et GMT avec les données de la structure MqlDateTime remplie dans le journal
   PrintFormat("Time Local: %s\nTime GMT: %s\n- Year: %u\n- Month: %02u\n- Day: %02u\n"+
               "- Hour: %02u\n- Min: %02u\n- Sec: %02u\n- Day of Year: %03u\n- Day of Week: %u (%s)\nLocal time offset relative to GMT: %+d",
               (string)time1, (string)time2, tm.year, tm.mon, tm.day, tm.hour, tm.min, tm.sec, tm.day_of_year, tm.day_of_week,
               EnumToString((ENUM_DAY_OF_WEEK)tm.day_of_week), shift);
  /*
  Résultat :
   Time Local: 2024.04.18 19:37:23
   Time GMT: 2024.04.18 12:37:23
   - Year: 2024
   - Month: 04
   - Day: 18
   - Hour: 12
   - Min: 37
   - Sec: 23
   - Day of Year: 108
   - Day of Week: 4 (THURSDAY)
   Local time offset relative to GMT: +7
  */
  }