Справочник MQL5Стандартная библиотекаМатематикаНечеткая логикаФункции принадлежностиCProductTwoSigmoidalMembershipFunctions

CProductTwoSigmoidalMembershipFunction

Класс для реализации функции принадлежности в виде произведения двух сигмоидных функций с параметрами А1, А2, С1, С2.

Описание

Произведение двух сигмоидных функций принадлежности применяется для задания гладких асимметричных функций. С его помощью можно создавать функции принадлежности со значениями, равными 1, начиная с некоторого значения аргумента. Подобные функции подходят, если необходимо задать лингвистические термы типа "короткий" или "длинный".

fuzzy_prodsigmoidal_function

Пример кода для построения этого графика приведен ниже.

Декларация

class CProductTwoSigmoidalMembershipFuncion : public IMembershipFunction

Заголовок

#include <Math\Fuzzy\membershipfunction.mqh>

Иерархия наследования

CObject

IMembershipFunction

CProductTwoSigmoidalMembershipFunctions

Методы класса

Метод класса	Описание
A1	Возвращает и устанавливает коэффициент крутизны первой функции принадлежности.
A2	Возвращает и устанавливает коэффициент крутизны второй функции принадлежности.
C1	Возвращает параметр координаты перегиба первой функции принадлежности.
C2	Возвращает параметр координаты перегиба второй функции принадлежности.
GetValue	Рассчитывает значение функции принадлежности по указанному аргументу.

Методы унаследованные от CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Пример

//+------------------------------------------------------------------+
//|                       ProductTwoSigmoidalMembershipFunctions.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Create membership functions
CProductTwoSigmoidalMembershipFunctions func1(2,1,-1,7);
CProductTwoSigmoidalMembershipFunctions func2(2,2,-4,7);
CProductTwoSigmoidalMembershipFunctions func3(2,3,-8,7);
//--- Create wrappers for membership functions
double ProductTwoSigmoidalMembershipFunctions1(double x) { return(func1.GetValue(x)); }
double ProductTwoSigmoidalMembershipFunctions2(double x) { return(func2.GetValue(x)); }
double ProductTwoSigmoidalMembershipFunctions3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- create graphic
   CGraphic graphic;
   if(!graphic.Create(0,"ProductTwoSigmoidalMembershipFunctions",0,30,30,780,380))
     {
      graphic.Attach(0,"ProductTwoSigmoidalMembershipFunctions");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("ProductTwoSigmoidalMembershipFunctions");
   graphic.BackgroundMainSize(16);
//--- create curve
   graphic.CurveAdd(ProductTwoSigmoidalMembershipFunctions1,0.0,10.0,0.1,CURVE_LINES,"[2, 1, -1, 7]");
   graphic.CurveAdd(ProductTwoSigmoidalMembershipFunctions2,0.0,10.0,0.1,CURVE_LINES,"[2, 2, -4, 7]");
   graphic.CurveAdd(ProductTwoSigmoidalMembershipFunctions3,0.0,10.0,0.1,CURVE_LINES,"[2, 3, -8, 7]");
//--- sets the X-axis properties
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- sets the Y-axis properties
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- plot
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue