OnBookEvent

void  OnBookEvent(
   const string&  symbol         // 심볼
   );

//+------------------------------------------------------------------+
//|                                           OnBookEvent_Sample.mq5 |
//|                        Copyright 2018, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com/en/articles/2635"
#property version   "1.00"
#property description "OnBookEvent()를 사용하여 시장 수준 업데이트/교체율 측정 예"
#property description "코드는 다음 문서에서 가져왔습니다. https://www.mql5.com/en/articles/2635"
//--- 매개변수 입력
input ulong ExtCollectTime   =30;  // 테스트 시간(초)
input ulong ExtSkipFirstTicks=10;  // 시작할 때 건너뛴 틱 수
//--- BookEvent 이벤트 구독 플래그
bool book_subscribed=false;
//--- 시장 수준으로부터의 요청을 수락하기 위한 배열
MqlBookInfo  book[];
//+------------------------------------------------------------------+
//| 엑스퍼트 초기화 기능                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- 시작 표시
   Comment(StringFormat("첫 %I64u 틱이 도착할 때까지 기다리는 중",ExtSkipFirstTicks));
   PrintFormat("첫 %I64u 틱이 도착할 때까지 기다리는 중",ExtSkipFirstTicks);
//--- 시장 수준 브로드캐스트 가능
   if(MarketBookAdd(_Symbol))
     {
      book_subscribed=true;
      PrintFormat("%s: MarketBookAdd(%s) 함수가 true 반환함",__FUNCTION__,_Symbol);
     }
   else
      PrintFormat("%s: MarketBookAdd(%s) 함수가 false 반환함! GetLastError()=%d",__FUNCTION__,_Symbol,GetLastError());
//--- 성공적인 초기화
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| 초기화 해제 엑스퍼트                                              |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//--- 초기화 취소 이유 코드 표시
   Print(__FUNCTION__,": 초기화 해제 이유 코드 = ",reason);  
//--- 시장 수준 이벤트 가져오기를 위해 구독을 취소
   if(book_subscribed)
     {
      if(!MarketBookRelease(_Symbol))
         PrintFormat("%s: MarketBookRelease(%s)가 false 반환! GetLastError()=%d",_Symbol,GetLastError());
      else
         book_subscribed=false;
     }
//--- 
  }
//+------------------------------------------------------------------+
//| BookEvent 기능                                               |
//+------------------------------------------------------------------+
void OnBookEvent(const string &symbol)
  {
   static ulong starttime=0;             // 테스트 시작 시간
   static ulong tickcounter=0;           // 시장 수준 업데이트 카운터
//--- 직접 구독해야 시장 수준 이벤트를 진행할 수 있습니다
   if(!book_subscribed)
      return;
//--- 특정 기호에 대한 업데이트만의 수
   if(symbol!=_Symbol)
      return;
//--- 첫 번째 체크 표시를 건너 뛰고 대기열을 지우고 준비
   tickcounter++;
   if(tickcounter<ExtSkipFirstTicks)
      return;
//--- 시작 시간을 기억
   if(tickcounter==ExtSkipFirstTicks) 
      starttime=GetMicrosecondCount();
//--- 시장 수준 데이터를 요청
   MarketBookGet(symbol,book);
//--- 언제 멈추나요?  
   ulong endtime=GetMicrosecondCount()-starttime;
   ulong ticks  =1+tickcounter-ExtSkipFirstTicks;
// 테스트 시작 후 시간(마이크로초)이 얼마나 지났습니까?
   if(endtime>ExtCollectTime*1000*1000) 
     {
      PrintFormat("%I64u ticks for %.1f seconds: %.1f ticks/sec ",ticks,endtime/1000.0/1000.0,ticks*1000.0*1000.0/endtime);
      ExpertRemove();
      return;
     }
//--- 코멘트 필드에 카운터를 표시
   if(endtime>0)
      Comment(StringFormat("%I64u ticks for %.1f seconds: %.1f ticks/sec ",ticks,endtime/1000.0/1000.0,ticks*1000.0*1000.0/endtime));
  }