Спасибо за хороший учебный пример качественного кода - Общее обсуждение

Maxim Kuznetsov 2022.05.20 16:43 #721

Vitaliy Kuznetsov #:

Может кто-нибудь подсказать, есть ли готовый код для Edit Box на канвас.

Делаю резиновую панельку и нужен такой элемент. По нажатию на него нужно вписывать и удалять цифры и видеть мигающий курсор.

Если нет, то сделаю обычную подмену при нажатии.

кто-то делал, были проблемы не с графикой, а с вводом - MetaTrader "утаскивал/обрабатывал" привычные кнопки (Enter/Tab) и вообще KeyPress/Repeate/Release.

проще взять DLL и заэмбедидь окно Виндовс-контрола, или сразу Notepad.exe чего мелочиться.

Несколько дней мата про недостаток информации (низкоуровневые вещи сейчас сложно искать, их мало), но кода в итоге будет на два порядка меньше и работать будет лучше

Элитные показатели :) Элементы управления на графиках Когда оживет форум? :)

Anatoli Kazharski 2022.05.20 17:28 #722

Vitaliy Kuznetsov #:

Может кто-нибудь подсказать, есть ли готовый код для Edit Box на канвас.

...

EasyAndFastGUI - библиотека для создания графических интерфейсов >>>

Смотрите файл TextBox.mqh

EasyAndFastGUI - библиотека для создания графических интерфейсов

www.mql5.com

Библиотека EasyAndFastGUI дает возможность создавать графические интерфейсы для своих MQL-программ.

Vitaliy Kuznetsov 2022.05.20 17:32 #723

Всем спасибо, попробую разные варианты

Maxim Kuznetsov 2022.05.22 10:48 #724

Maxim Kuznetsov #:

кто-то делал, были проблемы не с графикой, а с вводом - MetaTrader "утаскивал/обрабатывал" привычные кнопки (Enter/Tab) и вообще KeyPress/Repeate/Release.

проще взять DLL и заэмбедидь окно Виндовс-контрола, или сразу Notepad.exe чего мелочиться.

Несколько дней мата про недостаток информации (низкоуровневые вещи сейчас сложно искать, их мало), но кода в итоге будет на два порядка меньше и работать будет лучше

кстати про "заэмбедить" и помятуя разные эксперименты: окошки встраиваются, но есть имеют проблемы с перерисовкой и вводом. Просто неюзабельно, остановился на "факт что потенциально работает"

Впрочем неудивительно - эксперты работают в одном треде, GUI чарта в другом и там же ещё разное видимо.
Надо как-то объяснять Windows чтобы все требуемые сообщения пересылались и отрисовка корректно обрабатывалась. Не вполне типичная конструкция GUI когда есть контрол (в терминах win, это всё-таки окно) у которого всё в общем-то в другом треде.

Тут я конечно в некотором тупике, практика Linux не способствует. надо выставлять какие-то(какие?) флаги процессу эксперта (в терминах ОС он-же не GUI-тред вроде как и часть до него просто недолетает) и/или дёргать AttachThreadInput

если такую проблемы решить то для не страшащихся DLL открываются радужные перспективы:

- можно будет использовать Gtk/Qt/Lazarus с их дизайнерами и действительно хорошей графикой, для "диалогов внутри чарта" (а toplevel и так делаются, но это не всегда удобно, всё-же пользователь работает с чартом)

- можно будет делать свои "вкладки" - внутри MDI и от "нарисовать окошко в чарт" до "сделать вкладку в МТ" пол шага. Всякие доски/боарды не будут требовать открытия нового чарта

Да, на уровне хака :-)

Советники: Stop loss Take График Тестера Стратегий всегда Элитные показатели :)

Ilyas 2022.05.23 09:41 #725

Vitaliy Kuznetsov #:

Может кто-нибудь подсказать, есть ли готовый код для Edit Box на канвас.

Делаю резиновую панельку и нужен такой элемент. По нажатию на него нужно вписывать и удалять цифры и видеть мигающий курсор.

Если нет, то сделаю обычную подмену при нажатии.

Примерный код такого EditCtrl (основа)

//+------------------------------------------------------------------+
//|                                                     EditCtrl.mq5 |
//|                                  Copyright 2022, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2022, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"

