Canvas - это круто! - страница 19

Nikolai Semko
8283
Nikolai Semko  
Renat Fatkhullin:

Оказывается, я смотрел частоту генерации полотна, а не частоту вывода.

Это разные числа, кратно отличающиеся.

Я оказывается чуть неправильно рассчитывал частоту генерации полотна (без вывода)и частоту вывода (без генерации)

Вот более корректный вариант.


Результаты на моем процессоре:

Если брать время чисто по формированию кадра из 200 сглаженных окружностей без вывода, то это происходит с частотой около 500 кадров в секунду.

формирование кадра из 200 несглаженных окружностей без вывода - около 1000 кадров в секунду.

Частота самой функции вывода изображения(полотна) на экран (функция Update) - это около 650 кадров в секунду.

Вы действительно потрудились на славу!

Файлы:
Nikolai Semko
8283
Nikolai Semko  
Renat Fatkhullin:

Бойтесь как огня массовых конвертаций вида (int)double или (double)int и вообще смешения int+double в мат операциях.

Это дает дичайший оверхед в процессоре - просто такая дорогая ассемблерная команда. Если считаете в double, продолжайте в нем считать и не переключайтесь в integer типы.

Команды вида cvtsi2sd/cvttsd2si очень долгие. Небольшая наводка в статье "Самая медленная инструкция x86", злодей номер 2.

Спасибо за весьма ценную статью.


Но если честно, я не понимаю почему тогда в этом простом скрипте:

#define Num 1000000 
void OnStart()
  {
    double arr[Num];
    for (int i=0;i<Num;i++) arr[i]=(double) rand()/(1+rand()%100); // инициализируем массив случайными числами double от 0.0 до 32767.0
    
    long sumL=0;
    
    ulong t1=GetMicrosecondCount();
    for (int i=0;i<Num;i++) sumL+=(long)arr[i]; // сумма long
    t1=GetMicrosecondCount()-t1;
    
    double sumD=0;
    
    ulong t2=GetMicrosecondCount();
    for (int i=0;i<Num;i++) sumD+=arr[i];      // сумма double
    t2=GetMicrosecondCount()-t2;  
    
    Print ("Сумма long   = "+ string(sumL)+ ", время суммирования "+string(t1)+" микросекунд");
    Print ("Сумма double = "+ DoubleToString(sumD)+ ", время суммирования "+string(t2)+" микросекунд");   
  }

сумма long с конвертацией типа double в long осуществляется заметно быстрее, чем сумма double того же массива без конвертации

2019.01.15 22:21:46.410 TestSpeedDoubleAndInt (NZDUSD,M5)       Сумма long   = 849290923,          время суммирования 748  микросекунд
2019.01.15 22:21:46.410 TestSpeedDoubleAndInt (NZDUSD,M5)       Сумма double = 849764484.23059070, время суммирования 1393 микросекунд
MetaQuotes
Админ
28655
Renat Fatkhullin  

Во первых, надо смотреть ассемблерный код и результат оптимизаций экстремально простых случаев(супермикросинтетика давно уже вводит в заблуждение). Тут легко нарваться на конвеерную реализацию, прям идеальный случай.

Во вторых, уже мало кто может гарантировать как скомпилируется и за сколько выполнится тот или иной код.

Достаточно добавить в код дополнительную строку/команду и скорость резко меняется. Реальный код/данные могут банально вылезти из L1/L2 кеша и все. 

У вас как получилось? По теории/суперсинтетике кажется что целочисленные команды помогут в скорости, а в реальном коде слив. Потому что там кода в десятки/сотни раз больше, нет конвееризации, постоянное прыгание вычислений от целочисленных к вещественным и оптимизация ограничена.

Реter Konow
10257
Реter Konow  
Renat Fatkhullin:


А почему инициализация массивов любых типов в MQL4, более чем в 10 раз медленее чем в MQL5?

MetaQuotes
Админ
28655
Renat Fatkhullin  
Реter Konow:

А почему инициализация массивов любых типов в MQL4, более чем в 10 раз медленее чем в MQL5?

Потому что там все массивы динамические и язык в десяток раз медленнее.

Aliaksandr Hryshyn
3671
Aliaksandr Hryshyn  
Классный ответ)).
В десять раз медленнее, потому что в десять раз медленнее))).
Nikolai Semko
8283
Nikolai Semko  

Сверхбыстрый индикатор из сотен скользящих средних, реализованный на Canvas.

100 линий MA(шаг периода 10) - время расчета и вывода на экран - 4-7 миллисекунд


1000 линий MA(шаг периода 1) - время расчета и вывода на экран - 20-30 миллисекунд


код сильно не тестировал. Могут быть баги. Реализовано только для бара в толщину один пиксель (переводится принудительно в такой масштаб). Также не оптимизированна частота обновления экрана. Все линии расчитываются и полностью выводятся при каждом тике. 

#include <Canvas\iCanvas.mqh> //https://www.mql5.com/ru/code/22164
#property indicator_chart_window

