Discusión sobre el artículo "R cuadrado como evaluación de la calidad de la curva del balance de la estrategia" - página 2

Nuevo comentario
 
Leí en diagonal, pero sin embargo - saqué conclusiones importantes para mí. Muchas gracias al autor.
 
Gracias por este artículo tan útil. ¡Reposted it! :-)
 

Figura 19: Distribución de LR-Correlación para 10.000 paseos aleatorios


Figura 20: Distribución de R^2 para 10.000 paseos aleatorios

¿No veo cómo R^2 puede tomar los valores negativos que se muestran en el segundo gráfico? Sí y hay dudas con el primer gráfico. Si la regresión lineal se traza correctamente, parece que el RQ (LR) de Pearson no debería ser negativo. Pero en el gráfico no lo es. ¿En qué me equivoco?


Entendido. No me equivoco en ninguna parte, es sólo que los gráficos tienen R^2 y LR personalizados - la multiplicación por -1 del valor real se produce si el último elemento de la serie numérica es menor que el primero. Sería bueno escribir sobre ello antes de los gráficos.

 

En el documento, la regresión lineal se considera con un error - a través de CLinReg::LRLine.

Prueba

#include <Graphics\Graphic.mqh> 
#include <Math\Stat\Normal.mqh>
#include <Math\Alglib\Alglib.mqh>

// Devuelve los valores Y de la recta (y(x)=a*x+b)
void GetLine( const double a, const double b, const int Amount, double &Result[] )
{
  ArrayResize(Result, Amount);
  
  for (int i = 0; i < Amount; i++)
    Result[i] = a * i + b;    
}

// Devuelve una regresión lineal mediante CLinReg::LRLine
void GetLinearRegression( const double &Array[], double &Result[] )
{
  const int Total = ArraySize(Array);
  
  CMatrixDouble XY(Total, 2);
  
  for (int i = 0; i < Total; i++)
  {
    XY[i].Set(0, i);
    XY[i].Set(1, Array[i]);
  }
  
  int retcode;
  double a, b;
  
  CLinReg::LRLine(XY, Total, retcode, a, b);

  GetLine(a, b, Total, Result);    
}

// Devuelve una regresión lineal mediante CAlglib::LRBuild + CAlglib::LRUnpack
void GetLinearRegression2( const double &Array[], double &Result[] )
{
  const int Total = ArraySize(Array);
  
  CMatrixDouble XY(Total, 2);
  
  for (int i = 0; i < Total; i++)
  {
    XY[i].Set(0, i);
    XY[i].Set(1, Array[i]);
  }
  
  int retcode;
  
  CLinearModelShell lm;
  CLRReportShell    ar;
//--- arrays para almacenar los resultados de la regresión
  double lr_coeff[];
//--- cálculo de los coeficientes de regresión lineal
  CAlglib::LRBuild(XY, Total, 1, retcode, lm, ar);
//--- obtención de coeficientes de regresión lineal
  CAlglib::LRUnpack(lm, lr_coeff, retcode);

  GetLine(lr_coeff[0], lr_coeff[1], Total, Result);      
}

void ToChart( const double &Array1[], const double &Array2[], const int X = 0, const int Y = 0, const int Width = 780, const int Height = 380 )
{
  static const string Name = __FILE__;
  
  CGraphic Graphic; 

  if (ObjectFind(0, Name) < 0) 
    Graphic.Create(0, Name, 0, X, Y, Width, Height); 
  else 
    Graphic.Attach(0, Name); 

  Graphic.CurveAdd(Array1, CURVE_LINES);
  Graphic.CurveAdd(Array2, CURVE_LINES);
  
  Graphic.CurvePlotAll(); 
  Graphic.Update();  
}

void GetRandomArray( double &Array[], const int Amount = 1 e3 )
{
  double Random[];
  
  MathSrand(GetTickCount()); 

  MathRandomNormal(0, 1, Amount, Random); 
  MathCumulativeSum(Random, Array);
}

