Iin_MA_Signal_Alert - MetaTrader 5のためのインディケータ

著者:Iin Zulkarnainn

Iin_MA_Signalセマフォシグナルインジケータは、アラート、電子メール、プッシュ通知を備えています。

アラート、電子メールメッセージ、およびプッシュ通知を実装するために、インジケータコードに次の変更が加えられました。

1. 新しいインプットパラメータを導入

   input uint NumberofBar=1;//シグナルの足番号
   input bool SoundON=true; //アラートを有効にする
   input uint NumberofAlerts=2;//アラートの数
   input bool EMailON=false; //シグナルの送信を有効にする
   input bool PushON=false; //モバイルデバイスへのシグナル送信を有効にする
   

2. インジケータコードの最後に3つの新しい関数を追加しました: BuySignal ()、SellSignal () と GetStringTimeframe ()

   //+------------------------------------------------------------------+
   //| Buy signal function                                              |
   //+------------------------------------------------------------------+
   void BuySignal(string SignalSirname,      //電子メールおよびプッシュメッセージのインジケータ名のテキスト
                  double &BuyArrow[],        //買いシグナル付きインジケータバッファ
                  const int Rates_total,     //現在の足数
                  const int Prev_calculated, //前のティックの足の数
                  const double &Close[],     //終値
                  const int &Spread[])       //スプレッド
     {
   //---
      static uint counter=0;
      if(Rates_total!=Prev_calculated) counter=0;
   
      bool BuySignal=false;
      bool SeriesTest=ArrayGetAsSeries(BuyArrow);
      int index;
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      if(NormalizeDouble(BuyArrow[index],_Digits) && BuyArrow[index]!=EMPTY_VALUE) BuySignal=true;
      if(BuySignal && counter<=NumberofAlerts)
        {
         counter++;
         MqlDateTime tm;
         TimeToStruct(TimeCurrent(),tm);
         string text=TimeToString(TimeCurrent(),TIME_DATE)+" "+string(tm.hour)+":"+string(tm.min);
         SeriesTest=ArrayGetAsSeries(Close);
         if(SeriesTest) index=int(NumberofBar);
         else index=Rates_total-int(NumberofBar)-1;
         double Ask=Close[index];
         double Bid=Close[index];
         SeriesTest=ArrayGetAsSeries(Spread);
         if(SeriesTest) index=int(NumberofBar);
         else index=Rates_total-int(NumberofBar)-1;
         Bid+=Spread[index];
         string sAsk=DoubleToString(Ask,_Digits);
         string sBid=DoubleToString(Bid,_Digits);
         string sPeriod=GetStringTimeframe(ChartPeriod());
         if(SoundON) Alert("BUY signal \n Ask=",Ask,"\n Bid=",Bid,"\n currtime=",text,"\n Symbol=",Symbol()," Period=",sPeriod);
         if(EMailON) SendMail(SignalSirname+": BUY signal alert","BUY signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);
         if(PushON) SendNotification(SignalSirname+": BUY signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);
        }
   
   //---
     }
   //+------------------------------------------------------------------+
   //| Sell signal function                                             |
   //+------------------------------------------------------------------+
   void SellSignal(string SignalSirname,      //電子メールおよびプッシュメッセージのインジケータ名のテキスト
                   double &SellArrow[],       //売りシグナル付きインジケータバッファ
                   const int Rates_total,     //現在の足数
                   const int Prev_calculated, //前のティックの足の数
                   const double &Close[],     //終値
                   const int &Spread[])       //スプレッド
     {
   //---
      static uint counter=0;
      if(Rates_total!=Prev_calculated) counter=0;
   
      bool SellSignal=false;
      bool SeriesTest=ArrayGetAsSeries(SellArrow);
      int index;
      if(SeriesTest) index=int(NumberofBar);
      else index=Rates_total-int(NumberofBar)-1;
      if(NormalizeDouble(SellArrow[index],_Digits) && SellArrow[index]!=EMPTY_VALUE) SellSignal=true;
      if(SellSignal && counter<=NumberofAlerts)
        {
         counter++;
         MqlDateTime tm;
         TimeToStruct(TimeCurrent(),tm);
         string text=TimeToString(TimeCurrent(),TIME_DATE)+" "+string(tm.hour)+":"+string(tm.min);
         SeriesTest=ArrayGetAsSeries(Close);
         if(SeriesTest) index=int(NumberofBar);
         else index=Rates_total-int(NumberofBar)-1;
         double Ask=Close[index];
         double Bid=Close[index];
         SeriesTest=ArrayGetAsSeries(Spread);
         if(SeriesTest) index=int(NumberofBar);
         else index=Rates_total-int(NumberofBar)-1;
         Bid+=Spread[index];
         string sAsk=DoubleToString(Ask,_Digits);
         string sBid=DoubleToString(Bid,_Digits);
         string sPeriod=GetStringTimeframe(ChartPeriod());
         if(SoundON) Alert("SELL signal \n Ask=",Ask,"\n Bid=",Bid,"\n currtime=",text,"\n Symbol=",Symbol()," Period=",sPeriod);
         if(EMailON) SendMail(SignalSirname+": SELL signal alert","SELL signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);
         if(PushON) SendNotification(SignalSirname+": SELL signal at Ask="+sAsk+", Bid="+sBid+", Date="+text+" Symbol="+Symbol()+" Period="+sPeriod);
        }
   //---
     }
   //+------------------------------------------------------------------+
   //| 時間枠を文字列として取得する |
   //+------------------------------------------------------------------+
   string GetStringTimeframe(ENUM_TIMEFRAMES timeframe)
     {
   //----
      return(StringSubstr(EnumToString(timeframe),7,-1));
   //----
     }
   

3. OnCalculate () ブロックのインジケータ計算サイクルの後、BuySignal () および SellSignal () 関数への呼び出しをいくつか追加しました。

   //---     
      BuySignal("Iin_MA_Signal_Alert",BuyBuffer,rates_total,prev_calculated,close,spread);
      SellSignal("Iin_MA_Signal_Alert",SellBuffer,rates_total,prev_calculated,close,spread);
   //--- 
   

ここで、BuyBuffer と SellBuffer は、売買シグナルを格納するためのインジケータバッファの名前です。 インジケータの空の値がゼロまたは EMPTY_VALUE のいずれかを設定する必要があります。

BuySignal () および SellSignal () 関数に対する1つの呼び出しだけが、インジケータコードの OnCalculate () ブロックで使用することが前提となります。

図1. チャート上の Iin_MA_Signal_Alert

図2. Iin_MA_Signal_Alert. アラートの生成