MQL5 Wizard - Señales de trading basadas en tres medias móviles (3EMA) - Asesor Experto para MetaTrader 5

MQL5 Wizard permite crear el código de Asesores Expertos automáticamente. Vea Crear Asesores Expertos listos para usar con el MQL5 Wizard para más detalles.

Aquí consideraremos la estrategia de tendencia, basada en tres medias móviles. La estrategia llamada "Signals based on three EMA". Para determinar la tendencia, se utilizan tres medias móviles exponencialmente suavizadas: FastEMA (rápida), MediumEMA (media) y SlowEMA (lenta).

Señales de trading:

• Compra: FastEMA>MediumEMA>SlowEMA (tendencia alcista).
• Venta: FastEMA<MediumEMA<SlowEMA (tendencia bajista).

Esta estrategia se implementa en la clase CSignal3EMA.

Figura 1. Señales de trading, basadas en tres medias móviles

Señales de Trade

La estrategia de trading se implementa en la clase CSignal3EMA, contiene algunos métodos protected para simplificar el acceso a los valores de las tres medias móviles ( Rápida, Media y Lenta):

double  FastEMA(int ind)      // devuelve el valor de la EMA rápida de la barra
double  MediumEMA(int ind)    // devuelve el valor de la EMA media de la barra
double  SlowEMA(int ind)      // devuelve el valor de la EMA lenta de la barra

1. Apertura de una posición larga

La tendencia alcista está determinada por la condición siguiente: FastEMA>MediumEMA>SlowEMA:

• FastEMA(1)>MediumEMA(1): EMA Rápida es mayor que la EMA Media (en la última barra completa);
• MediumEMA(1)>SlowEMA(1): EMA Media es mayor que la EMA lenta (en la última barra completa);

//+------------------------------------------------------------------+
//| Comprueba condiciones de apertura de posición larga (compra)     |
//+------------------------------------------------------------------+
bool CSignal3EMA::CheckOpenLong(double& price,double& sl,double& tp,datetime& expiration)
  {
   double medium=MediumEMA(1);
//---
   price=0.0;
   sl   =m_symbol.Ask()-m_stop_loss*m_adjusted_point;
   tp   =m_symbol.Ask()+m_take_profit*m_adjusted_point;
//--- Comprobando tendencia alcista (en la última barra completa): FastEMA(1)>MediumEMA(1)>SlowEMA(1)
    return(FastEMA(1)>medium && medium>SlowEMA(1));
  }

2. Cierre de posición larga

La tendencia bajista se determina por la condición siguiente: FastEMA<MediumEMA<SlowEMA:

• FastEMA(1)<MediumEMA(1): EMA Rápida es menor que la EMA Media (en la última barra completa);
• MediumEMA(1)<SlowEMA(1): EMA Media es menor que la EMA Lenta (en la última barra completa);

//+------------------------------------------------------------------+
//| Comprueba condiciones de cierre de posición larga                |
//+------------------------------------------------------------------+
bool CSignal3EMA::CheckCloseLong(double& price)
  {
   double medium=MediumEMA(1);
//---
   price=0.0;
//--- Comprobando tendencia bajista (en la última barra completa): FastEMA(1)<MediumEMA(1)<SlowEMA(1)
   return(FastEMA(1)<medium && medium<SlowEMA(1));
  }

3. Apertura de posición corta

//+------------------------------------------------------------------+
//| Comprueba condiciones de apertura de posición corta (venta)      |
//+------------------------------------------------------------------+
bool CSignal3EMA::CheckOpenShort(double& price,double& sl,double& tp,datetime& expiration)
  {
   double medium=MediumEMA(1);
//---
   price=0.0;
   sl   =m_symbol.Bid()+m_stop_loss*m_adjusted_point;
   tp   =m_symbol.Bid()-m_take_profit*m_adjusted_point;
//--- Comprobando tendencia bajista (en la última barra completa): FastEMA(1)<MediumEMA(1)<SlowEMA(1)
   return(FastEMA(1)<medium && medium<SlowEMA(1));

  }

4. Cierre de posición corta

//+------------------------------------------------------------------+
//| Comprueba condiciones de cierre de posición corta                |
//+------------------------------------------------------------------+
bool CSignal3EMA::CheckCloseShort(double& price)
  {
   double medium=MediumEMA(1);
//---
   price=0.0;
//--- Comprobando tendencia alcista (en la última barra completa): FastEMA(1)>MediumEMA(1)>SlowEMA(1)
   return(FastEMA(1)>medium && medium>SlowEMA(1));
  }

Creando el Asesor Experto con el MQL5 Wizard

Para crear un robot de trading basado en esta estrategia debe seleccionar "Signals based on three EMA" para las propiedades de señal del Expert Advisor en la opción "Expert Advisor (generate)" de MQL5 Wizard:

Figura 2. Seleccionar "Signals based on three EMA" en MQL5 Wizard

Lo próximo que debe especificar es el algoritmo necesario para trailing stop y el sistema de gestión de capital. El código del Asesor Experto será creado automáticamente, puede compilarlo y verificarlo en el Probador de Estrategias del terminal de cliente MetaTrader 5.

Resultados de las pruebas

Vamos a considerar una simulación del asesor experto con datos históricos (EURUSD H1, periodo personalizado: 2010.01.01-2011.01.05,  FastPeriod=5, MediumPeriod=12, SlowPeriod=24, StopLoss=400, TakeProfit=900).

En la creación del Asesor Experto se seleccionó una gestión de capital con volumen fijo de 0.1 lotes (Trading with fixed trade volume, 0.1), y sin algoritmo de Trailing Stop (Trailing Stop not used).

Figura 3. Resultados de la simulación histórica del Asesor Experto, basada en las tres EMA

Adjuntos: El fichero Signal3EMA.mqh con la clase CSignal3EMA se encuentra en la carpeta terminal_data_folder\MQL5\Include\Expert\Signal.

El fichero threeema.mq5 contiene el código, del Asesor Experto, creado con MQL5 Wizard.