#include <Canvas/Canvas.mqh>
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
class CControl : protected CCanvas
  {
public:

   bool              Create(int x,int y,int w,int h)
     {
      if(!CCanvas::CreateBitmapLabel("TEST_EDIT",x,y,w,h,COLOR_FORMAT_ARGB_NORMALIZE))
         return(false);
      if(!OnCreate())
         return(false);

      Update();
      return(true);
     }

   void              TimerSet(uint msec)
     {
      if(msec)
         EventSetMillisecondTimer(msec);
      else
         EventKillTimer();
     }

   void              Update(void)
     {
      OnDraw(this);
      CCanvas::Update();
     }

   virtual bool      OnCreate(void) { return(true); }
   virtual void      OnKeyDown(int key,uint flags) { }
   virtual void      OnTimer(void) { }
   virtual void      OnDraw(CCanvas &canvas) { }
  };
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
class CEditCtrl : public CControl
  {
protected:
   string            m_text;
   uint              m_cursor_pos;
   bool              m_cursor_visible;

public:
   virtual bool      OnCreate(void)
     {
      m_cursor_pos    =0;
      m_cursor_visible=true;
      m_text          ="";
      TimerSet(500);
      return(true);
     }

   virtual void      OnKeyDown(int key,uint flags)
     {
      short code;

      switch(key)
        {
         case 35: // END
            if(m_cursor_pos==m_text.Length())
               return;
            m_cursor_pos=m_text.Length();
            break;
         case 36: // HOME
            if(m_cursor_pos==0)
               return;
            m_cursor_pos=0;
            break;
         case 37: // LEFT
            if(m_cursor_pos==0)
               return;
            m_cursor_pos--;
            break;
         case 39: // RIGHT
            if(m_cursor_pos>=m_text.Length())
               return;
            m_cursor_pos++;
            break;
         default:
            if((code=TranslateKey(key))==-1)
               return;

            if(code<32)
              {
               if(code==8 && m_cursor_pos)
                 {
                  m_text=m_text.Substr(0,m_cursor_pos-1) + m_text.Substr(m_cursor_pos,-1);

                  if(--m_cursor_pos>m_text.Length())
                     m_cursor_pos=m_text.Length();
                     
                  break;
                 }

               return;
              }

            if(m_cursor_pos!=m_text.Length())
               m_text = m_text.Substr(0,m_cursor_pos) + "\xFFFF" + m_text.Substr(m_cursor_pos,m_text.Length());

            m_text.SetChar(m_cursor_pos,code);
            m_cursor_pos++;
            break;
        }

      Update();
     }

   virtual void      OnTimer(void)
     {
      m_cursor_visible=!m_cursor_visible;
      Update();
     }

   virtual void      OnDraw(CCanvas &canvas)
     {
      CCanvas::Erase(ARGB(255,255,255,255));

      if(m_text.Length())
         canvas.TextOut(0,0,m_text,ARGB(255,0,0,0));

      if(m_cursor_visible)
        {
         int x=0,y;

         if(m_cursor_pos)
            canvas.TextSize(m_text.Substr(0,m_cursor_pos),x,y);

         canvas.FillRectangle(x,0,x,canvas.Height(),ARGB(255,0,0,0));
        }
     }
  };

CEditCtrl ExtEditCtrl;
CControl *ExtInputFocus=&ExtEditCtrl;
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit(void)
  {
   ExtEditCtrl.Create(100,100,200,20);

   ChartSetInteger(0,CHART_QUICK_NAVIGATION,false);
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
  }
//+------------------------------------------------------------------+
//| Timer function                                                   |
//+------------------------------------------------------------------+
void OnTimer(void)
  {
   ExtInputFocus.OnTimer();
  }
//+------------------------------------------------------------------+
//| ChartEvent function                                              |
//+------------------------------------------------------------------+
void OnChartEvent(const int id,
                  const long &lparam,
                  const double &dparam,
                  const string &sparam)
  {
   if(id==CHARTEVENT_KEYDOWN)
      ExtInputFocus.OnKeyDown((int)lparam,(uint)sparam);
  }
//+------------------------------------------------------------------+

Vitaliy Kuznetsov 2022.05.23 11:14 #726

Ilyas #:

Примерный код такого EditCtrl (основа)

Спасибо. На МТ5 чуть позже буду пробовать.

Nikolai Semko 2022.05.23 11:54 #727

Ilyas #:

Примерный код такого EditCtrl (основа)

Спасибо, Ильяс, за хороший учебный пример качественного кода

Aleksei Beliakov 2022.05.23 13:39 #728

Ilyas #:

Примерный код такого EditCtrl (основа)

а можно както оключить backspace? чтобы обьект не удалялся?

Ilyas 2022.05.23 15:00 #729

Aleksei Beliakov #:

а можно както оключить backspace? чтобы обьект не удалялся?

int OnInit()
  {
   ChartSetInteger(0,CHART_EVENT_OBJECT_CREATE,true);   
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| ChartEvent function                                              |
//+------------------------------------------------------------------+
void OnChartEvent(const int id,
                  const long &lparam,
                  const double &dparam,
                  const string &sparam)
  {
   if(id==CHARTEVENT_OBJECT_CREATE)
     {
      ObjectSetInteger(0,sparam,OBJPROP_HIDDEN,true);
      ChartRedraw();
      Print(sparam);
     }
  }

Aleksei Beliakov 2022.05.24 00:45 #730

Ilyas #:

Даже если я ставлю это свойство объект удаляется backspace, может дело в том что он выделен?

Существует ли способ поместить обьект поверх другого если время создания меньше?

Например я создаю обьект bitmap label затем любой другой, bitmaplabel находится под объектами которые созданы после нее

Вопрос можно ли как-то поместить bitmap label поверх объектов созданных после нее кроме как удалить и создать заново?

Ошибки, баги, вопросы [АРХИВ]Любой вопрос новичка, чтоб Любые вопросы новичков по

Canvas - это круто! - страница 73