//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
input int MA=1000;   // максимальный период скользящих средних
input int stepMa=10; // шаг скользящих средних

double  Close[];
long Total;
int Ma;
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
int OnInit()
  {
   ChartSetInteger(0,CHART_EVENT_MOUSE_MOVE,true);
   ChartSetInteger(0,CHART_SCALE,0,0);
   ChartSetInteger(0,CHART_FOREGROUND,true);
   CopyClose(_Symbol,_Period,(int)W.Right_bar,W.BarsInWind+Ma-1,Close);
   Total=SeriesInfoInteger(_Symbol,_Period,SERIES_BARS_COUNT);
   if (Total<(MA+W.BarsInWind)) Ma=(int)Total-1-W.BarsInWind; else Ma=MA;
   if (Ma<=0) Ma=1;
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,const int prev_calculated,const int begin,const double &price[])
  {
   CopyClose(_Symbol,_Period,(int)W.Right_bar,W.BarsInWind+Ma-1,Close);
   Print("Время формирования кадра = "+(string)(nMA()/1000)+" миллискунд");
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| ChartEvent function                                              |
//+------------------------------------------------------------------+
void OnChartEvent(const int id,
                  const long &lparam,
                  const double &dparam,
                  const string &sparam)
  {
   if(id==CHARTEVENT_CHART_CHANGE)
     {
      ChartSetInteger(0,CHART_SCALE,0,0);
      CopyClose(_Symbol,_Period,(int)W.Right_bar,W.BarsInWind+Ma-1,Close);
      Print("Время формирования кадра = "+(string)(nMA()/1000)+" миллискунд");
     }
  }
//+------------------------------------------------------------------+

ulong nMA()
  {
   ulong t=GetMicrosecondCount();
   int preY=0;
   Canvas.Erase();
   double S=0;
   for(int i=0;i<Ma; i++) S+=Close[i];

   for(int Per=Ma;Per>0;)
     {
      double s=S;
      uint Clr=Grad((double)Per/Ma);
      for(int x=0; x<W.BarsInWind;x++)
        {
         int Y=(int)(Canvas.Y(s/Per)-0.5);
         if(x>0) if(fabs(Y-preY)>1) Canvas.Line(x-1,preY,x,Y,Clr);
         else Canvas.PixelSet(x,Y,Clr);
         if((Ma+x)<ArraySize(Close)) s=s-Close[x+Ma-Per]+Close[Ma+x]; else break;
         preY=Y;
        }
      for(int j=0; j<stepMa; j++) if(Per>0){ S=S-Close[Ma-Per]; Per--;} else break;
     }
   Canvas.Update();
   return GetMicrosecondCount()-t;
  }
//+------------------------------------------------------------------+
uint Grad(double p)
  {
   static uint Col[6]={0xFF0000FF,0xFFFF00FF,0xFFFF0000,0xFFFFFF00,0xFF00FF00,0xFF00FFFF};
   if(p>0.9999) return Col[5];
   if(p<0.0001) return Col[0];
   p=p*5;
   int n=(int)p;
   double k=p-n;
   argb c1,c2;
   c1.clr=Col[n];
   c2.clr=Col[n+1];
   return ARGB(255,c1.c[2]+uchar(k*(c2.c[2]-c1.c[2])+0.5),
                   c1.c[1]+uchar(k*(c2.c[1]-c1.c[1])+0.5),
                   c1.c[0]+uchar(k*(c2.c[0]-c1.c[0])+0.5));
  }
//+------------------------------------------------------------------+
Файлы:
MultiMA.mq5  9 kb
Maxim Dmitrievsky
25923
Maxim Dmitrievsky  
Nikolai Semko:

Сверхбыстрый индикатор из сотен скользящих средних, реализованный на Canvas.

100 линий MA(шаг периода 10) - время расчета и вывода на экран - 4-7 миллисекунд


1000 линий MA(шаг периода 1) - время расчета и вывода на экран - 20-30 миллисекунд


прикольно, через стандартные индикаторы повисло бы все наглухо

Nikolai Semko
8283
Nikolai Semko  
Maxim Dmitrievsky:

прикольно, через стандартные индикаторы повисло бы все наглухо

а еще бы был километр кода...

может быть даже это можно сделать только с помощью шаблона. Не в курсе на счет ограничений количества линий индикатора в теле одного индикатора. 

Anatoli Kazharski
35479
Anatoli Kazharski  
Nikolai Semko:

...

Не в курсе на счет ограничений количества линий индикатора в теле одного индикатора. 

Ограничение есть. До 512 индикаторных буфера можно сделать >>> https://www.mql5.com/ru/docs/indicators

Документация по MQL5: Технические индикаторы
Документация по MQL5: Технические индикаторы
  • www.mql5.com
Все функции типа iMA, iAC, iMACD, iIchimoku и т.п., создают в глобальном кеше клиентского терминала копию соответствующего технического индикатора. Если копия индикатора с этими параметрами уже существует, то новая копия не создается, а увеличивается счетчик ссылок на данную копию. Эти функции возвращают хэндл соответствующей копии индикатора...