Справочник MQL5Стандартная библиотекаМатематикаНечеткая логикаФункции принадлежностиCTrapezoidMembershipFunction

CTrapezoidMembershipFunction

Класс для реализации трапециевидной функции принадлежности с параметрами X1, X2, X3 и X4.

Описание

Функция формируется с использованием кусочно-линейной аппроксимации. Это обобщение треугольной функции, она позволяет задавать ядро нечеткого множетсва в виде интервала. Такая функция принадлежности делает возможной удобную интерпретацию оптимистической/пессимистической оценки.

Применяется для задания асимметричных функций принадлежности переменных, наиболее возможные значения которых принимаются на некотором интервале.

fuzzy_trapezoid_function

Пример кода для построения этого графика приведен ниже.

Декларация

class CTrapezoidMembershipFuncion : public IMembershipFunction

Заголовок

#include <Math\Fuzzy\membershipfunction.mqh>

Иерархия наследования

CObject

IMembershipFunction

CTrapezoidMembershipFunction

Методы класса

Метод класса	Описание
X1	Возвращает и устанавливает значение первой точки на абсциссе.
X2	Возвращает и устанавливает значение второй точки на абсциссе.
X3	Возвращает и устанавливает значение третьей точки на абсциссе.
X4	Возвращает и устанавливает значение четвертой точки на абсциссе.
GetValue	Рассчитывает значение функции принадлежности по указанному аргументу.

Методы унаследованные от CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Пример

//+------------------------------------------------------------------+
//|                                  TrapezoidMembershipFunction.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Create membership functions
CTrapezoidMembershipFunction func1(0,2,5,5);
CTrapezoidMembershipFunction func2(0,3,7,10);
CTrapezoidMembershipFunction func3(4,8,8,10);
//--- Create wrappers for membership functions
double TrapezoidMembershipFunction1(double x) { return(func1.GetValue(x)); }
double TrapezoidMembershipFunction2(double x) { return(func2.GetValue(x)); }
double TrapezoidMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- create graphic
   CGraphic graphic;
   if(!graphic.Create(0,"TrapezoidMembershipFunction",0,30,30,780,380))
     {
      graphic.Attach(0,"TrapezoidMembershipFunction");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("TrapezoidMembershipFunction");
   graphic.BackgroundMainSize(16);
//--- create curve
   graphic.CurveAdd(TrapezoidMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[0, 2, 5, 5]");
   graphic.CurveAdd(TrapezoidMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[0, 5, 7, 10]");
   graphic.CurveAdd(TrapezoidMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[4, 8, 8, 10]");
//--- sets the X-axis properties
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- sets the Y-axis properties
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- plot
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue