MetaTrader 5 herunterladen

iRSI

Gibt das Handle des Indikators Relative Strength Index zurück. Hat nur einen Puffer.

int  iRSI(
   string              symbol,            // Symbolname
   ENUM_TIMEFRAMES     period,            // Periode
   int                 ma_period,         // Mittelungsperiode
   ENUM_APPLIED_PRICE  applied_price      // Preistyp oder Handle
   );

Parameter

symbol

[in]  Symbolname des Instrumentes,dessen Daten für Berechnung des Indikators verwendet werden. NULL bedeutet das laufende Symbol.

period

[in] Wert der Periode kann einer der Enumerationswerte ENUM_TIMEFRAMES sein, 0 bedeutet das laufende Timeframe.

ma_period

[in] Mittelungsperiode für Berechnung des Indexes.

applied_price

[in]  Der verwendete Preis. Kann eine der Preiskonstanten ENUM_APPLIED_PRICE oder Handle eines anderen Indikators sein.

Rückgabewert

Gibt das Handle des angegebenen technischen Indikators zurück, beim Misserfolg gibt INVALID_HANDLE zurück. Um Computerspeicher aus nicht genutzten Indikatoren zu befreien, wird die Funktion IndicatorRelease() verwendet, zu deren Indikatorhandle passiert wird.

Beispiel:

//+------------------------------------------------------------------+
//|                                                    Demo_iRSI.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property description "Der Indikator zeigt, wie Daten erhalten werden sollen"
#property description "Indikator-Puffer für den technischen Indikator iRSI."
#property description "Symbol und Zeitrahmen, in denen der Indikator berechnet wird,"
#property description "sind durch die Parameter symbol und period angegeben."
#property description "Erstellungsweise des Handles ist durch den 'type' Parameter (Typ der Funktion) angegeben."
#property description "Alle andere Parameter sind wie im normalen Relative Strength Index."
 
#property indicator_separate_window
#property indicator_buffers 1
#property indicator_plots   1
//--- iRSI bauen
#property indicator_label1  "iRSI"
#property indicator_type1   DRAW_LINE
#property indicator_color1  clrDodgerBlue
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- Limits, um die Werte im Indikatorsfenster anzuzeigen
#property indicator_maximum 100
#property indicator_minimum 0
//--- Horizontale Ebenen im Indikatorsfenster
#property indicator_level1  70.0
#property indicator_level2  30.0
//+------------------------------------------------------------------+
//| Enumeration der Erstellungsweisen des Handles                     |
//+------------------------------------------------------------------+
enum Creation
  {
   Call_iRSI,              // iRSI verwenden
   Call_IndicatorCreate    // IndicatorCreate verwenden
  };
//--- Eingabeparameter
input Creation             type=Call_iRSI;               // Funktionstyp
input int                  ma_period=14;                 // MA Periode
input ENUM_APPLIED_PRICE   applied_price=PRICE_CLOSE;    // Preistyp
input string               symbol=" ";                   // Symbol
input ENUM_TIMEFRAMES      period=PERIOD_CURRENT;        // Zeitrahmen
//--- Indicator-Puffer
double         iRSIBuffer[];
//--- Eine Variable um Handle des Indikators iRSI zu speichern
int    handle;
//--- Variable für Speicherung
string name=symbol;
//--- Name des Indikators auf dem Chart
string short_name;
//--- die Anzahl der Werte im Indikator Relative Strength Index gespeichert wird
int    bars_calculated=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- Bindung von Array zum Indikator-Puffer
   SetIndexBuffer(0,iRSIBuffer,INDICATOR_DATA);
//--- das Symbol, auf das der Indikator gebaut wird, definieren
   name=symbol;
//--- Leerzeichen aus dem linken und rechten löschen
   StringTrimRight(name);
   StringTrimLeft(name);
//--- Wenn nach diesem die Länge des String name ist Null
   if(StringLen(name)==0)
     {
      //--- das Symbol aus dem Chart, auf dem der Indikator läuft, nehmen
      name=_Symbol;
    ;}
//--- Erstellen ein Handel des Indikators
   if(type==Call_iRSI)
      handle=iRSI(name,period,ma_period,applied_price);
   else
     {
      //--- die Struktur mit Werten von Indikatorparametern ausfüllen     
      MqlParam pars[2];
      //--- MA Periode
      pars[0].type=TYPE_INT;
      pars[0].integer_value=ma_period;
      //--- ser Grenzwert des Schritts, der in den Berechnungen verwendet werden kann
      pars[1].type=TYPE_INT;
      pars[1].integer_value=applied_price;
      handle=IndicatorCreate(name,period,IND_RSI,2,pars);
    ;}
