RC Soldiers and Crows MT5

//+-------------------------------------------------------------------------+
//| 	     RC_Soldiers_Crows_EA_Sample.mq5|
//|Urheberrecht 2024, Francisco Rayol|
//| https://www.rayolcode.com
//+-------------------------------------------------------------------------+
#property description "RC_Soldiers_Crows_EA_Sample"
#property version   "1.00"
#property strict
#property script_show_inputs

#include <Trade\Trade.mqh>
#include <Trade\PositionInfo.mqh>

CTrade         Ctrade;
CPositionInfo  Cposition;

enum en_options
  {
   Yes = 0,             // Ja
   No = 1,              // Nein
  };

enum tp_type
  {
   Fixed_tp = 0,        // Feste Gewinnmitnahme
   Indicator_tp = 1,    // Profitieren Sie vom Indikator
  };

enum sl_type
  {
   Fixed_sl = 0,        // Fester Stop-Loss
   Indicator_sl = 1,    // Stop Loss vom Indikator
  };

//--- Eingabeparameter
input int              inMagic_Number = 18272;          // Magische Zahl
//----
input double           inLot_Size = 0.01;               // Ursprüngliche Losgröße
//----
input tp_type          inTP_Type = 0;                   // Gewinnmitnahme-Methode wählen
input double           inTake_Profit = 150.0;           // Feste Gewinnmitnahme (in Punkten)
input sl_type          inSL_Type = 0;                   // Stop-Loss-Methode wählen
input double           inStop_Loss = 100.0;             // Fester Stop-Loss (in Punkten)
//----
//+------------------------------------------------------------------+
//||
//+------------------------------------------------------------------+
//--- Signalgriffe
int   handle_rc_soldiers_crows;
//--- Signal-Arrays
double RC_Buy_Signal[], RC_Sell_Signal[], RC_Take_Profit[], RC_Stop_Loss[];
//--- globale Variablen
int   initial_bar;

//+------------------------------------------------------------------+
//| Experten-Initialisierungsfunktion|
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   initial_bar = iBars(_Symbol,_Period);
//---
//--- RC-Soldaten und Krähen Blinkergriff
   handle_rc_soldiers_crows = iCustom(_Symbol, PERIOD_CURRENT, "\\Indicators\\Market\\RC_Soldiers_Crows.ex5");
   if(handle_rc_soldiers_crows == INVALID_HANDLE)
     {
      Print("Error getting information from \"RC_Soldiers_Crows\" indicator, check input parameters and try again");
      Alert("Error getting information from \"RC_Soldiers_Crows\" indicator, check input parameters and try again");
      return(INIT_FAILED);
     }
//---
   ArraySetAsSeries(RC_Buy_Signal, true);
   ArraySetAsSeries(RC_Sell_Signal, true);
   ArraySetAsSeries(RC_Take_Profit, true);
   ArraySetAsSeries(RC_Stop_Loss, true);
//---
   Ctrade.SetExpertMagicNumber(inMagic_Number);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Experten-Deinitialisierungsfunktion|
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---
   Comment("");
  }
//+------------------------------------------------------------------+
//| Experten-Tick-Funktion|
//+------------------------------------------------------------------+
void OnTick()
  {

//--- Brief- und Geldkurse
   double Ask = SymbolInfoDouble(_Symbol,SYMBOL_ASK);
   double Bid = SymbolInfoDouble(_Symbol,SYMBOL_BID);
//+------------------------------------------------------------------+
//--- Indikator-Signale
//--- RC_Soldaten_Krähen Signal: kaufen
   if(CopyBuffer(handle_rc_soldiers_crows,0,0,2,RC_Buy_Signal)<=0) // Kaufsignal
     {
      Print("Getting RC_Soldiers_Crows data is failed! Error ",GetLastError());
      return;
     }
//--- RC_Soldaten_Krähen Signal: verkaufen
   if(CopyBuffer(handle_rc_soldiers_crows,1,0,2,RC_Sell_Signal)<=0) // Verkaufssignal
     {
      Print("Getting RC_Soldiers_Crows data is failed! Error ",GetLastError());
      return;
     }
//--- RC_Soldiers_Crows Signal: Gewinn mitnehmen
   if(CopyBuffer(handle_rc_soldiers_crows,10,0,2,RC_Take_Profit)<=0) // Gewinnmitnahmepreis
     {
      Print("Getting RC_Soldiers_Crows data is failed! Error ",GetLastError());
      return;
     }
//--- RC_Soldiers_Crows Signal: Stop Loss
   if(CopyBuffer(handle_rc_soldiers_crows,11,0,2,RC_Stop_Loss)<=0) // Stop-Loss-Kurs
     {
      Print("Getting RC_Soldiers_Crows data is failed! Error ",GetLastError());
      return;
     }
//+------------------------------------------------------------------+
//---
   if(!F_CheckOpenOrders() && initial_bar!=iBars(_Symbol,_Period))
     {
      if(RC_Buy_Signal[1] != 0.0 && RC_Buy_Signal[1] != EMPTY_VALUE)
        {
         if(Ctrade.Buy(inLot_Size, _Symbol, Ask, inSL_Type == 0 ? Bid - inStop_Loss*_Point : RC_Stop_Loss[1],
                       inTP_Type == 0 ? Ask + inTake_Profit*_Point : RC_Take_Profit[1],"Buy open"))
           {
            initial_bar = iBars(_Symbol,_Period);
           }
         else
            Print("Error on opening buy position :"+IntegerToString(GetLastError()));
        }
      else
         if(RC_Sell_Signal[1] != 0.0 && RC_Sell_Signal[1] != EMPTY_VALUE)
           {
            if(Ctrade.Sell(inLot_Size, _Symbol, Bid, inSL_Type == 0 ? Ask + inStop_Loss*_Point : RC_Stop_Loss[1],
                           inTP_Type == 0 ? Bid - inTake_Profit*_Point : RC_Take_Profit[1],"Sell open"))
              {
               initial_bar = iBars(_Symbol,_Period);
              }
            else
               Print("Error on opening sell position :"+IntegerToString(GetLastError()));
           }
     }
//---
  }
//---
//+------------------------------------------------------------------+
//+------------------------------------------------------------------+
bool F_CheckOpenOrders()
  {
   for(int i = 0; i<PositionsTotal(); i++)
     {
      Cposition.SelectByIndex(i);
        {
         long ord_magic = PositionGetInteger(POSITION_MAGIC);
         string ord_symbol = PositionGetString(POSITION_SYMBOL);
         ENUM_POSITION_TYPE type = Cposition.PositionType();
         if(ord_magic==inMagic_Number && ord_symbol==_Symbol)
            return(true);
        }
     }
   return(false);
  }
//+------------------------------------------------------------------+