MetaTrader 5 herunterladen

iMACD

Gibt das Handle des Indikators Moving Averages Convergence/Divergence zurück. In den Systemen, wo OsMA als Histogramm MACD bezeichnet wird, wird dieser Indikator als zwei Linien dargestellt. Im Client-Terminal wird Konvergenz/Divergenz von Moving Averages als Histogramm dargestellt.

int  iMACD(
   string              symbol,              // Symbolname
   ENUM_TIMEFRAMES     period,              // Periode
   int                 fast_ema_period,     // Periode für Berechnung von Fast average 
   int                 slow_ema_period,     // Periode für Berechnung von Slow average 
   int                 signal_period,       // Periode für Mittelung ihrer Differenz 
   ENUM_APPLIED_PRICE  applied_price        // Preistyp oder handle
   );

Parameter

symbol

[in]  Symbolname des Instrumentes dessen Daten für Berechnung des Indikators verwendet werden. NULL bedeutet das laufende Symbol.

period

[in]  Wert der Periode kann einer der Enumerationswerte ENUM_TIMEFRAMES sein, 0 bedeutet das laufende Timeframe.

fast_ema_period

[in]  Mittelungsperiode für Berechnung von Fast Moving Average.

slow_ema_period

[in]  Mittelungsperiode für Berechnung von Slow Moving Average.

signal_period

[in]  Mittelunfsperiode für Berechnung von Signallinie.

applied_price

[in]  Der verwendete Preis. Kann einer der Preiskonstanten ENUM_APPLIED_PRICE oder Handle eines anderen Indikators sein.

Rückgabewert

Gibt das Handle des angegebenen technischen Indikators, beim Misserfolg gibt INVALID_HANDLE zurück. Um Computerspeicher aus nicht genutzten Indikatoren zu befreien, wird die Funktion IndicatorRelease() verwendet, zu deren Indikatorhandle passiert wird.

Hinweis

Puffernummern: 0 - MAIN_LINE, 1 - SIGNAL_LINE.

Beispiel:

//+------------------------------------------------------------------+
//|                                                   Demo_iMACD.mq5 |
//|                        Copyright 2011, MetaQuotes Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
#property description "Der Indikator zeigt, wie Daten erhalten werden sollen"
#property description "Indikator-Puffer für den technischen Indikator iMACD."
#property description "Symbol und Zeitrahmen, in denen der Indikator berechnet wird,"
#property description "sind durch die Parameter symbol und period angegeben."
#property description "Erstellungsweise des Handles ist durch den 'type' Parameter (Typ der Funktion) angegeben."
#property description "Alle andere Parameter sind wie im normalen Indikator MACD."
 
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_plots   2
//--- MACD bauen
#property indicator_label1  "MACD"
#property indicator_type1   DRAW_HISTOGRAM
#property indicator_color1  clrSilver
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- Signal bauen
#property indicator_label2  "Signal"
#property indicator_type2   DRAW_LINE
#property indicator_color2  clrRed
#property indicator_style2  STYLE_DOT
#property indicator_width2  1
//+------------------------------------------------------------------+
//| Enumeration der Erstellungsweisen des Handles                     |
//+------------------------------------------------------------------+
enum Creation
  {
   Call_iMACD,             // iMACD verwenden
   Call_IndicatorCreate    // IndicatorCreate verwenden
  };
//--- Eingabeparameter
input Creation             type=Call_iMACD;           // Funktionstyp
input int                  fast_ema_period=12;        // Periode der schnellen MA
input int                  slow_ema_period=26;        // Periode der langsamen MA
input int                  signal_period=9;           // Mittelungsperiode der Unterschied
input ENUM_APPLIED_PRICE   applied_price=PRICE_CLOSE// Preistyp
input string               symbol=" ";                // Symbol
input ENUM_TIMEFRAMES      period=PERIOD_CURRENT;     // Zeitrahmen
//--- Indicator-Puffer
double         MACDBuffer[];
double         SignalBuffer[];
//--- Eine Variable um Handle des Indikators iMACD zu speichern
int    handle;
//--- Variable für Speicherung
string name=symbol;
//--- Name des Indikators auf dem Chart
string short_name;
//--- die Anzahl der Werte im Indikator Moving Averages Convergence/Divergence gespeichert wird
int    bars_calculated=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- Bindung von Arrays zu den Indikator-Puffern
   SetIndexBuffer(0,MACDBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,SignalBuffer,INDICATOR_DATA);
//--- das Symbol, auf das der Indikator gebaut wird, definieren
   name=symbol;
//--- Leerzeichen aus dem linken und rechten löschen
   StringTrimRight(name);
   StringTrimLeft(name);
//--- Wenn nach diesem die Länge des String name ist Null
   if(StringLen(name)==0)
     {
      //--- das Symbol aus dem Chart, auf dem der Indikator läuft, nehmen
      name=_Symbol;
    ;}
//--- Erstellen ein Handel des Indikators
   if(type==Call_iMACD)
      handle=iMACD(name,period,fast_ema_period,slow_ema_period,signal_period,applied_price);
   else
     {
      //--- die Struktur mit Werten von Indikatorparametern ausfüllen     
      MqlParam pars[4];
      //--- Schnelle Periode 
      pars[0].type=TYPE_INT;
      pars[0].integer_value=fast_ema_period;
      //--- Langsame Periode
      pars[1].type=TYPE_INT;
      pars[1].integer_value=slow_ema_period;
//--- Mittelungsperiode der Unterschied zwischen der schnellen und langsamen MA
      pars[2].type=TYPE_INT;
      pars[2].integer_value=signal_period;
      //--- Preistyp
      pars[3].type=TYPE_INT;
      pars[3].integer_value=applied_price;
      handle=IndicatorCreate(name,period,IND_MACD,4,pars);
    ;}
