Referência MQL5Biblioteca PadrãoMatemáticaLógica difusaFunções de associaçãoCProductTwoSigmoidalMembershipFunctions

CProductTwoSigmoidalMembershipFunction

Classe para implementar uma função de associação na forma do produto entre duas funções sigmóides com parâmetros A1, A2, C1, C2.

Descrição

O produto de duas funções de associação sigmóides é usado para definir as funções assimétricas suaves. Você pode usá-lo para criar uma função de associação com valores iguais a 1, começando com um determinado valor do argumento. Estas funções são adequados, se é necessário definir os termos linguísticos de tipo "curto" ou "longo".

fuzzy_prodsigmoidal_function

Exemplo de código para plotagem do gráfico mostrado abaixo.

Declaração

class CProductTwoSigmoidalMembershipFuncion : public IMembershipFunction

Cabeçalho

#include <Math\Fuzzy\membershipfunction.mqh>

Hierarquia de herança

CObject

IMembershipFunction

CProductTwoSigmoidalMembershipFunctions

Métodos de classe

Método de classe	Descrição
A1	Retorna e define o coeficiente de inclinação da primeira função de associação.
A2	Retorna e define o coeficiente de inclinação da segunda função de associação.
C1	Retorna o parâmetro de coordenada da inflexão da primeira função de associação.
C2	Retorna o parâmetro de coordenada da inflexão da segunda função de associação.
GetValue	Calcula o valor da função de associação para o argumento especificado.

Métodos herdados da classe CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Exemplo

//+------------------------------------------------------------------+
//|                       ProductTwoSigmoidalMembershipFunctions.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Create membership functions
CProductTwoSigmoidalMembershipFunctions func1(2,1,-1,7);
CProductTwoSigmoidalMembershipFunctions func2(2,2,-4,7);
CProductTwoSigmoidalMembershipFunctions func3(2,3,-8,7);
//--- Create wrappers for membership functions
double ProductTwoSigmoidalMembershipFunctions1(double x) { return(func1.GetValue(x)); }
double ProductTwoSigmoidalMembershipFunctions2(double x) { return(func2.GetValue(x)); }
double ProductTwoSigmoidalMembershipFunctions3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- create graphic
   CGraphic graphic;
   if(!graphic.Create(0,"ProductTwoSigmoidalMembershipFunctions",0,30,30,780,380))
     {
      graphic.Attach(0,"ProductTwoSigmoidalMembershipFunctions");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("ProductTwoSigmoidalMembershipFunctions");
   graphic.BackgroundMainSize(16);
//--- create curve
   graphic.CurveAdd(ProductTwoSigmoidalMembershipFunctions1,0.0,10.0,0.1,CURVE_LINES,"[2, 1, -1, 7]");
   graphic.CurveAdd(ProductTwoSigmoidalMembershipFunctions2,0.0,10.0,0.1,CURVE_LINES,"[2, 2, -4, 7]");
   graphic.CurveAdd(ProductTwoSigmoidalMembershipFunctions3,0.0,10.0,0.1,CURVE_LINES,"[2, 3, -8, 7]");
//--- sets the X-axis properties
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- sets the Y-axis properties
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- plot
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue