Nachschlagewerk MQL5StandardbibliothekMathematikFuzzy logicMembership functionsCTriangularMembershipFunction

CTriangularMembershipFunction

Klasse für die Implementierung einer Dreicksfunktion mit den Parametern X1, X2 und X3.

Beschreibung

Die Funktion setzt die Zugehörigkeitsfunktion in Form eines Dreiecks. Eine einfache und meist verwendete Zugehörigkeitsfunktion.

fuzzy_triangular_functions

Ein Beispielcode für das Zeichnen dieser Grafik ist unten angeführt.

Deklaration

class CTriangularMembershipFuncion : public IMembershipFunction

Überschrift

#include <Math\Fuzzy\membershipfunction.mqh>

Vererbungshierarchie

CObject

IMembershipFunction

CTriangularMembershipFunction

Methoden der Klasse

Methode der Klasse	Beschreibung
X1	Gibt den Wert des ersten Punktes auf der X-Achse zurück.
X2	Gibt den Wert des zweiten Punktes auf der X-Achse zurück.
X3	Gibt den Wert des dritten Punktes auf der X-Achse zurück.
ToNormalMF	Wandelt eine Dreiecksfunktion in die Gauß'sche Zugehörigkeitsfunktion um.
GetValue	Berechnet den Wert der Funktion nach dem angegebenen Argument.

Methoden geerbt von der Klasse CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Beispiel

//+------------------------------------------------------------------+
//|                                 TriangularMembershipFunction.mq5 |
//|                        Copyright 2016, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Create membership functions
CTriangularMembershipFunction func1(0,2,5);
CTriangularMembershipFunction func2(0,5,10);
CTriangularMembershipFunction func3(8,8,10);
//--- Create wrappers for membership functions
double TriangularMembershipFunction1(double x) { return(func1.GetValue(x)); }
double TriangularMembershipFunction2(double x) { return(func2.GetValue(x)); }
double TriangularMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- create graphic
   CGraphic graphic;
   if(!graphic.Create(0,"TriangularMembershipFunction",0,30,30,780,380))
     {
      graphic.Attach(0,"TriangularMembershipFunction");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("TriangularMembershipFunction");
   graphic.BackgroundMainSize(16);
//--- create curve
   graphic.CurveAdd(TriangularMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[0, 2, 5]");
   graphic.CurveAdd(TriangularMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[0, 5, 10]");
   graphic.CurveAdd(TriangularMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[8, 8, 10]");
//--- sets the X-axis properties
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- sets the Y-axis properties
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- plot
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue