Trade Classes from MT5 for MT4 - библиотека для MetaTrader 4

В данной версии могут встретиться некоторые методы классов, которые не удалось обнаружить при тестировании, как нуждающиеся в исправлении.

Файл TradeLibraryMT5Example.mq4 - это пример простого советника, который компилируется и работает в MT5 и в MT4.

Для открытия отложенных ордеров используется такой код:

CTrade m_trade;

...

res = m_trade.OrderOpen(m_symbol, ORDER_TYPE_BUY_LIMIT, m_lot, lowPrice, lowPrice, 0, 0, ORDER_TIME_GTC, 0);
res = m_trade.OrderOpen(m_symbol, ORDER_TYPE_SELL_LIMIT, m_lot, highPrice, highPrice, 0, 0, ORDER_TIME_GTC, 0);

Функция расчета суммарной прибыли всех открытых рыночных позиций может быть реализована так:

//+------------------------------------------------------------------+
//| Calculate total profit for all market orders                     |
//+------------------------------------------------------------------+
double GetProfit() {
   int total = PositionsTotal();
   double profit = 0;

   CPositionInfo p;

   for(int i = total - 1; i >= 0; i--) {
      if(p.SelectByIndex(i)) {
         ulong magic = p.Magic();
         string symbol = p.Symbol();
         if(magic != m_magicN || symbol != m_symbol) {
            continue;
         }

         profit += p.Profit() + p.Commission() + p.Swap();
      }
   }

   return profit;
}

Функция закрытия всех открытых позиций и отложенных ордеров может быть реализована так:

//+------------------------------------------------------------------+
//| Attempt to close all pending and market orders                   |
//+------------------------------------------------------------------+
bool TryCloseAll() {
   bool res = true;
   
   int total;
   double profit = 0;
   ulong ticket;
   ulong magic;
   string symbol;
   
   total = OrdersTotal();

   COrderInfo o;

   for(int i = total - 1; i >= 0; i--) {
      if(o.SelectByIndex(i)) {
         magic = o.Magic();
         symbol = o.Symbol();
         if(magic != m_magicN || symbol != m_symbol) {
            continue;
         }
         ticket = o.Ticket();

         res &= m_trade.OrderDelete(o.Ticket());
      }
   }

   total = PositionsTotal();
   
   CPositionInfo p;

   for(int i = total - 1; i >= 0; i--) {
      if(p.SelectByIndex(i)) {
         magic = p.Magic();
         symbol = p.Symbol();
         if(magic != m_magicN || symbol != m_symbol) {
            continue;
         }
         ticket = p.Ticket();

         res &= m_trade.PositionClose(ticket);
      }
   }

   return res;
}