Demo_FileWrite - MetaTrader 5のためのスクリプト

このスクリプトはMACD指標で形成されたシグナルを定義してファイルに保存します。スクリプトの入力パラメータではMACD指標計算や通貨ペアと時間枠だけではなくデータ分析の日付が指定できます。指標シグナルを持つファイルは、ローカル端末フォルダの「Data」サブディレクトリに配置されます。

コード：

最初に、指標値と時間配列と指定された期間の配列を取得します。

//--- 終了時刻が現在時刻
   date_finish=TimeCurrent();
//--- MACD 指標ハンドルを受け取る
   ResetLastError();
   int macd_handle=iMACD(InpSymbolName,InpSymbolPeriod,InpFastEMAPeriod,InpSlowEMAPeriod,InpSignalPeriod,InpAppliedPrice);
   if(macd_handle==INVALID_HANDLE)
     {
      //--- 指標ハンドルの受け取りに失敗
      PrintFormat("Error when receiving indicator handle. Error code = %d",GetLastError());
      return;
     }
//--- 全ての指標値が計算されるまでループに留まる
   while(BarsCalculated(macd_handle)==-1)
      Sleep(10); // 指標が全ての値を計算出来るように一時停止する
//--- 一定期間の指標値を複製する
   ResetLastError();
   if(CopyBuffer(macd_handle,0,InpDateStart,date_finish,macd_buff)==-1)
     {
      PrintFormat("Failed to copy indicator values. Error code = %d",GetLastError());
      return;
     }
//--- 指標値に適切な時間を複製する
   ResetLastError();
   if(CopyTime(InpSymbolName,InpSymbolPeriod,InpDateStart,date_finish,date_buff)==-1)
     {
      PrintFormat("Failed to copy time values. Error code = %d",GetLastError());
      return;
     }

そして、指標シグナルとそれらの形成時間を定義します。

//--- バッファサイズを受け取る
   macd_size=ArraySize(macd_buff);
//--- データを分析し指標シグナルを配列に保存する
   ArrayResize(sign_buff,macd_size-1);
   ArrayResize(time_buff,macd_size-1);
   for(int i=1;i<macd_size;i++)
     {
      //--- 買いシグナル
      if(macd_buff[i-1]<0 && macd_buff[i]>=0)
        {
         sign_buff[sign_size]=true;
         time_buff[sign_size]=date_buff[i];
         sign_size++;
        }
      //--- 売りシグナル
      if(macd_buff[i-1]>0 && macd_buff[i]<=0)
        {
         sign_buff[sign_size]=false;
         time_buff[sign_size]=date_buff[i];
         sign_size++;
        }
     }

最後にFileWrite()関数を使って得られたシグナルの値をファイルに書き込みます。

//--- 指標値を書き込むためにファイルを開く（ファイルが存在しない場合は自動的に作成される）
   ResetLastError();
   int file_handle=FileOpen(InpDirectoryName+"//"+InpFileName,FILE_READ|FILE_WRITE|FILE_CSV);
   if(file_handle!=INVALID_HANDLE)
     {
      PrintFormat("%s file is available for writing",InpFileName);
      PrintFormat("File path: %s\\Files\\",TerminalInfoString(TERMINAL_DATA_PATH));
      //--- 初めにシグナル数を書く
      FileWrite(file_handle,sign_size);
      //--- シグナルの時間と値をファイルに書く
      for(int i=0;i<sign_size;i++)
         FileWrite(file_handle,time_buff[i],sign_buff[i]);
      //--- ファイルを閉じる
      FileClose(file_handle);
      PrintFormat("Data is written, %s file is closed",InpFileName);
     }
   else
      PrintFormat("Failed to open %s file, Error code = %d",InpFileName,GetLastError());