RC Soldiers and Crows MT5

//+-------------------------------------------------------------------------+
//|                                  	     RC_Soldiers_Crows_EA_Sample.mq5|
//|                                          Copyright 2024, Francisco Rayol|
//|                                                https://www.rayolcode.com|
//+-------------------------------------------------------------------------+
#property description "RC_Soldiers_Crows_EA_Sample"
#property version   "1.00"
#property strict
#property script_show_inputs

#include <Trade\Trade.mqh>
#include <Trade\PositionInfo.mqh>

CTrade         Ctrade;
CPositionInfo  Cposition;

enum en_options
  {
   Yes = 0,             // Yes
   No = 1,              // No
  };

enum tp_type
  {
   Fixed_tp = 0,        // Fixed Take Profit
   Indicator_tp = 1,    // Take Profit from indicator
  };

enum sl_type
  {
   Fixed_sl = 0,        // Fixed Stop Loss
   Indicator_sl = 1,    // Stop Loss from indicator
  };

//--- input parameters
input int              inMagic_Number = 18272;          // Magic number
//----
input double           inLot_Size = 0.01;               // Initial lot size
//----
input tp_type          inTP_Type = 0;                   // Choose Take Profit method
input double           inTake_Profit = 150.0;           // Fixed Take Profit (in points)
input sl_type          inSL_Type = 0;                   // Choose Stop Loss method
input double           inStop_Loss = 100.0;             // Fixed Stop Loss (in points)
//----
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//--- signal handles
int   handle_rc_soldiers_crows;
//--- signal arrays
double RC_Buy_Signal[], RC_Sell_Signal[], RC_Take_Profit[], RC_Stop_Loss[];
//--- global variables
int   initial_bar;

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   initial_bar = iBars(_Symbol,_Period);
//---
//--- RC Soldiers and Crows indicator handle
   handle_rc_soldiers_crows = iCustom(_Symbol, PERIOD_CURRENT, "\\Indicators\\Market\\RC_Soldiers_Crows.ex5");
   if(handle_rc_soldiers_crows == INVALID_HANDLE)
     {
      Print("Error getting information from \"RC_Soldiers_Crows\" indicator, check input parameters and try again");
      Alert("Error getting information from \"RC_Soldiers_Crows\" indicator, check input parameters and try again");
      return(INIT_FAILED);
     }
//---
   ArraySetAsSeries(RC_Buy_Signal, true);
   ArraySetAsSeries(RC_Sell_Signal, true);
   ArraySetAsSeries(RC_Take_Profit, true);
   ArraySetAsSeries(RC_Stop_Loss, true);
//---
   Ctrade.SetExpertMagicNumber(inMagic_Number);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---
   Comment("");
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {

//--- Ask and Bid prices
   double Ask = SymbolInfoDouble(_Symbol,SYMBOL_ASK);
   double Bid = SymbolInfoDouble(_Symbol,SYMBOL_BID);
//+------------------------------------------------------------------+
//--- Indicator Signals
//--- RC_Soldiers_Crows signal: buy
   if(CopyBuffer(handle_rc_soldiers_crows,0,0,2,RC_Buy_Signal)<=0) // Buy signal
     {
      Print("Getting RC_Soldiers_Crows data is failed! Error ",GetLastError());
      return;
     }
//--- RC_Soldiers_Crows signal: sell
   if(CopyBuffer(handle_rc_soldiers_crows,1,0,2,RC_Sell_Signal)<=0) // Sell signal
     {
      Print("Getting RC_Soldiers_Crows data is failed! Error ",GetLastError());
      return;
     }
//--- RC_Soldiers_Crows signal: take profit
   if(CopyBuffer(handle_rc_soldiers_crows,10,0,2,RC_Take_Profit)<=0) // Take Profit price
     {
      Print("Getting RC_Soldiers_Crows data is failed! Error ",GetLastError());
      return;
     }
//--- RC_Soldiers_Crows signal: stop loss
   if(CopyBuffer(handle_rc_soldiers_crows,11,0,2,RC_Stop_Loss)<=0) // Stop Loss price
     {
      Print("Getting RC_Soldiers_Crows data is failed! Error ",GetLastError());
      return;
     }
//+------------------------------------------------------------------+
//---
   if(!F_CheckOpenOrders() && initial_bar!=iBars(_Symbol,_Period))
     {
      if(RC_Buy_Signal[1] != 0.0 && RC_Buy_Signal[1] != EMPTY_VALUE)
        {
         if(Ctrade.Buy(inLot_Size, _Symbol, Ask, inSL_Type == 0 ? Bid - inStop_Loss*_Point : RC_Stop_Loss[1],
                       inTP_Type == 0 ? Ask + inTake_Profit*_Point : RC_Take_Profit[1],"Buy open"))
           {
            initial_bar = iBars(_Symbol,_Period);
           }
         else
            Print("Error on opening buy position :"+IntegerToString(GetLastError()));
        }
      else
         if(RC_Sell_Signal[1] != 0.0 && RC_Sell_Signal[1] != EMPTY_VALUE)
           {
            if(Ctrade.Sell(inLot_Size, _Symbol, Bid, inSL_Type == 0 ? Ask + inStop_Loss*_Point : RC_Stop_Loss[1],
                           inTP_Type == 0 ? Bid - inTake_Profit*_Point : RC_Take_Profit[1],"Sell open"))
              {
               initial_bar = iBars(_Symbol,_Period);
              }
            else
               Print("Error on opening sell position :"+IntegerToString(GetLastError()));
           }
     }
//---
  }
//---
//+------------------------------------------------------------------+
//+------------------------------------------------------------------+
bool F_CheckOpenOrders()
  {
   for(int i = 0; i<PositionsTotal(); i++)
     {
      Cposition.SelectByIndex(i);
        {
         long ord_magic = PositionGetInteger(POSITION_MAGIC);
         string ord_symbol = PositionGetString(POSITION_SYMBOL);
         ENUM_POSITION_TYPE type = Cposition.PositionType();
         if(ord_magic==inMagic_Number && ord_symbol==_Symbol)
            return(true);
        }
     }
   return(false);
  }
//+------------------------------------------------------------------+