//--- Wenn Handle konnte nicht erstellt werden
   if(handle==INVALID_HANDLE)
     {
      //--- darüber schreiben und Nummer des Fehlers anzeigen
      PrintFormat("Handle des Indikators iRSI für das Paar %s/%s konnte nicht erstellt werden. Fehlercode ist %d",
                  name,
                  EnumToString(period),
                  GetLastError());
      //--- Arbeit des Indikators ist früher geendet
      return(INIT_FAILED);
    ;}
//--- Das Paar, Symbol/Zeitrahmen, auf deren Relative Strength Index berechnet war, zeigen
   short_name=StringFormat("iRSI(%s/%s, %d, %d)",name,EnumToString(period),
                           ma_period,applied_price);
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- normale Initialisierung des Indikators
   return(INIT_SUCCEEDED);
 ;}
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- Anzahl der Werte des Indikators iRSI zu kopieren
   int values_to_copy;
//--- Anzahl der berechneten Werte im Indikator finden
   int calculated=BarsCalculated(handle);
   if(calculated<=0)
     {
      PrintFormat("BarsCalculated() hat %d zurückgegeben, Fehlercode ist %d",calculated,GetLastError());
      return(0);
    ;}
//--- wenn dies der erste Start der Berechnung des Indikators ist oder die Anzahl der Werte im Indikator iRSI geändert hat
//--- oder wenn Sie brauchen den Indikator für zwei oder mehr Balken (was bedeutet, dass etwas in der Geschichte verändert hat) zu berechnen
   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
     {
      //--- wenn Array iRSIBuffer größer als die Anzahl der Werte in iRSI auf symbol/period ist, dann kopieren wir nicht alles
      //--- sonst kopieren wir weniger als Größe der Indikator-Puffer
      if(calculated>rates_total) values_to_copy=rates_total;
      else                       values_to_copy=calculated;
    ;}
   else
     {
      //--- dann ist unser Indikator nicht das erste Mal berechnet, und seit dem letzten Aufruf von OnCalculate())
      //--- nicht mehr als ein Balken für die Berechnung hinzugefügt war
      values_to_copy=(rates_total-prev_calculated)+1;
    ;}
//--- Das Array mit den Werten aus dem Indikator iRSI ausfüllen
//--- Wenn FillArrayFromBuffer false zurückgegeben hat, dann die Daten nicht bereit sind - das Werk vollenden
   if(!FillArrayFromBuffer(iRSIBuffer,handle,values_to_copy)) return(0);
//--- Nachricht bilden
   string comm=StringFormat("%s ==> Aktualisierte Werte im Indikator %s: %d",
                            TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
                            short_name,
                            values_to_copy);
//--- Hilfsnachrichtung auf dem Chart anzeigen
   Comment(comm);
//--- die Anzahl der Werte im Indikator Relative Strength Index speichern
   bars_calculated=calculated;
//--- den Wert prev_calculated für den nächsten Anruf zurückgeben
   return(rates_total);
 ;}
//+------------------------------------------------------------------+
//| Indikator-Puffer aus dem Indikator iRSI ausfüllen                |
//+------------------------------------------------------------------+
bool FillArrayFromBuffer(double &rsi_buffer[],  // Indikator-Puffer der Werte von Relative Strength Index
                         int ind_handle,        // Handle des Indikators iSAR
                         int amount             // Anzahl der Werte, die kopiert werden
                         )
  {
//--- Fehlercode rücksetzen
   ResetLastError();
//--- Teil des Arrays iRSIBuffer mit Werten auf Indikator-Puffer mit Index 0 ausfüllen
   if(CopyBuffer(ind_handle,0,0,amount,rsi_buffer)<0)
     {
      //--- wenn die Kopie fehlschlägt, Fehlercode anzeigen
      PrintFormat("Daten konnte nicht aus dem Indikator iRSI kopiert werden, Fehlercode ist %d",GetLastError());
      //--- Beenden mit Null-Ergebnis - dies bedeutet, dass der Indikator nicht berechnet wird
      return(false);
    ;}
//--- Alles gelang
   return(true);
 ;}
//+------------------------------------------------------------------+
//| Indicator deinitialization function                              |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//--- Das Chart nach der Löschung des Indikators leeren
   Comment("");
 ;}