#define  TOSTRING(A) #A + " = " + (string)(A) + "\n"

void OnStart() 
{   
  double Array[];
  
  GetRandomArray(Array);  
  
  double Estimate[];
  double Estimate2[];
     
  GetLinearRegression(Array, Estimate);
  GetLinearRegression2(Array, Estimate2);

  const double R = CAlglib::PearsonCorr2(Array, Estimate);
  const double R2 = CAlglib::PearsonCorr2(Array, Estimate2);
  
  Print(TOSTRING(R) +
        TOSTRING((Array[0] > Array[ArraySize(Array) - 1]) ? -R : R) +
        TOSTRING(R2));
  
  ToChart(Array, Estimate2);
}


Resultado

R = -0.5864718581193301
(Array[0]>Array[ArraySize(Array)-1])?-R:R = -0.5864718581193301
R2 = 0.58647185811933


El signo es incorrecto. La implementación alternativa de LR (CAlglib::LRBuild + CAlglib::LRUnpack) cuenta correctamente:


 
fxsaber:

Los gráficos de las distribuciones LR Correlación y R^2 para los 10.000 ejemplos independientes que se presentan en el artículo muestran que R^2 != LR^2.

No entiendo por qué el segundo grado de la distribución "cóncava" original la hace "plana".

Aquí es donde se demostró que estaba equivocado. Para mí, la afirmación no es obvia en absoluto

Lo sorprendente es que mediante una simple acción matemática (elevando al segundo grado ) hemos eliminado por completo los efectos marginales no deseados de la distribución.

Así que decidí confirmarlo experimentalmente mediante una animación (que no se fíen de mi palabra)

#include <Graphics\Graphic.mqh> 
#include <Math\Stat\Normal.mqh>
#include <Math\Alglib\Alglib.mqh>

// Devuelve los valores Y de la recta (y(x)=a*x+b)
void GetLine( const double a, const double b, const int Amount, double &Result[] )
{
  ArrayResize(Result, Amount);
  
  for (int i = 0; i < Amount; i++)
    Result[i] = a * i + b;    
}

// Devuelve una regresión lineal mediante CAlglib::LRBuild + CAlglib::LRUnpack
void GetLinearRegression( const double &Array[], double &Result[] )
{
  const int Total = ArraySize(Array);
  
  CMatrixDouble XY(Total, 2);
  
  for (int i = 0; i < Total; i++)
  {
    XY[i].Set(0, i);
    XY[i].Set(1, Array[i]);
  }
  
  int retcode;
  
  CLinearModelShell lm;
  CLRReportShell    ar;
//--- arrays para almacenar los resultados de la regresión
  double lr_coeff[];
//--- cálculo de los coeficientes de regresión lineal
  CAlglib::LRBuild(XY, Total, 1, retcode, lm, ar);
//--- obtención de coeficientes de regresión lineal
  CAlglib::LRUnpack(lm, lr_coeff, retcode);

  GetLine(lr_coeff[0], lr_coeff[1], Total, Result);      
}

// Calcula R
double GetCustomR( const double &Array[] )
{
  double Estimate[];
   
  GetLinearRegression(Array, Estimate);
   
  const double R = CAlglib::PearsonCorr2(Array, Estimate);

  return((Array[0] > Array[ArraySize(Array) - 1]) ? -R : R);
}

// Calcula los vectores aleatorios R
void GetRandomCustomR( const int Amount, const int VectorSize, double &Result[] )
{
  double Random[];
  double Sum[];
  
  MathSrand(GetTickCount()); 

  ArrayResize(Result, Amount);
  
  for (int i = 0; i < Amount; i++)
  {
    MathRandomNormal(0, 1, VectorSize, Random); 
    MathCumulativeSum(Random, Sum);
    
    Result[i] = GetCustomR(Sum);
  }  
}

