//+--------------------------------------------------------------------------------+
//| iADXWilder.mq5 |
//| Copyright 2011, MetaQuotes Software Corp. |
//| https://www.mql5.com |
//+--------------------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "L'indicatore dimostra come ottenere i dati"
#property description "del buffer indicatore per l'indicatore tecnico iADXWilder.
#property description "Il simbolo e timeframe usati per i calcoli dell'indicatore,"
#property description "vengono impostati dai parametri simbolo e periodo."
#property description "Il metodo per la creazione dell'handle è impostato attraverso il parametro 'type' (funzione type)."
#property indicator_separate_window
#property indicator_buffers 3
#property indicator_plots 3
//--- traccio ADX
#property indicator_label1 "ADX"
#property indicator_type1 DRAW_LINE
#property indicator_color1 clrLightSeaGreen
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- traccio DI_plus
#property indicator_label2 "DI_plus"
#property indicator_type2 DRAW_LINE
#property indicator_color2 clrYellowGreen
#property indicator_style2 STYLE_SOLID
#property indicator_width2 1
//--- disegna DI_minus
#property indicator_label3 "DI_minus"
#property indicator_type3 DRAW_LINE
#property indicator_color3 clrWheat
#property indicator_style3 STYLE_SOLID
#property indicator_width3 1
//+--------------------------------------------------------------------------------+
//| Enumerazione dei metodi della creazione dell'handle |
//+--------------------------------------------------------------------------------+
enum Creation
{
Call_iADXWilder, // usa iADXWilder
Call_IndicatorCreate // usa IndicatorCreate
};
//--- parametri di input
input Creation type=Call_iADXWilder; // tipo di funzione
input int adx_period=14; // periodo per il calcolo
input string symbol=" "; // simbolo
input ENUM_TIMEFRAMES period=PERIOD_CURRENT; // timeframe
//--- buffers indicatore
double ADXBuffer[];
double DI_plusBuffer[];
double DI_minusBuffer[];
//--- variabile per memorizzare l'handle dell'indicatore iADXWilder
int handle;
//--- variabile per memorizzare
string name=symbol;
//--- nome dell'indicatore sul grafico
string short_name;
//--- manterremo il numero di valori dell'indicatore Average Directional Movement Index di Welles Wilder
int bars_calculated=0;
//+--------------------------------------------------------------------------------+
//| Funzione di inizializzazione Indicatore Personalizzato |
//+--------------------------------------------------------------------------------+
int OnInit()
{
//--- assegnazione di array di buffer indicatori
SetIndexBuffer(0,ADXBuffer,INDICATOR_DATA);
SetIndexBuffer(1,DI_plusBuffer,INDICATOR_DATA);
SetIndexBuffer(2,DI_minusBuffer,INDICATOR_DATA);
//--- determinare il simbolo per cui viene disegnato l'indicatore
name=symbol;
//--- eliminare gli spazi a destra e a sinistra
StringTrimRight(name);
StringTrimLeft(name);
//--- se il risultato è zero nella lunghezza della stringa 'name'
if(StringLen(name)==0)
{
//--- prende il simbolo del grafico indicatore a cui è attaccato
name=_Symbol;
}
//--- crea l'handle dell'indicatore
if(type==Call_iADXWilder)
handle=iADXWilder(name,period,adx_period);
else
{
//--- riempie la struttura con i parametri dell'indicatore
MqlParam pars[1];
pars[0].type=TYPE_INT;
pars[0].integer_value=adx_period;
handle=IndicatorCreate(name,period,IND_ADXW,1,pars);
}
//--- se l'handle non viene creato
if(handle==INVALID_HANDLE)
{
//--- dice riguardo il fallimento e l'output del codice di errore
PrintFormat("Fallimento nel creare l'handle dell'indicatore iADXWilder per il simbolo %s/%s, codice errore %d",
name,
EnumToString(period),
GetLastError());
//--- l'indicatore si ferma precocemente
return(INIT_FAILED);
}
//--- mostra il simbolo/timeframe per cui è calcolato l'indicatore tecnico Average Directional Movement Index di Welles Wilder
short_name=StringFormat("iADXWilder(%s/%s period=%d)",name,EnumToString(period),adx_period);
IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- inizializzazione normale dell'indicatore
return(INIT_SUCCEEDED);
}
//+--------------------------------------------------------------------------------+
//| Funzione di iterazione indicatore personalizato |
//+--------------------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
//--- numero di valori copiati dall' indicatore iADXWilder
int values_to_copy;
//--- determina il numero di valori calcolati in dell'indicatore
int calculated=BarsCalculated(handle);
if(calculated<=0)
{
PrintFormat("BarsCalculated() returned %d, error code %d",calculated,GetLastError());
return(0);
}
//--- se è il primo inizio del calcolo dell'indicatore o se il numero di valori dell'indicatore iADXWilder è cambiato
//--- o se è necessario calcolare l'indicatore per due o più barre (significa che qualcosa è cambiato nello storico prezzi)
if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
{
//--- se l' array iADXBuffer è maggiore del numero di valori dell'indicatore iADXWilder per il simbolo/periodo, allora non copiamo tutto
//--- altrimenti, copiamo meno della grandezza del buffer indicatore
if(calculated>rates_total) values_to_copy=rates_total;
else values_to_copy=calculated;
}
else
{
//--- vuol dire che non è la prima volta del calcolo dell'indicatore, e dopo l'ultima chiamata di OnCalculate() )
//--- per il calcolo non viene aggiunta più di una barra
values_to_copy=(rates_total-prev_calculated)+1;
}
//--- riempie l'array con i valori dell'indicatore Average Directional Movement Index di Welles Wilder
//--- se FillArraysFromBuffer restituisce false, significa che l'informazione non è ancora pronta, chiude l'operazione
if(!FillArraysFromBuffers(ADXBuffer,DI_plusBuffer,DI_minusBuffer,handle,values_to_copy)) return(0);
//--- forma il messaggio
string comm=StringFormat("%s ==> Valore aggiornato nell'indicatore %s: %d",
TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
short_name,
values_to_copy);
//--- visualizza il messaggio di servizio sul grafico
Comment(comm);
//--- memorizza il numero di valori dell'indicatore Average Directional Movement Index
bars_calculated=calculated;
//--- restituisce il valore prev_calculated per la chiamata successiva
return(rates_total);
}
//+--------------------------------------------------------------------------------+
//| Riempie il buffer indicatore dall'indicatore iADXWilder |
//+--------------------------------------------------------------------------------+
bool FillArraysFromBuffers(double &adx_values[], // buffer indicatore della linea di ADX
double &DIplus_values[], // buffer indicatore per DI+
double &DIminus_values[], // buffer indicatore for DI-
int ind_handle, // handle dell'indicatore iADXWilder
int amount // numero di valori copiati
)
{
//--- resetta codice errore
ResetLastError();
//--- riempie una parte dell'array iADXBuffer con valori dal buffer indicatore che ha indice 0
if(CopyBuffer(ind_handle,0,0,amount,adx_values)<0)
{
//--- se la copia fallisce, dice il codice dell'errore
PrintFormat("Fallimento nel copiare i dati dall'indicatore iADXWilder, codice errore %d",GetLastError());
//--- esce con risultato zero - significa che l'indicatore è considerato come non calcolato
return(false);
}
//--- riempie una parte dell'array DI_plusBuffer con valori dal buffer indicatore che ha indice 1
if(CopyBuffer(ind_handle,1,0,amount,DIplus_values)<0)
{
//--- se la copia fallisce, dice il codice dell'errore
PrintFormat("Fallimento nel copiare i dati dall'indicatore iADXWilder, codice errore %d",GetLastError());
//--- esce con risultato zero - significa che l'indicatore è considerato come non calcolato
return(false);
}
//--- riempie una parte dell'array DI_plusBuffer con valori dal buffer indicatore che ha indice 2
if(CopyBuffer(ind_handle,2,0,amount,DIminus_values)<0)
{
//--- se la copia fallisce, dice il codice dell'errore
PrintFormat("Fallimento nel copiare i dati dall'indicatore iADXWilder, codice errore %d",GetLastError());
//--- esce con risultato zero - significa che l'indicatore è considerato come non calcolato
return(false);
}
//--- tutto è ok
return(true);
}
//+--------------------------------------------------------------------------------+
//| Funzione deinizializzazione indicatore |
//+--------------------------------------------------------------------------------+
void OnDeinit(const int reason)
{
if(handle!=INVALID_HANDLE)
IndicatorRelease(handle);
//--- cancella il grafico dopo aver eliminato l'indicatore
Comment("");
}
|