SymbolInfoCommissions

int  SymbolInfoCommissions(
   string           name,              // 심볼 이름
   MqlCommission&   commissions[]      // 수수료 규칙 배열
   );

//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- 수수료 부과 규칙을 받기 위한 동적 배열 선언
   MqlCommission commissions[];
 
//--- 현재 심볼의 수수료 규칙 가져오기.
//--- NULL 대신 심볼 이름을 지정하면 함수는 해당 심볼의 수수료를 반환합니다.
   int total=SymbolInfoCommissions(NULL,commissions);
 
//--- 함수 실행 결과 확인
   if(total<0)
     {
      //--- 오류가 발생한 경우 오류 코드 출력
      PrintFormat("SymbolInfoCommissions failed. Error %d",GetLastError());
      return;
     }
 
//--- 수신된 수수료 규칙 수 출력
   PrintFormat("Commission rules: %d",total);
 
//--- 모든 수수료 규칙 반복
   for(int i=0;i<total;i++)
     {
      //--- 수수료 규칙의 주요 매개변수 출력:
      //--- 통화, 범위 선택 모드 및 부과 모드
      PrintFormat("Rule %d: currency=%s, range mode=%d, charge mode=%d",
                  i,
                  commissions[i].currency,
                  commissions[i].mode_range,
                  commissions[i].mode_charge);
 
      //--- 현재 규칙의 수수료 티어 수 가져오기
      int tiers_total=ArraySize(commissions[i].tiers);
 
      //--- 수수료 티어 반복
      for(int j=0;j<tiers_total;j++)
        {
         //--- 수수료 티어 매개변수 출력:
         //--- 계산 모드, 값, 적용 범위 및 통화
         PrintFormat("  Tier %d: mode=%d, value=%G, range=%G - %G, currency=%s",
                     j,
                     commissions[i].tiers[j].mode,
                     commissions[i].tiers[j].value,
                     commissions[i].tiers[j].range_from,
                     commissions[i].tiers[j].range_to,
                     commissions[i].tiers[j].currency);
        }
     }
  }

struct MqlCommissionTier
  {
   ENUM_SYMBOL_COMMISSION_MODE           mode;
   ENUM_SYMBOL_COMMISSION_VOLUME_TYPE    volume_type;
   double                                value;
   double                                min_value;
   double                                max_value;
   double                                range_from;
   double                                range_to;
   string                                currency;
  };

struct MqlCommission
  {
   string                                   currency;
   ENUM_SYMBOL_COMMISSION_RANGE_MODE        mode_range;
   ENUM_SYMBOL_COMMISSION_CHARGE_MODE       mode_charge;
   ENUM_SYMBOL_COMMISSION_ENTRY_MODE        mode_entry;
   ENUM_SYMBOL_COMMISSION_DIRECTION_MODE    mode_direction;
   ENUM_SYMBOL_COMMISSION_PROFIT_MODE       mode_profit;
   MqlCommissionTier                        tiers[];
  };