void ToChart( const double &X[],  const double &Y[], const string Str = NULL, const int X0 = 0, const int Y0 = 0, const int Width = 780, const int Height = 380 )
{
  static const string Name = __FILE__;
  
  CGraphic Graphic; 

  if (ObjectFind(0, Name)<0) 
    Graphic.Create(0, Name, 0, X0, Y0, Width, Height); 
  else 
    Graphic.Attach(0, Name); 

  Graphic.BackgroundMain(Str); 
  Graphic.BackgroundMainSize(16); 

  Graphic.CurveAdd(X, Y, CURVE_HISTOGRAM).HistogramWidth(6);
  
  Graphic.CurvePlotAll(); 
  Graphic.Update();  
}

void MathPow( double &Result[], const double &Array[], const double Pow )
{
  const int Size = ArrayResize(Result, ArraySize(Array));
  
  for (int i = 0; i < Size; i++)
    Result[i] = (Array[i] < 0) ? -MathPow(-Array[i], Pow) : MathPow(Array[i], Pow);
}

// https://www.mql5.com/es/docs/standardlibrary/mathematics/stat/normal
//+------------------------------------------------------------------+ 
//| Calcular frecuencias para el conjunto de datos| 
//+------------------------------------------------------------------+ 
bool CalculateHistogramArray(const double &data[],double &intervals[],double &frequency[], 
                             double &maxv,double &minv,const int cells=10) 
  { 
   if(cells<=1) return (false); 
   int size=ArraySize(data); 
   if(size<cells*10) return (false); 
   minv=data[ArrayMinimum(data)]; 
   maxv=data[ArrayMaximum(data)]; 
   double range=maxv-minv; 
   double width=range/cells; 
   if(width==0) return false; 
   ArrayResize(intervals,cells); 
   ArrayResize(frequency,cells); 
//--- fijar los centros de los intervalos 
   for(int i=0; i<cells; i++) 
     { 
      intervals[i]=minv+(i+0.5)*width; 
      frequency[i]=0; 
     } 
//--- rellenar las frecuencias de intervalo 
   for(int i=0; i<size; i++) 
     { 
      int ind=int((data[i]-minv)/width); 
      if(ind>=cells) ind=cells-1; 
      frequency[ind]++; 
     } 
   return (true); 
  } 

void DistributionToChart( const double &Array[], const string Str = NULL, const int NCells = 51 )
{
  double X[];          // centros de intervalo del histograma 
  double Y[];          // número de valores de la muestra que entran en el intervalo 
  double Max, Min;     // valores máximo y mínimo de la muestra 
  
  CalculateHistogramArray(Array, X, Y, Max, Min, NCells);   

  ToChart(X, Y, Str);
}

void OnInit() 
{   
  double R[];
  
  GetRandomCustomR(1 e3, 1 e4, R);
  
  double Array[];

  const int Max = 50;
  
  while (!IsStopped())
    for (int i = 1; !IsStopped() && i < (Max << 1); i++)
    {
      const double Pow = (i > Max) ? ((Max << 1) - i) * 0.1 : i * 0.1;
      
      MathPow(Array, R, Pow);
      DistributionToChart(Array, "Distribution of R^" + DoubleToString(Pow, 1));      
      
      Sleep(100);
    }
}



Parece ser que es así.

 

 

Fig. 21: Valor R^2 como criterio de optimización personalizado

¿Dónde en MQL LR Correlación, que está en la imagen? ¿O este y muchos otros parámetros se calculan sólo para ejecuciones individuales, por lo que están ausentes en ENUM_STATISTICS?

Si es así, sugieren para calcular este parámetro de las consideraciones razonables mencionados en este artículo: por la equidad sin MM y al cuadrado.


