//+------------------------------------------------------------------+
//| Demo_iWPR.mq5 |
//| Copyright 2011, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "Der Indikator zeigt, wie Daten erhalten werden sollen"
#property description "Indikator-Puffer für den technischen Indikator iWPR."
#property description "Symbol und Zeitrahmen, in denen der Indikator berechnet wird,"
#property description "sind durch die Parameter symbol und period angegeben."
#property description "Erstellungsweise des Handles ist durch den 'type' Parameter (Typ der Funktion) angegeben."
#property indicator_separate_window
#property indicator_buffers 1
#property indicator_plots 1
//--- iWPR bauen
#property indicator_label1 "iWPR"
#property indicator_type1 DRAW_LINE
#property indicator_color1 clrCyan
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- die Grenzwerte des Indikators definieren
#property indicator_minimum -100
#property indicator_maximum 0
//--- Horizontale Ebenen im Indikatorsfenster
#property indicator_level1 -20.0
#property indicator_level2 -80.0
//+------------------------------------------------------------------+
//| Enumeration der Erstellungsweisen des Handles |
//+------------------------------------------------------------------+
enum Creation
{
Call_iWPR, // iWPR verwenden
Call_IndicatorCreate // IndicatorCreate verwenden
};
//--- Eingabeparameter
input Creation type=Call_iWPR; // Funktionstyp
input int calc_period=14; // Periode
input string symbol=" "; // Symbol
input ENUM_TIMEFRAMES period=PERIOD_CURRENT; // Zeitrahmen
//--- Indicator-Puffer
double iWPRBuffer[];
//--- Eine Variable um Handle des Indikators iWPR zu speichern
int handle;
//--- Variable für Speicherung
string name=symbol;
//--- Name des Indikators auf dem Chart
string short_name;
//--- die Anzahl der Werte im Indikator Larry Williams' Percent Range gespeichert wird
int bars_calculated=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int OnInit()
{
//--- Bindung von Array zum Indikator-Puffer
SetIndexBuffer(0,iWPRBuffer,INDICATOR_DATA);
//--- das Symbol, auf das der Indikator gebaut wird, definieren
name=symbol;
//--- Leerzeichen aus dem linken und rechten löschen
StringTrimRight(name);
StringTrimLeft(name);
//--- Wenn nach diesem die Länge des String name ist Null
if(StringLen(name)==0)
{
//--- das Symbol aus dem Chart, auf dem der Indikator läuft, nehmen
name=_Symbol;
}
//--- Erstellen ein Handel des Indikators
if(type==Call_iWPR)
handle=iWPR(name,period,calc_period);
else
{
//--- die Struktur mit Werten von Indikatorparametern ausfüllen
MqlParam pars[1];
//--- Periode
pars[0].type=TYPE_INT;
pars[0].integer_value=calc_period;
handle=IndicatorCreate(name,period,IND_WPR,1,pars);
}
//--- Wenn Handle konnte nicht erstellt werden
if(handle==INVALID_HANDLE)
{
//--- darüber schreiben und Nummer des Fehlers anzeigen
PrintFormat("Handle des Indikators iWPR für das Paar %s/%s konnte nicht erstellt werden. Fehlercode ist %d",
name,
EnumToString(period),
GetLastError());
//--- Arbeit des Indikators ist früher geendet
return(INIT_FAILED);
}
//--- Das Paar, Symbol/Zeitrahmen, auf deren Larry Williams' Percent Range berechnet war, zeigen
short_name=StringFormat("iWPR(%s/%s, %d)",name,EnumToString(period),calc_period);
IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- normale Initialisierung des Indikators
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
//--- Anzahl der Werte des Indikators iWPR zu kopieren
int values_to_copy;
//--- Anzahl der berechneten Werte im Indikator finden
int calculated=BarsCalculated(handle);
if(calculated<=0)
{
PrintFormat("BarsCalculated() hat %d zurückgegeben, Fehlercode ist %d",calculated,GetLastError());
return(0);
}
//--- wenn dies der erste Start der Berechnung des Indikators ist oder die Anzahl der Werte im Indikator iWPR geändert hat
//--- oder wenn Sie brauchen den Indikator für zwei oder mehr Balken (was bedeutet, dass etwas in der Geschichte verändert hat) zu berechnen
if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
{
//--- wenn Array iWPRBuffer größer als die Anzahl der Werte in iWPR auf symbol/period ist, dann kopieren wir nicht alles
//--- sonst kopieren wir weniger als Größe der Indikator-Puffer
if(calculated>rates_total) values_to_copy=rates_total;
else values_to_copy=calculated;
}
else
{
//--- dann ist unser Indikator nicht das erste Mal berechnet, und seit dem letzten Aufruf von OnCalculate())
//--- nicht mehr als ein Balken für die Berechnung hinzugefügt war
values_to_copy=(rates_total-prev_calculated)+1;
}
//--- Das Array mit den Werten aus dem Indikator Larry Williams' Percent Range ausfüllen
//--- Wenn FillArrayFromBuffer false zurückgegeben hat, dann die Daten nicht bereit sind - das Werk vollenden
if(!FillArrayFromBuffer(iWPRBuffer,handle,values_to_copy)) return(0);
//--- Nachricht bilden
string comm=StringFormat("%s ==> Aktualisierte Werte im Indikator %s: %d",
TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
short_name,
values_to_copy);
//--- Hilfsnachrichtung auf dem Chart anzeigen
Comment(comm);
//--- die Anzahl der Werte im Indikator Larry Williams' Percent Range speichern
bars_calculated=calculated;
//--- den Wert prev_calculated für den nächsten Anruf zurückgeben
return(rates_total);
}
//+------------------------------------------------------------------+
//| Indikator-Puffer aus dem Indikator iWPR ausfüllen |
//+------------------------------------------------------------------+
bool FillArrayFromBuffer(double &wpr_buffer[], // Indikator-Puffer der Werte von Williams' Percent Range
int ind_handle, // Handle des Indikators iWPR
int amount // Anzahl der Werte, die kopiert werden
)
{
//--- Fehlercode rücksetzen
ResetLastError();
//--- Teil des Arrays iWPRBuffer mit Werten auf Indikator-Puffer mit Index 0 ausfüllen
if(CopyBuffer(ind_handle,0,0,amount,wpr_buffer)<0)
{
//--- wenn die Kopie fehlschlägt, Fehlercode anzeigen
PrintFormat("Daten konnte nicht aus dem Indikator iWPR kopiert werden, Fehlercode ist %d",GetLastError());
//--- Beenden mit Null-Ergebnis - dies bedeutet, dass der Indikator nicht berechnet wird
return(false);
}
//--- Alles gelang
return(true);
}
//+------------------------------------------------------------------+
//| Indicator deinitialization function |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
if(handle!=INVALID_HANDLE)
IndicatorRelease(handle);
//--- Das Chart nach der Löschung des Indikators leeren
Comment("");
}
|