Referência MQL5Biblioteca PadrãoMatemáticaLógica difusaFunções de associaçãoCTriangularMembershipFunction

CTriangularMembershipFunction

Classe para implementar uma função de associação triangular com parâmetros X1, X2, X3.

Descrição

A função defina a função de associação na forma de um triângulo. Trata-se da simples e frequentemente utilizada função de associação.

fuzzy_triangular_functions

Exemplo de código para plotagem do gráfico mostrado abaixo.

Declaração

class CTriangularMembershipFuncion : public IMembershipFunction

Cabeçalho

#include <Math\Fuzzy\membershipfunction.mqh>

Hierarquia de herança

CObject

IMembershipFunction

CTriangularMembershipFunction

Métodos de classe

Método de classe	Descrição
X1	Retorna o valor do primeiro ponto na abcissa.
X2	Retorna o valor do segundo ponto na abcissa.
X3	Retorna o valor do terceiro ponto na abcissa.
ToNormalMF	Converte a função de associação triangular numa função de Gauss.
GetValue	Calcula o valor da função de associação para o argumento especificado.

Métodos herdados da classe CObject

Prev, Prev, Next, Next, Save, Load, Type, Compare

Exemplo

//+------------------------------------------------------------------+
//|                                 TriangularMembershipFunction.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"
#include <Math\Fuzzy\membershipfunction.mqh>
#include <Graphics\Graphic.mqh>
//--- Create membership functions
CTriangularMembershipFunction func1(0,2,5);
CTriangularMembershipFunction func2(0,5,10);
CTriangularMembershipFunction func3(8,8,10);
//--- Create wrappers for membership functions
double TriangularMembershipFunction1(double x) { return(func1.GetValue(x)); }
double TriangularMembershipFunction2(double x) { return(func2.GetValue(x)); }
double TriangularMembershipFunction3(double x) { return(func3.GetValue(x)); }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- create graphic
   CGraphic graphic;
   if(!graphic.Create(0,"TriangularMembershipFunction",0,30,30,780,380))
     {
      graphic.Attach(0,"TriangularMembershipFunction");
     }
   graphic.HistoryNameWidth(70);
   graphic.BackgroundMain("TriangularMembershipFunction");
   graphic.BackgroundMainSize(16);
//--- create curve
   graphic.CurveAdd(TriangularMembershipFunction1,0.0,10.0,0.1,CURVE_LINES,"[0, 2, 5]");
   graphic.CurveAdd(TriangularMembershipFunction2,0.0,10.0,0.1,CURVE_LINES,"[0, 5, 10]");
   graphic.CurveAdd(TriangularMembershipFunction3,0.0,10.0,0.1,CURVE_LINES,"[8, 8, 10]");
//--- sets the X-axis properties
   graphic.XAxis().AutoScale(false);
   graphic.XAxis().Min(0.0);
   graphic.XAxis().Max(10.0);
   graphic.XAxis().DefaultStep(1.0);
//--- sets the Y-axis properties
   graphic.YAxis().AutoScale(false);
   graphic.YAxis().Min(0.0);
   graphic.YAxis().Max(1.1);
   graphic.YAxis().DefaultStep(0.2);
//--- plot
   graphic.CurvePlotAll();
   graphic.Update();
  }

GetValue