ZY Medí cuánto tiempo se tarda en calcular GetCustomR para una matriz de un millón de valores (como la equidad) - 2,5 segundos. Eso es mucho tiempo. Todo se gasta en el cálculo de LR(CAlglib::LRBuild + CAlglib::LRUnpack). Pero a veces curvado LR a través de CLinReg::LRLine es un orden de magnitud más rápido. Si lo dopeas, llega a ser tolerable en Optimizaciones como criterio de Optimización.

Документация по MQL5: Стандартные константы, перечисления и структуры / Состояние окружения / Статистика тестирования
Документация по MQL5: Стандартные константы, перечисления и структуры / Состояние окружения / Статистика тестирования
  • www.mql5.com
Максимальная просадка баланса в процентах. В процессе торговли баланс может испытать множество просадок, для каждой фиксируется относительное значение просадки в процентах. Возвращается наибольшее значение Максимальная...
 
Dennis Kirichenko:

¡Oh! Siempre pensé que era 100. Gracias, interesante artículo.

Sí, es un número que he encontrado en libros de renombre sobre R y estadística. Pero no he podido encontrar el enlace, lo siento.

Dennis Kirichenko:

También es habitual realizar pruebas de significación sobre el coeficiente de regresión. Incluso Alglib las tiene :-)

Obviamente, las pruebas son para una distribución normal. Nosotros tenemos una distribución uniforme.

PearsonCorrelationSignificance(), SpearmanRankCorrelationSignificance().

Gracias por el enlace, lo recordaré.

 
fxsaber:

ZY Afirmación errónea

R^2 no es más que la correlación entre un gráfico y su modelo lineal

//-- Encuentra R^2 y su signo
   double r2 = MathPow(corr, 2.0);

Sí, efectivamente, un craso error de redacción. Me sorprende haber escrito tal cosa. Lo corregiré.

Cuando nos fijamos en todos los demás MQL-códigos, usted no entiende por qué se dan, porque son completamente ilegibles sin el conocimiento CStrategy

CStrategy es necesario sólo para recoger los requisitos. El código principal, como se señaló con razón, es el cálculo real de R2.

El código para el cálculo de la "equidad", adecuado para R^2. Está escrito en estilo MT4, no es difícil traducirlo a MT5....

Vamos a estudiarlo.

 
Maxim Dmitrievsky:

Estoy de acuerdo con esto, todo lo demas tendra que ser arrancado de clases para agregarlo a tu sistema... seria mejor tener todo en f-iases separadas o un includnik separado.

Toma tu cálculo de equidad (o el código presentado por fxsaber) como un doble-array e insértalo en la función de cálculo R^2. No necesitas arrancar nada, no necesitas usar clases y CStrategy.

 
fxsaber:

No entiendo cómo R^2 puede tomar valores negativos como se muestra en el segundo gráfico. También hay dudas con el primer gráfico. Si la regresión lineal se construye correctamente, parece que la R^2 de Pearson no debería ser negativa. Pero en el gráfico no lo es. ¿En qué me equivoco?

Entendido. No me equivoco en ninguna parte, es sólo que los gráficos tienen R^2 y LR personalizados - la multiplicación por -1 del valor real se produce si el último elemento de la serie numérica es menor que el primero. Sería bueno escribir sobre esto antes de los gráficos.

Está oculto en el artículo:

Nuestro script calcula tanto la Correlación LR como R^2. Veremos la diferencia entre ellas un poco más adelante. Hay una pequeña adición a la secuencia de comandos. Multiplicaremos el coeficiente de correlación resultante por el signo final del gráfico sintético. Si acabamos con un resultado menor que cero, la correlación será negativa, si es mayor - positiva. Esto se hace para separar rápida y fácilmente los resultados negativos de los positivos sin tener que recurrir a otras estadísticas. Así es como funciona la Correlación LR en MetaTrader 5, y R^2 se construirá de acuerdo con el mismo principio.

Tal vez debería haber escrito sobre ello en otro lugar y varias veces.
123456789
Nuevo comentario