//--- Wenn Handle konnte nicht erstellt werden
   if(handle==INVALID_HANDLE)
     {
      //--- darüber schreiben und Nummer des Fehlers anzeigen
      PrintFormat("Handle des Indikators iMACD für das Paar %s/%s konnte nicht erstellt werden. Fehlercode ist %d",
                  name,
                  EnumToString(period),
                  GetLastError());
      //--- Arbeit des Indikators ist früher geendet
      return(INIT_FAILED);
    ;}
//--- Das Paar, Symbol/Zeitrahmen, auf deren Moving Averages Convergence/Divergence berechnet war, zeigen
   short_name=StringFormat("iMACD(%s/%s,%d,%d,%d,%s)",name,EnumToString(period),
                           fast_ema_period,slow_ema_period,signal_period,EnumToString(applied_price));
   IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- normale Initialisierung des Indikators  
   return(INIT_SUCCEEDED);
 ;}
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//--- Anzahl der Werte des Indikators iMACD zu kopieren
   int values_to_copy;
//--- Anzahl der berechneten Werte im Indikator finden
   int calculated=BarsCalculated(handle);
   if(calculated<=0)
     {
      PrintFormat("BarsCalculated() hat %d zurückgegeben, Fehlercode ist %d",calculated,GetLastError());
      return(0);
    ;}
//--- wenn dies der erste Start der Berechnung des Indikators ist oder die Anzahl der Werte im Indikator iMACD geändert hat
//--- oder wenn Sie brauchen den Indikator für zwei oder mehr Balken (was bedeutet, dass etwas in der Geschichte verändert hat) zu berechnen
   if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
     {
      //--- wenn Array MACDBuffer größer als die Anzahl der Werte in iMACD auf symbol/period ist, dann kopieren wir nicht alles
      //--- sonst kopieren wir weniger als Größe der Indikator-Puffer
      if(calculated>rates_total) values_to_copy=rates_total;
      else                       values_to_copy=calculated;
    ;}
   else
     {
      //--- dann ist unser Indikator nicht das erste Mal berechnet, und seit dem letzten Aufruf von OnCalculate())
      //--- nicht mehr als ein Balken für die Berechnung hinzugefügt war
      values_to_copy=(rates_total-prev_calculated)+1;
    ;}
//--- Die Arrays mit den Werten aus dem Indikator iMACD ausfüllen
//--- Wenn FillArraysFromBuffers false zurückgegeben hat, dann die Daten nicht bereit sind - das Werk vollenden
   if(!FillArraysFromBuffers(MACDBuffer,SignalBuffer,handle,values_to_copy)) return(0);
//--- Nachricht bilden
   string comm=StringFormat("%s ==> Aktualisierte Werte im Indikator %s: %d",
                            TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
                            short_name,
                            values_to_copy);
//--- Hilfsnachrichtung auf dem Chart anzeigen
   Comment(comm);
//--- die Anzahl der Werte im Indikator Moving Averages Convergence/Divergence speichern
   bars_calculated=calculated;
//--- den Wert prev_calculated für den nächsten Anruf zurückgeben
   return(rates_total);
 ;}
//+------------------------------------------------------------------+
//| Indikator-Puffer aus dem Indikator iMACD ausfüllen               |
//+------------------------------------------------------------------+
bool FillArraysFromBuffers(double &macd_buffer[],    // Indikator-Puffer der Werte von MACD
                           double &signal_buffer[],  // Indicator-Puffer von MACD Signallinie 
                           int ind_handle,           // Handle des Indikators iMACD
                           int amount                // Anzahl der Werte, die kopiert werden
                           )
  {
//--- Fehlercode rücksetzen
   ResetLastError();
//--- Teil des Arrays iMACDBuffer mit Werten auf Indikator-Puffer mit Index 0 ausfüllen
   if(CopyBuffer(ind_handle,0,0,amount,macd_buffer)<0)
     {
      //--- wenn die Kopie fehlschlägt, Fehlercode anzeigen
      PrintFormat("Daten konnte nicht aus dem Indikator iMACD kopiert werden, Fehlercode ist %d",GetLastError());
      //--- Beenden mit Null-Ergebnis - dies bedeutet, dass der Indikator nicht berechnet wird
      return(false);
    ;}
 
//--- Teil des Arrays SignalBuffer mit Werten auf Indikator-Puffer mit Index 1 ausfüllen
   if(CopyBuffer(ind_handle,1,0,amount,signal_buffer)<0)
     {
      //--- wenn die Kopie fehlschlägt, Fehlercode anzeigen
      PrintFormat("Daten konnte nicht aus dem Indikator iMACD kopiert werden, Fehlercode ist %d",GetLastError());
      //--- Beenden mit Null-Ergebnis - dies bedeutet, dass der Indikator nicht berechnet wird
      return(false);
    ;}
//--- Alles gelang
   return(true);
 ;}
//+------------------------------------------------------------------+
//| Indicator deinitialization function                              |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//--- Das Chart nach der Löschung des Indikators leeren
   Comment("");
 ;}